在vf的表里有sfzh(身份证号)和ksh(考生号),学生的照片都是以身份证号命名的,现在要把照片批量提取同时替换成与身份证号相对印的考生号
1、数据表在C盘DBF目录下，表名为学生.dbf
2、照片在C盘PIC目录下

程序代码：
CLOSE DATABASES
SET DEFAULT TO C:\PIC
USE c:\dbf\学生.dbf
SCAN
     IF FILE(ALLTRIM(TABNAME.SFZH)+[.JPG])
       RENAME ALLTRIM(TABNAME.SFZH)+[.JPG] TO ALLTRIM(TABNAME.KSH)+[.JPG]
     ENDIF
ENDSCAN
现在能不能不帮我改一下:
                       1、照片批量提取并复制到pic2目录下并同时替换成与身份证号相对印的考生号
                       2、如果没有找到，把没有找到的信息给予提示
谢谢各位师哥师姐

把rename改成copy file，没找到的提示信息就放在if的else分支中即可。

CLOSE DATABASES
path1='C:\PIC\'
path2='C:\PIC2\'
CREATE CURSOR t1 (SFZH c(20))
USE c:\dbf\学生 IN 0
SELECT 学生
SCAN
     IF FILE(path1+ALLTRIM(学生.SFZH)+'.JPG')
         COPY FILE (path1+ALLTRIM(学生.SFZH)+'.JPG') TO (path2+ALLTRIM(学生.KSH)+'.JPG')
     ELSE
         INSERT INTO t1 (SFZH) VALUES (学生.SFZH)
    ENDIF
ENDSCAN
IF RECCOUNT('t1')>0
    =MESSAGEBOX('相片不存在',64,'提示')
    m.out_filename=allt(PUTFILE('','','XLS'))
    IF NOT EMPTY(m.out_filename)
        SELECT t1
        COPY TO (m.out_filename) XLS
    ENDIF
ENDIF
CLOSE DATABASES

CLOSE DATABASES
*SET DEFAULT TO C:\PIC
USE C:\DBF\学生
SCAN
   IF FILE([C:\PIC\]+ALLTRIM(学生.SFZH)+[.JPG])
      COPY FILE [C:\PIC\]+ALLTRIM(学生.SFZH)+[.JPG] TO [C:\PIC2\]+ALLTRIM(学生.KSH)+[.JPG]
      DELETE FILE [C:\PIC\]+ALLTRIM(学生.SFZH)+[.JPG]
   ELSE
      STRTOFILE([C:\PIC\]+ALLTRIM(学生.SFZH)+[.JPG 不存在]+CHR(13)+CHR(10),[C:\DBF\JPG.TXT],.T.)
   ENDIF
ENDSCAN

[ 本帖最后由 sdta 于 2013-5-23 23:32 编辑 ]