以下是引用liuxingang28在2016-3-14 16:57:16的发言：

针对第二个问题，解决方案如下：

修改 MyProc.prg，在 THISFORM.Refresh 之后添加一行：THIS.Parent.SetFocus

以下是引用mywisdom88在2016-3-14 17:06:52的发言：


有点小问题，能定位到列了，但行记录，将会跳来跳去
是要把THIS.Parent.SetFocus放在GO TOP的上面
THIS.Parent.SetFocus
GO TOP
THISFORM.Refresh

以下是引用liuxingang28在2016-3-15 08:48:50的发言：

我的原话是：“在 THISFORM.Refresh 之后添加一行：THIS.Parent.SetFocus”，修改后的完整代码如下：

DEFINE CLASS MyHeader as Header
    name = 'Header1'
    PROCEDURE Click
        LOCAL nSelect,cFldName,cAlias,nNum_Tag
        cAlias = JUSTFNAME(THIS.Parent.ControlSource)    && 表名
        cFldName = JUSTEXT(THIS.Parent.ControlSource)    && 字段名
        cOldPict = JUSTSTEM(THIS.Picture)        && 当前图片
        THIS.Parent.Parent.SetAll('Picture','')        && 先去除所有图片
        nSelect = SELECT()
        SELECT (cAlias)
        nNum_Tag = ATAGINFO(aTag)
        DO CASE
        CASE ATC('up',cOldPict) > 0                && 升序时降序
            THIS.Picture = 'dowm.bmp'
            IF nNum_Tag > 0 AND ASCAN(aTag,cFldName,-1,-1,1,7) > 0 && 若索引标记存在，则激活之
               SET ORDER TO &cFldName DESCENDING
            ELSE
                INDEX ON &cFldName TAG (cFldName) DESCENDING   && 索引标记不存在，新建之
            ENDIF
        CASE ATC('down',cOldPict) > 0            && 降序时无序
            SET ORDER TO
        OTHERWISE                                && 无序时升序
            THIS.Picture = 'up.bmp'
            IF nNum_Tag > 0 AND ASCAN(aTag,cFldName,-1,-1,1,7) > 0
                SET ORDER TO &cFldName
            ELSE
                INDEX ON &cFldName TAG (cFldName)
            ENDIF
        ENDCASE
        lFlag = .f.
        SCAN
            REPLACE flag WITH lFlag
            lFlag = !lFlag
        ENDSCAN
        GO TOP
        THISFORM.Refresh
        THIS.Parent.SetFocus

        SELECT (nSelect)
    ENDPROC
ENDDEFINE

行记录不是“跳来跳去”，每次单击列标题后跳转到“第一条”记录，这也是大多数人的需要。如果你想单击列标题后保留原记录，也很简单，代码稍作修改如下：
DEFINE CLASS MyHeader as Header
    name = 'Header1'
    PROCEDURE Click
        LOCAL nSelect,cFldName,cAlias,nNum_Tag
        cAlias = JUSTFNAME(THIS.Parent.ControlSource)    && 表名
        cFldName = JUSTEXT(THIS.Parent.ControlSource)    && 字段名
        cOldPict = JUSTSTEM(THIS.Picture)        && 当前图片
        THIS.Parent.Parent.SetAll('Picture','')        && 先去除所有图片
        nSelect = SELECT()
        SELECT (cAlias)
        nRec = IIF(EOF(),0,RECNO())
        nNum_Tag = ATAGINFO(aTag)
        DO CASE
        CASE ATC('up',cOldPict) > 0                && 升序时降序
            THIS.Picture = 'dowm.bmp'
            IF nNum_Tag > 0 AND ASCAN(aTag,cFldName,-1,-1,1,7) > 0 && 若索引标记存在，则激活之
               SET ORDER TO &cFldName DESCENDING
            ELSE
                INDEX ON &cFldName TAG (cFldName) DESCENDING   && 索引标记不存在，新建之
            ENDIF
        CASE ATC('down',cOldPict) > 0            && 降序时无序
            SET ORDER TO
        OTHERWISE                                && 无序时升序
            THIS.Picture = 'up.bmp'
            IF nNum_Tag > 0 AND ASCAN(aTag,cFldName,-1,-1,1,7) > 0
                SET ORDER TO &cFldName
            ELSE
                INDEX ON &cFldName TAG (cFldName)
            ENDIF
        ENDCASE
        lFlag = .f.
        SCAN
            REPLACE flag WITH lFlag
            lFlag = !lFlag
        ENDSCAN
*        GO TOP
        IF nRec # 0
           GO nRec
        ENDIF
        THISFORM.Refresh
        THIS.Parent.SetFocus
        SELECT (nSelect)
    ENDPROC
ENDDEFINE

“师父领进门，修行在个人”。如果自己没有独立思考能力，单靠他人指导是不行的。

以下是引用liuxingang28在2016-3-16 16:05:27的发言：

我也曾使用过ActiveRow，代码是：This.SetAll("DynamicBackColor","IIF(MOD(this.activerow,2)=0,RGB(255,255,255),RGB(192,192,192))","Column")

当使用鼠标滚轮或滚动条向下滚动记录时，奇偶行并未分色显示，分别单击各行时才分色显示。虽经努力，始终未解决此问题，不知吹版主有何高招？

而采用我的方法：为表新增 Flag 字段，根据该字段来分色显示却没有任何问题。

DECLARE LONG PostMessage IN User32 LONG, LONG, LONG, LONG

CREATE CURSOR tt (F1 I, F2 C(10))
FOR i = 1 TO 20
    INSERT INTO tt VALUES (i%2, PADL(i,4,"0")) 
ENDFOR
GO TOP

of = CREATEOBJECT("form1")
of.Show
READ EVENTS
CLEAR DLLS
RETURN

DEFINE CLASS form1 As Form
    ADD OBJECT cmd1 as commandbutton WITH top=8,left=10,caption="SORT"
    Add Object Grid1 As Grid WITH top=30
        
    PROCEDURE UnLoad
        CLEAR EVENTS
    ENDPROC

    PROCEDURE Init
        BINDEVENT(this.hWnd, 0x401, this, "GridSetFocus")
        this.Grid1.SetFocus
    ENDPROC
    
    PROCEDURE cmd1.Click
        DELETE TAG ALL 
        INDEX on F2 TAG tt_F2 DESCENDING 
        thisform.Grid1.SetFocus
    ENDPROC
    
    PROCEDURE Grid1.Init
        this.SetAll("DynamicBackColor", "IIF(MOD(this.ActiveRow,2)==0, 0xFFFFFF, 0xC0C0C0)", "Column")
    ENDPROC

    PROCEDURE Grid1.Scrolled(nDirection)
        DOEVENTS
        PostMessage(thisform.hWnd, 0x401, 0, 0)
    ENDPROC
    
    FUNCTION GridSetFocus(hWnd, nMsg, wParam, lParam)
        this.Grid1.SetFocus
    ENDPROC
ENDDEFINE

以下是引用liuxingang28在2016-3-16 16:09:26的发言：

回复 14 楼问题：

关于有些行颜色显示错乱，这不是我提供的代码有问题，而是你的初始索引文件有问题，需要 Reindex。因为在我的代码中，若该字段已建立了索引，则直接激活该索引，并没有重新建立。