本人一点都不了解VB,想求一段 定时移动鼠标的代码过来学习一下

新建一工程，放一个按钮command1，放一个时钟timer1,拷贝下列代码运行，按按钮一下会发现鼠标随机移动，碰到边界会反弹，再按按钮一下（或回车键）会停止。
'*****************************拷贝下列代码*****************************************
Private Type POINTAPI
        x As Long
        y As Long
End Type
Private Declare Function GetCursorPos Lib "user32" (lpPoint As POINTAPI) As Long
Private Declare Function SetCursorPos Lib "user32" (ByVal x As Long, ByVal y As Long) As Long

Dim rndX As Integer, rndY As Integer  '定义随机移动方向和速率

Private Sub Command1_Click()
  If rndX <> 0 And rndY <> 0 Then
    rndX = 0
    rndY = 0
    Exit Sub
  End If
  While rndX = 0
    rndX = Rnd * 20 - 10
  Wend
  While rndY = 0
    rndY = Rnd * 20 - 10
  Wend
End Sub

Private Sub Form_Load()
  Timer1.Interval = 10
End Sub

Private Sub Timer1_Timer()
  Dim pos As POINTAPI, x As Long, y As Long
  If rndX = 0 And rndY = 0 Then
    Rnd
    Exit Sub
  End If
  GetCursorPos pos
  x = pos.x + rndX
  y = pos.y + rndY
  If x < 20 Then
    x = 20
    rndX = rndX * (-1)
  End If
  If x >= Screen.Width / 15 - 60 Then
    x = Screen.Width / 15 - 60
    rndX = rndX * (-1)
  End If
  If y < 20 Then
    y = 20
    rndY = rndY * (-1)
  End If
  If y >= Screen.Height / 15 - 100 Then
    y = Screen.Height / 15 - 100
    rndY = rndY * (-1)
  End If
  SetCursorPos x, y
End Sub

你的这段代码相当于屏保了呀，奇怪的是，我写了一个鼠标移动的，就是不让电脑自己待机，我感觉我的是相当于屏保的功能。按我这笨脑袋想，你这样写法才是真的不会让计算机休眠或待机，可是，结局恰好相反，

你应该可以通过这段代码举一反三的，把这个代码看透了就很容易实现你的功能了。
你所说的需求我以前还真这样做过，十多年前时我设计了一个硬盘播出程序，是vga转tv的那种，播出时是不能屏保或休眠的，我就是用程序定时自动微动一下鼠标来实现的，后来设计了播出卡播出的程序就不需要这个了。
你好厉害啊，刚注册的就当两个版版主了。

[ 本帖最后由 lowxiong 于 2013-5-26 17:10 编辑 ]

收到的鲜花

• Aviva_Wang 于 2013-05-28 22:19 送鲜花  30朵   附言：你才真正的厉害，我今天才写出你十年前写出 ...