比如：有这个表
bz     rs      ycbt
f50    10     633600
f55    5      244800
m60    35    1209600
转换为
bz       f50         f55         m60
rs       10          5           35
ycbt    633600      244800      1209600
请问如何实现？

execel中复制——选择性粘贴：转置 ok了
写代码的话先建好新表
scan循环扫描数据填充新纪录

能否具体一点。谢谢！

CREATE CURSOR tb1 (bz c(8),rs c(8),ycbt c(8))
INSERT INTO tb1 VALUES ("f50","10","633600")
INSERT INTO tb1 VALUES ("f55","5","1244800")
INSERT INTO tb1 VALUES ("m60","35","11209600")

***程序没有对字段宽度和字段类型作任何判断，假定为全部为字符型，宽度不超20字符可以容纳，
***且tb1第一列全部数据可以直接作字段名，并且没有重复
AFIELDS(arr1,"tb1")
tbstru="create cursor tb2 (&arr1(1,1). c(20)"    &&字段宽度没有作严格的判断，可以自己完善
SCAN
    tbstru=tbstru+","+ALLTRIM(&arr1(1,1).)+" c(20)"
ENDSCAN
?tbstru+")"
EXECSCRIPT(tbstru+")")

AFIELDS(arr2,"tb2")
FOR i=2 TO ALEN(arr1,1)
    INSERT INTO tb2 (&arr1(1,1).) VALUES (arr1(i,1))
ENDFOR

CLEAR
FOR j=2 TO ALEN(arr1,1)
        SELECT tb1
        SCAN
            mval="tb1."+arr1(j,1)
            EXECSCRIPT("update tb2 set "+arr2(RECNO("tb1")+1,1)+"=["+&mval.+"] where "+arr2(1,1)+"=["+arr1(j,1)+"]")
        ENDSCAN
ENDFOR
SELECT tb2
BROWSE

非常感谢！不过EXECSCRI(tbstru+")")是不是写错了。运行后提示EXECSCRI.prg不存在。

EXECSCRIPT()

上面的代码运行通过。
execscript()及时省略后面两个字母，VFP也应该是可以识别的，因为不存在产生二义的另外的函数

运行环境，vfp9.0，如果低版本没有这个函数，改成宏替换吧
CREATE CURSOR tb1 (bz c(8),rs c(8),ycbt c(8))
INSERT INTO tb1 VALUES ("f50","10","633600")
INSERT INTO tb1 VALUES ("f55","5","1244800")
INSERT INTO tb1 VALUES ("m60","35","11209600")

***程序没有对字段宽度和字段类型作任何判断，假定为全部为字符型，宽度不超20字符可以容纳，
***且tb1第一列全部数据可以直接作字段名，并且没有重复
AFIELDS(arr1,"tb1")
tbstru="create cursor tb2 (&arr1(1,1). c(20)"    &&字段宽度没有作严格的判断，可以自己完善
SCAN
    tbstru=tbstru+","+ALLTRIM(&arr1(1,1).)+" c(20)"
ENDSCAN
tbstru=tbstru+")"
&tbstru.

AFIELDS(arr2,"tb2")
FOR i=2 TO ALEN(arr1,1)
    INSERT INTO tb2 (&arr1(1,1).) VALUES (arr1(i,1))
ENDFOR

CLEAR
FOR j=2 TO ALEN(arr1,1)
        SELECT tb1
        SCAN
            mval="tb1."+arr1(j,1)
            upstr="update tb2 set "+arr2(RECNO("tb1")+1,1)+"=["+&mval.+"] where "+arr2(1,1)+"=["+arr1(j,1)+"]"
            &upstr.
        ENDSCAN
ENDFOR
SELECT tb2
BROWSE

CREATE CURSOR tb1 (bz c(8),rs c(8),ycbt c(8))
INSERT INTO tb1 VALUES ("f50","10","633600")
INSERT INTO tb1 VALUES ("f55","5","1244800")
INSERT INTO tb1 VALUES ("m60","35","11209600")
AFIELDS(cc)
COPY TO ARRAY aa fields rs, ycbt
LOCAL bb[ALEN(aa, 2), ALEN(aa, 1)]
FOR lnj = 1 TO ALEN(aa)
    la1 = asubscript(aa, lnj, 1)
    la2 = asubscript(aa, lnj, 2)
    bb[la2, la1] = aa[lnj]
ENDFOR
lcStr = "bz c(10)"
lcZdm = ""
SCAN 
    lcStr = lcStr + ", " + ALLTRIM(bz) + " c(10)"
    lcZdm = lcZdm + IIF(EMPTY(lcZdm), "", ",") + ALLTRIM(bz)
ENDSCAN 

CREATE CURSOR tt (&lcStr)
FOR lnj = 2 TO ALEN(cc, 1)
    INSERT INTO tt (bz) VALUES (cc[lnj, 1])
ENDFOR
REPLACE FROM ARRAY bb FIELDS &lcZdm ALL 
BROWSE