代码如下：
Private Declare Function exitwindowsex Lib "user32" (ByVal uFlags As Long, ByVal dwReserved As Long) As Long
-----------
Private Sub Form_Load()
Dim X As Long

Const EWX_SHUTDOWN = 1
Const ewx_logoff = 0
Const ewx_reboot = 2
Const ewx_force = 4
Const ewx_poweroff = 8

X = exitwindowsex(EWX_SHUTDOWN, dwReserved)

End Sub
--------------------------------------
为什么我运行时提示：实时错误‘453’：
找不到DLL入口点exitwindowsex in user32

这句话X = exitwindowsex(EWX_SHUTDOWN, dwReserved)报错
---------------------------------
请各位高手指点迷津！

注意大小写。

Private Declare Function exitwindowsex Lib "user32" (ByVal uFlags As Long, ByVal dwReserved As Long) As Long
Private Sub Form_Load()
Dim X As Long

Const EWX_SHUTDOWN = 1
Const EWX_LOGOFF = 0
Const EWX_REBOOT = 2
Const EWX_FORCE = 4
Const EWX_POWEROFF = 8
Const EWX_RESET = EWX_LOGOFF + EWX_FORCE + EWX_REBOOT
X = exitwindowsex(EWX_REXET, dwReserved)

End Sub

没有用啊，依然是那个错误

很明显，你的是有错的，这个程序是不需要返回值的吧，你直接exitwindowsex EWX_SHUTDOWN, 1 试试，

[ 本帖最后由 a414715440 于 2011-10-4 22:18 编辑 ]

噢，犯了个低级错误。。。
exitwindowsex应该为ExitWindowsEx

但为什么只能注销，而不是重启？？？

这个问题我也试过无数次，只能注销，最好你直接调用系统的，关机程序，

什么叫“直接调用系统的，关机程序”？？？？？

Option Explicit

Private Type LUID
UsedPart As Long
IgnoredForNowHigh32BitPart As Long
End Type

Private Type TOKEN_PRIVILEGES
PrivilegeCount As Long
TheLuid As LUID
Attributes As Long
End Type

' Beginning of Code
Private Const EWX_SHUTDOWN As Long = 1
Private Const EWX_FORCE As Long = 4
Private Const EWX_REBOOT = 2

Private Declare Function ExitWindowsEx Lib "user32" ( _
ByVal dwOptions As Long, ByVal dwReserved As Long) As Long

Private Declare Function GetCurrentProcess Lib "kernel32" () As Long
Private Declare Function OpenProcessToken Lib "advapi32" ( _
ByVal ProcessHandle As Long, ByVal DesiredAccess As Long, _
TokenHandle As Long) As Long
Private Declare Function LookupPrivilegeValue Lib "advapi32" _
Alias "LookupPrivilegeValueA" (ByVal lpSystemName As String, _
ByVal lpName As String, lpLuid As LUID) As Long
Private Declare Function AdjustTokenPrivileges Lib "advapi32" ( _
ByVal TokenHandle As Long, ByVal DisableAllPrivileges As Long, _
NewState As TOKEN_PRIVILEGES, ByVal BufferLength As Long, _
PreviousState As TOKEN_PRIVILEGES, ReturnLength As Long) As Long
Private Sub AdjustToken()

Const TOKEN_ADJUST_PRIVILEGES = &H20
Const TOKEN_QUERY = &H8
Const SE_PRIVILEGE_ENABLED = &H2
Dim hdlProcessHandle As Long
Dim hdlTokenHandle As Long
Dim tmpLuid As LUID
Dim tkp As TOKEN_PRIVILEGES
Dim tkpNewButIgnored As TOKEN_PRIVILEGES
Dim lBufferNeeded As Long

hdlProcessHandle = GetCurrentProcess()
OpenProcessToken hdlProcessHandle, (TOKEN_ADJUST_PRIVILEGES Or _
TOKEN_QUERY), hdlTokenHandle

' Get the LUID for shutdown privilege.
LookupPrivilegeValue "", "SeShutdownPrivilege", tmpLuid

tkp.PrivilegeCount = 1 ' One privilege to set
tkp.TheLuid = tmpLuid
tkp.Attributes = SE_PRIVILEGE_ENABLED

' Enable the shutdown privilege in the access token of this
' process.
AdjustTokenPrivileges hdlTokenHandle, False, tkp, _
Len(tkpNewButIgnored), tkpNewButIgnored, lBufferNeeded

End Sub

Private Sub cmdForceShutdown_Click()
AdjustToken
ExitWindowsEx (EWX_SHUTDOWN Or EWX_FORCE Or EWX_REBOOT), &HFFFF
End Sub

有些需要提权。

版主，帮我的那个贴子看看吧，就在他的这个贴子下面，

作为菜鸟的我彻底晕了，版主就是
牛！