写出计算公式

CLOSE TABLES
USE book
GO 1
inta=a201312
intb=a201212
GO 2
REPLACE a201312 WITH (ROUND(inta/intb,2)-1)*100
GO 3
inta=a201312
intb=a201212
GO 4
REPLACE a201312 WITH (ROUND(inta/intb,2)-1)*100

其他类同

SELECT * FROM book INTO CURSOR t1 READWRITE WHERE 项目年度 in ('收入 ','支出 ')
SELECT * FROM t1 INTO CURSOR t2 READWRITE WHERE .f.
INSERT INTO t2 (项目年度) SELECT distinct 项目年度 FROM t1
SELECT t1
SCAN
    FOR i=1 TO FCOUNT('t1')
        IF UPPER(LEFT(FIELD(i,'t1'),1))=='A'
            FIELD_TMP2=FIELD(i,'t1')
            YEAR_TMP2=VAL(SUBSTR(FIELD_TMP2,2,4))
            YEAR_TMP1=YEAR_TMP2-1
            FIELD_TMP1='A'+TRANSFORM(YEAR_TMP1)+SUBSTR(FIELD_TMP2,6,2)
            IF TYPE(FIELD_TMP1)=='N' AND EVALUATE(FIELD_TMP1)<>0
                同比=100*ROUND(EVALUATE(FIELD_TMP2)/EVALUATE(FIELD_TMP1)-1,2)
                REPLACE (FIELD_TMP2) WITH 同比 FOR ALLTRIM(项目年度)==ALLTRIM(t1.项目年度) IN t2
            ENDIF
        ENDIF
    ENDFOR
ENDSCAN
REPLACE  ALL 项目年度 WITH ALLTRIM(项目年度)+'同比% ' IN t2
INSERT INTO t1 SELECT * FROM t2
SELECT * FROM t1 INTO CURSOR t3 ORDER BY 项目年度
SELECT t3
BROWSE

路过

老师布置完作业，人就不见了。

这个数据的结构设计不合理。

SELECT * FROM BOOK INTO CURSOR T1 READWRITE WHERE 项目年度 IN ('收入 ','支出 ')
SELECT ALLTRIM(项目年度)+[03] 项目年度,EVALUATE(FIELD(2)) 本期,EVALUATE(FIELD(6)) 上期,000.00 同比 FROM T1 ;
UNION ALL SELECT ALLTRIM(项目年度)+[06] 项目年度,EVALUATE(FIELD(3)),EVALUATE(FIELD(7)),000.00 同比 FROM T1 ;
UNION ALL SELECT ALLTRIM(项目年度)+[09] 项目年度,EVALUATE(FIELD(4)),EVALUATE(FIELD(8)),000.00 同比 FROM T1 ;
UNION ALL SELECT ALLTRIM(项目年度)+[12] 项目年度,EVALUATE(FIELD(5)),EVALUATE(FIELD(9)),000.00 同比 FROM T1 ;
ORDER BY 1 INTO CURSOR T2 READWRITE
REPLACE ALL 同比 WITH 100*(本期-上期)/上期
BROWSE

SELECT * FROM BOOK INTO CURSOR T1 READWRITE WHERE 项目年度 IN ('收入 ','支出 ')
BQ=[A]+TRANSFORM(YEAR(DATE()))
SQ=[A]+TRANSFORM(YEAR(DATE())-1)
SELECT ALLTRIM(项目年度)+[03] 项目年度,EVALUATE(FIELD(2)) &BQ,EVALUATE(FIELD(6)) &SQ,000.00 同比 FROM T1 ;
UNION ALL SELECT ALLTRIM(项目年度)+[06] 项目年度,EVALUATE(FIELD(3)),EVALUATE(FIELD(7)),000.00 同比 FROM T1 ;
UNION ALL SELECT ALLTRIM(项目年度)+[09] 项目年度,EVALUATE(FIELD(4)),EVALUATE(FIELD(8)),000.00 同比 FROM T1 ;
UNION ALL SELECT ALLTRIM(项目年度)+[12] 项目年度,EVALUATE(FIELD(5)),EVALUATE(FIELD(9)),000.00 同比 FROM T1 ;
ORDER BY 1 INTO CURSOR T2 READWRITE
REPLACE ALL 同比 WITH 100*(&BQ-&SQ)/&SQ
BROWSE

论坛中还是热心人多啊！