我是个新手想请教各位老师一个问题；用户多条记录如何合并成一条记录如下：
日期   客户    金额   顺序号  
2009   XM      50       1
2009   XM      60       1
2009   XM      70       1
2009   XM      80       1
2009   JM      100      2
2009   JM      200      2
2009   JM      300      2  
2009   JM      400      2
想要合并后是这样的效果
日期   客户    金额    金额1  金额2 金额3    金额3  顺序号
2009   XM       50     60      70    80               1
2009   JM       100    100     200   300      400     2
请问这个该如何去处理呢？
谢谢！

close all
create table tblTemp (日期 N(4),客户 C(8),金额 N(4),顺序号 N(1))
insert into tblTemp values (2009,'XM', 50,1)
insert into tblTemp values (2009,'XM', 60,1)
insert into tblTemp values (2009,'XM', 70,1)
insert into tblTemp values (2009,'XM', 80,1)
insert into tblTemp values (2009,'JM',100,2)
insert into tblTemp values (2009,'JM',100,2)
insert into tblTemp values (2009,'JM',200,2)
insert into tblTemp values (2009,'JM',300,2)
insert into tblTemp values (2009,'JM',400,2)
select count(*) as cnt from tbltemp group by 客户 into table tblTemp1
select max(cnt) from tblTemp1 into array laMyArr
lc='(日期 N(4),客户 C(8),金额 N(4)'
for lnCnt=1 to laMyArr(1)-1
  lc=lc+',金额'+alltrim(str(lnCnt))+' N(4)'
endfor
lc=lc+',顺序号 N(1))'
create table tblTemp2 &lc
select tblTemp
scan
  select tblTemp2
  locate for 客户=tblTemp.客户
  if eof()
    append blank
    replace 日期 with tblTemp.日期,客户 with tblTemp.客户,金额 with tblTemp.金额,顺序号 with tblTemp.顺序号
  else
    for lnCnt=4 to fcount()-1
      lc=field(lnCnt)
      if empty(&lc)
        exit
      endif
    endfor
    replace &lc with tblTemp.金额
  endif
endscan
select tblTemp2
brow
return

老师如果是很多个客户是不是也一样一个一个用insert into 做呢？谢谢！

你给的数据，我没有现成的表，只好做一个表。实际上，你应该是通过其他的途径得到tblTemp这个表的，后面的就用这个表来处理。看回复应该知道回复者的无奈。

我不太懂这个了，是想学学怎么做呵呵，不好意思刚学这个好多都不会啊。我才学没几天，能否告诉我详细一点，如果有很多个客户也是用这样的方法吗？

特别提醒，同一个客户如果记录超过251个就有麻烦了。

不同客户的数量无论多少都没有关系，但同一个客户的记录不可以太多。

谢谢楼主分享！！！！！

典型的列记录转换为行记录