现有一学校报名数据bmk（bmh 报名号,kldm 科类代码,njdm 年级代码,kch 考场号,zwh 座位号），共有三个年级，每个年级有文科（11）和理科（12），如何编程安排考场（30人一个考场）？在论坛中学习了老师们编排考场的程序，每次都分年级分科类编排考场后再把数据合拢，很麻烦！现在想请教老师们帮忙支招！不胜感激！

有什么具体要求

SELECT distinct njdm,kldm FROM bmk INTO CURSOR t
SCAN
   SELECT bmh,njdm,kldm,SPACE(2) 考场号,SPACE(2) 座位号 FROM bmk WHERE njdm==t.njdm AND kldm==t.kldm INTO CURSOR T1 READWRITE
   REPLACE ALL 考场号 WITH TRANSFORM(CEILING(RECNO()/30)),座位号 WITH TRANSFORM(IIF(MOD(RECNO(),30)=0,30,MOD(RECNO(),30)))
   UPDATE BMK SET KCH=考场号,ZWH=座位号 FROM T1 WHERE BMK.BMH=T1.BMH
ENDSCAN
SELECT BMK
BROWSE

是否是楼主所要的结果

*--如果全校考场编号是统一的，代码如下：
SELECT NJDM,KLDM FROM BMK GROUP BY 1,2 INTO CURSOR T
ZKCH=0 &&记录总考场号
SCAN
   SELECT BMH,NJDM,KLDM,SPACE(2) 考场号,SPACE(2) 座位号 FROM BMK WHERE NJDM==T.NJDM AND KLDM==T.KLDM INTO CURSOR T1 READWRITE
   REPLACE ALL 考场号 WITH TRANSFORM(CEILING(RECNO()/30)+ZKCH),座位号 WITH TRANSFORM(IIF(MOD(RECNO(),30)=0,30,MOD(RECNO(),30)))
   GO BOTTOM IN T1
   ZKCH=VAL(考场号)
   UPDATE BMK SET KCH=考场号,ZWH=座位号 FROM T1 WHERE BMK.BMH=T1.BMH
ENDSCAN
SELECT BMK
BROWSE

排考场还有三个要求你没说清：1、是否所有考场的座位号都从1-30，还是说同一年级同一科类的座位号连续；2、同一年级同一科类按每30人一考场分了以后，最后一个考场可能不足30人。这不足30人的考场会不会与其它年级其它科类不足30人的考场合并，还是就单独一个考场；3、所有的考场号是否连续编排，还是另有其它方案？

感谢老师们，我昨天没有说清楚具体要求。
1、编排时要随机打散编排；2、分年级分科类编排，不足30人的不合并，单独一个考场；3、所有座位号都是1-30。

随机打散编排对程序设计有一定要求的。你的考场号如何安排？全部连续编号，还是只在同一年级同一科类连续？

同年级同一科类连续。比如说一年级文史（11）考场1---，一年级理工（12）考场1----；二年级文史考场1----，二年级理工考场1----。

SELECT distinct njdm,kldm FROM bmk INTO CURSOR t
SCAN
   SELECT bmh,njdm,kldm,SPACE(2) 考场号,SPACE(2) 座位号,INT(RAND()*50000) 随机 FROM bmk WHERE njdm==t.njdm AND kldm==t.kldm INTO CURSOR T1 READWRITE  ORDER BY  随机
   REPLACE ALL 考场号 WITH TRANSFORM(CEILING(RECNO()/30)),座位号 WITH TRANSFORM(IIF(MOD(RECNO(),30)=0,30,MOD(RECNO(),30)))
   UPDATE BMK SET KCH=考场号,ZWH=座位号 FROM T1 WHERE BMK.BMH=T1.BMH
ENDSCAN

座位号从01-30是对的，问题是每个年级的考场号都从1号开始吗？还是连着的？学生的试场与座位随机打散是不难的。