API CLSIDFromProgID()检测控件注册。
控件文件（OCX、DLL）里面有导出函数 DllRegisterServer()、DllUnregisterServer()注册或取消注册。

看到过这些函数，就是不太会用，大师有不有实例?

* 检测MS日期控件 MSComCt2.OCX 未注册时完成注册，版本2-("MSComCtl2.DTPicker.2")
IF !myRegServer("MSComCtl2.DTPicker.2", 0)
    IF !myRegServer("MSComCt2.OCX", 1)
        RETURN .F.
    ENDIF
ENDIF

* 取消MS日期控件 MSComCt2.OCX 的注册
myRegServer("MSComCt2.OCX", 2)

FUNCTION myRegServer(sName, nFlags)
    IF INLIST(nFlags, 1, 2) AND !FILE(sName)
        MESSAGEBOX(sName + " 文件不存在")
        RETURN .F.
    ENDIF
    LOCAL sCLSID, nRet
    DO CASE
    CASE nFlags == 0
        DECLARE LONG CLSIDFromProgID IN Ole32 STRING, STRING@
        sCLSID = REPLICATE(0h00, 16)
        nRet = CLSIDFromProgID(STRCONV(sName + 0h00, 5), @sCLSID)
        CLEAR DLLS "CLSIDFromProgID"
        RETURN (nRet == 0)
    CASE nFlags == 1
        DECLARE LONG DllRegisterServer IN (sName)
        nRet = DllRegisterServer()
        CLEAR DLLS "DllRegisterServer"
    CASE nFlags == 2
        DECLARE LONG DllUnregisterServer IN (sName)
        nRet = DllUnregisterServer()
        CLEAR DLLS "DllUnregisterServer"
    OTHERWISE
        MESSAGEBOX("调用 myRegServer() 的参数无效")
        RETURN .F.
    ENDCASE
    IF (nRet != 0)
        MESSAGEBOX("调用 myRegServer() 失败，试用管理员身份运行。")
    ENDIF
    RETURN (nRet == 0)
ENDFUNC

[此贴子已经被作者于2016-1-1 20:59编辑过]

其他WIN系统没问题，但在win10中出现：
调用 myRegServer() 失败，试用管理员身份运行
请问要怎么解决？

高版本windows注册控件有权限，试用管理员身份运行。

是的，我也没办法，VFP9还是用的installshield Express 5.0 for Visual ForPro打包，不能直接设置管理员身份运行

可以单独编译成一个EXE文件，程序中以管理员身份运行这个外部EXE就可以。
如：
oApp = CREATEOBJECT("Shell.Application")
oApp.ShellExecute(EXE文件名, "", "", "runas", 1)

快捷可以右点选“以管理员身份运行”

弯道超车，实属不易，就这么办，谢谢啊！

留个脚印，学习。