| 网站首页 | 业界新闻 | 小组 | 交易 | 人才 | 下载频道 | 博客 | 代码贴 | 在线编程 | 编程论坛
共有 427 人关注过本帖
标题:列表框list编程出错
只看楼主 加入收藏
yusanfengyi
Rank: 1
等 级:新手上路
帖 子:5
专家分:0
注 册:2013-2-8
结帖率:100%
  已结贴   问题点数:20  回复次数:4   
列表框list编程出错
Private Sub cmd1_Click()
Dim i%
While lst1.SelCount > 0
 For i = 0 To lst1.ListCount - 1
  If lst1.Selected(i) = True Then
   lst2.AddItem lst1.Selected(i)
   lst1.RemoveItem i
  End If
netx i
End Sub

运行时出现编译错误 子程序或函数未定义请问错在哪儿了呢?
附件: 您没有浏览附件的权限,请 登录注册
搜索更多相关主题的帖子: 编程 子程序 
2013-02-11 15:12
Artless
Rank: 19Rank: 19Rank: 19Rank: 19Rank: 19Rank: 19
等 级:贵宾
威 望:103
帖 子:4211
专家分:28888
注 册:2009-4-8
  得分:0 
netx i
next i

无知
2013-02-11 18:29
益西翁登
Rank: 4
等 级:业余侠客
威 望:1
帖 子:126
专家分:272
注 册:2010-2-22
  得分:0 
Private Sub Command1_Click()
List2.Clear
For i = 0 To List1.ListCount - 1
List2.AddItem List1.List(i)
Next
List1.Clear
End Sub
2013-02-12 07:02
益西翁登
Rank: 4
等 级:业余侠客
威 望:1
帖 子:126
专家分:272
注 册:2010-2-22
  得分:0 
Option Explicit
'ListBox示例
Private Sub cmdAdd_Click()
    '添加按钮代码
    Dim i As Integer
    i = lstLeft.ListCount                   '获取左列表中的列表项目个数
    lstLeft.AddItem "第" & i & "项目", i    '添加项目
End Sub

Private Sub cmdClear_Click()
    '清空右列表
    lstRight.Clear
End Sub

Private Sub cmdLeft_Click()
    '向左列表移动项目
    Dim n As Integer                            '定义列表项目总数变量
    Dim i As Integer                            '定义遍历变量
    n = lstRight.ListCount - 1                  '获取列表项目总数量
    Do While i <= n                             '遍历列表
        If lstRight.Selected(i) Then            '如果该项目被选中
            lstLeft.AddItem lstRight.List(i)    '左列表添加选中项
            lstLeft.Refresh                     '刷新左列表
            lstRight.RemoveItem i               '右列表中删除选中项
            lstRight.Refresh                    '刷新右列表
            n = n - 1
        Else
            i = i + 1                           '下一个列表项
        End If
    Loop
End Sub

Private Sub cmdRigth_Click()
    '向右列表移动项目
    Dim n As Integer                           '定义列表项目总数变量
    Dim i As Integer                           '定义遍历变量
    n = lstLeft.ListCount - 1                  '获取列表项目总数量
    Do While i <= n                            '遍历列表
        If lstLeft.Selected(i) Then            '如果该项目被选中
            lstRight.AddItem lstLeft.List(i)   '右列表添加选中项
            lstRight.Refresh                   '刷新右列表
            lstLeft.RemoveItem i               '左列表中删除选中项
            lstLeft.Refresh                    '刷新左列表
            n = n - 1
        Else
            i = i + 1                           '下一个列表项
        End If
    Loop
End Sub

Private Sub Form_Load()
    '初始化左列表
    Dim i As Integer
    For i = 0 To 9
        lstLeft.AddItem "第" & i & "项目", i    '为左列表添加列表项
    Next i
End Sub
2013-02-12 07:21
益西翁登
Rank: 4
等 级:业余侠客
威 望:1
帖 子:126
专家分:272
注 册:2010-2-22
  得分:20 
Private Sub Form_Load()
    Dim i As Integer

    For i = 1 To 12
        ListL.AddItem "List Item " & i
    Next i
    SetButtonsState ' 设置按钮初始状态
End Sub

'  将左侧列表框中的指定项目移动到右侧
Private Sub ROne_Btn_Click()
    MoveOneItem ListL, ListR
    SetButtonsState
End Sub

'  将左侧列表框中的所有项目移动到右侧
Private Sub RAll_Btn_Click()
    MoveAllItem ListL, ListR
    SetButtonsState
End Sub

'  将右侧列表框中的指定项目移动到左侧
Private Sub LOne_Btn_Click()
    MoveOneItem ListR, ListL
    SetButtonsState
End Sub

'  将右侧列表框中的所有项目移动到左侧
Private Sub LAll_Btn_Click()
    MoveAllItem ListR, ListL
    SetButtonsState
End Sub

' 从列表框控件删除一条记录
Private Sub ListDelItem(ListCtrl As ListBox, ByVal delIndex As Integer)
   
    If ListCtrl.ListCount > 0 And delIndex >= 0 Then
        ListCtrl.RemoveItem delIndex
        
        If ListCtrl.ListCount > 0 Then
            If ListCtrl.ListCount <= delIndex Then
                ListCtrl.ListIndex = delIndex - 1
            Else
                ListCtrl.ListIndex = delIndex
            End If
        End If
    End If
End Sub

' 移动一条
Private Sub MoveOneItem(SrcList As ListBox, DesList As ListBox)
        
    If SrcList.ListCount > 0 Then
        If SrcList.ListIndex < 0 Then
            SrcList.ListIndex = 0
        End If
        
        DesList.AddItem SrcList.List(SrcList.ListIndex)
        DesList.ItemData(DesList.NewIndex) = SrcList.ItemData(SrcList.ListIndex)
        
        ListDelItem SrcList, SrcList.ListIndex
    End If
End Sub

' 全体移动
Private Sub MoveAllItem(SrcList As ListBox, DesList As ListBox)
    Dim i As Integer
   
    i = 0
    Do While i < SrcList.ListCount
        DesList.AddItem SrcList.List(i)
        DesList.ItemData(DesList.NewIndex) = SrcList.ItemData(i)
        i = i + 1
    Loop
   
    SrcList.Clear
End Sub

' 向源列表框中添加新项目
Private Sub AddICmd_Click()
    ListL.AddItem "List Item new"
End Sub

' 从源列表框中移除项目
Private Sub RemoveICmd_Click()
    If ListL.ListIndex <> -1 Then
        ListL.RemoveItem ListL.ListIndex
    End If
End Sub

' 清空源列表框中项目
Private Sub ClearCmd_Click()
    ListL.Clear
End Sub

' 设置按钮控件是否可用
Private Sub SetButtonsState()
    If ListL.ListCount > 0 Then
        ROne_Btn.Enabled = True
        RAll_Btn.Enabled = True
    Else
        ROne_Btn.Enabled = False
        RAll_Btn.Enabled = False
    End If
      
    If ListR.ListCount > 0 Then
        LOne_Btn.Enabled = True
        LAll_Btn.Enabled = True
    Else
        LOne_Btn.Enabled = False
        LAll_Btn.Enabled = False
    End If
End Sub
2013-02-12 07:27
快速回复:列表框list编程出错
数据加载中...
 
   



关于我们 | 广告合作 | 编程中国 | 清除Cookies | TOP | 手机版

编程中国 版权所有,并保留所有权利。
Powered by Discuz, Processed in 0.072351 second(s), 7 queries.
Copyright©2004-2020, BCCN.NET, All Rights Reserved