vfp表格中 怎样才能显示不同颜色的记录行。
如：满足条件empy(nc)的记录显示红色， empy(mc)显示绿色  empty(lc)显示灰色

显示一种颜色我是可以的（如下代码已经OK）但是显示多种颜色我不知道怎么弄了？ 各位大哥大姐请帮帮我？
This.SetAll("DynamicForeColor","iif(empty(ck_cp_op.dj) and empty(ck_cp_op.sl) and empty(ck_cp_op.kp) , rgb(200,10,18),This.ForeColor)","Column")

ck_cp_op.dbf 字段如下
dj
sl
kp
kc
gc
lc
mc
nc  

论坛中有，自己搜索下

核心代码

With ThisForm.Grid1
     .RecordSource="Temp"
     .RecordSourceType=1
     For lnI=1 To Fcount("Temp")
         .Columns(lnI).Header1.Caption=Field(lnI,"Temp")
         .Columns(lnI).Header1.Alignment=2
         .Columns(lnI).Header1.FontName="YaHei Consolas Hybrid"
         .Columns(lnI).DynamicForeColor="Icase('本期合计'$日期,Rgb(255,0,0),'年'$日期,Rgb(0,128,0),Rgb(0,0,0))"
     Endfor
     .SetFocus
     .AutoFit 
     .SetAll("Format","Z","Column")
EndWith

[ 本帖最后由 sdta 于 2014-11-23 17:10 编辑 ]

收到的鲜花

• wxhapxl 于 2014-11-23 18:40 送鲜花  1朵  

还是不会弄

看了你的核心代码还是不明白， 能否按照我的数据据和字段名帮我写一下。 我是初学者希望原凉

上传相关文件，不能为了帮你解决问题，我自己还要帮你造数据吧

PUBLIC oForm
oForm = NEWOBJECT("Form1")
oForm.Show
RETURN

DEFINE CLASS form1 AS form


    DoCreate = .T.
    AutoCenter = .T.
    Caption = "Form1"
    Name = "Form1"


    ADD OBJECT grid1 AS grid WITH ;
        FontName = "YaHei Consolas Hybrid", ;
        FontSize = 11, ;
        Height = 200, ;
        Left = 12, ;
        RowHeight = 23, ;
        Top = 24, ;
        Width = 320, ;
        Name = "Grid1"


    PROCEDURE Init
        Create Cursor T (A1 N(4),A2 N(4),A3 N(4))
        Insert Into T Values (10,100,1000)
        Insert Into T Values (1000,10,100)
        Insert Into T Values (100,1000,10)
        Go Top 
        With ThisForm.Grid1
             .ColumnCount=Fcount("T")
             .RecordSource="T"
             .RecordSourceType=0
             For lnI=1 To .ColumnCount
                 myField=Field(lnI)
                 .Columns(lnI).DynamicForeColor="Icase(&myField=10,Rgb(255,0,0),&myField=100,Rgb(0,255,0),Rgb(0,0,255))"
                 .Columns(lnI).Header1.Caption=Field(lnI)
             EndFor
             .Refresh
        EndWith
    ENDPROC


    PROCEDURE grid1.AfterRowColChange
        LPARAMETERS nColIndex
        thisform.Caption=TRANSFORM(thisform.Grid1.Columns[nColIndex].Text1.Value)
    ENDPROC


ENDDEFINE

你的QQ或都邮箱是什么， 我发给你

我把程序上传了， 请各位大哥看一下怎样改？

按银行往来目录下的，银行往来.exe  ，  登陆（操作员1 口令9090）再点银行帐， 再点下面的“查找”

要求：当审核人为空且经办人为空且经手人为空时，满足的记录显示红色
      当审核人为空且经办人为空，经手人不为空时， 记录显示黄色
      当审核人为空， 经办人和经手人不为空时， 记灵显示灰色

请问怎么写代码？？？

select ha_cw_yx
 if lrs='晓英安'
 set filter to  ALLTRIM(ha_cw_yx.sz_dw)='华安'
 endi
 if lrs='晓英昌'
 set filter to  ALLTRIM(ha_cw_yx.sz_dw)='华昌'
 endi
 if lrs='孔森'
 set filter to  ALLTRIM(ha_cw_yx.sz_dw)='华顺'
 endi
 if lrs='潘萍萍'
 set filter to  ALLTRIM(ha_cw_yx.sz_dw)='华泰'
 endi

在你以上代码后加入这句子

THISFORM.grdcw.SetAll("DynamicForeColor","ICASE(EMPTY(shr+jbr+man), RGB(255,0,0),EMPTY(shr+jbr) AND NOT EMPTY(man),RGB(255,255,0),EMPTY(shr) AND NOT EMPTY(jbr) AND NOT EMPTY(man),RGB(128,128,128),RGB(0,0,0) )", "Column")