下面这些是个批处理，运行后减少XP的滚动条的滚动次数，我运行后，启动次数从二十多圈减少到一圈，很管用，但是有一个问题就是光驱的盘符不见了，不知道下面这些代码那句不对，我的电脑上IDE1接的是硬盘，主盘位置；IDE2接的光驱，从盘位置，谁能帮我看看每句代码什么意思，哪句不对，怎么解决我遇到的问题，谢谢各位了


:: 修改IDE通道检测设备模式，不接设备的设置为无，提高XP启动速度
:: 建议在系统第二次重新启动检测到所有已经安装的IDE设备后运行
:: Author: Climbing(xclimbing@)
:: Date: 2006.10.28
@set _debug=
@echo %_debug% off & setlocal ENABLEDELAYEDEXPANSION
set hkey1=HKLM\SYSTEM\CurrentControlSet\Enum\PCIIDE\IDEChannel
set hkey2=HKLM\SYSTEM\CurrentControlSet\Control\Class
for /f "usebackq tokens=*" %%I in (`reg query %hkey1% ^| find /i "IDEChannel\"`) do call :_check "%%I"
goto :eof

:_check
::echo %1
set subkey=
for /f "usebackq tokens=3*" %%J in (`reg query %1 ^| find /i "driver"`) do set subkey=%%J
set DriverDesc=
for /f "usebackq tokens=3,4*" %%K in (`reg query "%hkey2%\%subkey%" /v DriverDesc ^| find /i "driverdesc"`) do set DriverDesc=%%K %%L 通道
reg query "%hkey2%\%subkey%" /v MasterDeviceType | find /i "0x1" > nul
if %errorlevel%==1 goto _ChgMaster
goto _CheckSlave

:_ChgMaster
reg add "%hkey2%\%subkey%" /v UserMasterDeviceType /t REG_DWORD /d 3 /f
echo “%DriverDesc%”的设备0检测方式设置为无。

:_CheckSlave
reg query "%hkey2%\%subkey%" /v SlaveDeviceType | find /i "0x1" > nul
if %errorlevel%==1 goto _ChgSlave
goto :eof

:_ChgSlave
reg add "%hkey2%\%subkey%" /v UserSlaveDeviceType /t REG_DWORD /d 3 /f
echo “%DriverDesc%”的设备1检测方式设置为无。
goto :eof

[ 本帖最后由 whm2n 于 2009-8-16 21:21 编辑 ]

看了上面介绍的原理：
修改IDE通道检测设备模式，不接设备的设置为无。

自己通过修改系统属性就可以了。不需要通过批处理。
控制面板->系统->设备管理器,修改相关的设置。
能百度到答案更好。实在不知道可以pm我或加QQ。

转一个搜索到的帖子。百度关键词用：IDE通道 关闭设备

关闭IDE通道自动检测,使计算机启动如飞

计算机启动速度很慢有非常多的原因,也有很多的办法可以让启动速度提升.但是在我用了很多的方法后,计算机启动的速度也没有太大的改善.原来我的计算机启动时滚动条要滚7圈才能进去,感觉很慢,让人等得受不了,一次在去修电脑的时候才明白,原来XP滚动条滚动的圈数直接跟系统搜索IDE通道直接相关,设置了主要和次要IDE通道为无后,我的计算机在启动的时候滚动了一圈就进去了,启动时间也快了许多,大家计算机启动慢的话也可以试试.下面有点IDE的知识.大家可以看看.设置的具体方法在下段的后面粗体内容. IDE的英文全称为“Integrated Drive Electronics”，即“电子集成驱动器”，它的本意是指把“硬盘控制器”与“盘体”集成在一起的硬盘驱动器。把盘体与控制器集成在一起的做法减少了硬盘接口的电缆数目与长度，数据传输的可靠性得到了增强，硬盘制造起来变得更容易，因为硬盘生产厂商不需要再担心自己的硬盘是否与其它厂商生产的控制器兼容。对用户而言，硬盘安装起来也更为方便。IDE这一接口技术从诞生至今就一直在不断发展，性能也不断的提高，其拥有的价格低廉、兼容性强的特点，为其造就了其它类型硬盘无法替代的地位。一般每个主板上有两个IDE接口（IDE1和IDE2）。每个接口可以分别接两个硬盘或者两个光驱。在机箱内主板上连接硬盘和光驱的接口就是IDE接口。所以IDE通道就是用来管理硬盘读写的通道（或者是光驱）。一般来讲主要的IDE接口是接硬盘的，次要的是接光驱的。所以主要和次要的IDE通道分别是管理硬盘和光驱的读写的通道。在计算机我的电脑属性设备管理器里面，可用看到IDE通道，在IDE ATI/ATIPI控制器的目录下。在IDE通道的属性里面可用看到，IDE的一些基本的属性和设置项目，包括常规，高级设置，驱动程序，详细信息，资源5个选项。在常规选项里面主要显示该IDE的基本属性，制造商，运行状态等。在高级设置里面有设备类型和传送模式两个选项，设备类型里面有自动检测和无两个选项。自动检测是指对硬盘接口就是（就是IDE接口）的检测，这一项在一般情况下可以改成“无”，这样对设备不会有什么伤害，可以提高系统的启动速度。传送模式有DMA（若可用）和仅PIO两种。DMA的意思是直接内存访问，是一种不经过CPU而直接从内存了存取数据的数据交换模式。在DMA模式下，CPU只须向DMA控制器下达指令，让DMA控制器来处理数的传送，数据传送完毕再把信息反馈给CPU，这样就很大程度上减轻了CPU资源占有率。PIO模式是一种通过CPU执行I/O端口指令来进行数据的读写的数据交换模式。是最早先的硬盘数据传输模式，数据传输速率低下，CPU占有率也很高。另外还有一种Ultra DMA模式，这种模式的含义是高级直接内存访问。UDMA模式采用16-bit Multi-Word DMA（16位多字节DMA）模式为基准，可以理解为DMA模式的增强版本，它在包含了DMA模式的优点的基础上，又增加了CRC（Cyclic Redundancy Check循环冗余码校验）技术，提高数据传输过程中的准确性，安全性得到保障。在IDE属性里的另外三个选项里面。驱动程序和详细信息是IDE的驱动和详细信息的说明。资源一项是对其输入输出的范围的说明和详细的说明。随着技术的发展，IDE技术不断完善。由于其价格低，兼容性好等优点比较受欢迎。 关闭IDE通道自动检测,避免系统无效检测 Windows XP在启动时会自动重新检测所有IDE通道上的硬盘。如果其中有的IDE通道不存在，那么检测速度就会变得比较缓慢，系统的启动自然也被拖慢了。其实，如果你的IDE设备长期保持不变，比方说就只使用一个硬盘，那么就可以将不用的IDE通道设置为无，这样，系统在启动时便不会在该IDE通道上做无用的测试，节约了宝贵的启动时间。 在“我的电脑”上点击右键，依次选择“属性”→“硬件”→“设备管理器”，分别进入“主要IDE通道”和“次要IDE通道”，在其属性菜单中将不使用的设备类型改为“无”即可。 当然，如果你经常更换IDE设备（经常拆卸和添加），那么以上的方法就不适用了。 经过这样的设置以后相信你的计算机启动时滚动条滚动的圈数会显著减少的.启动时间大大减少. 此外，还有一些比较常用的方式例如禁止索引文件的产生、清空Prefetch文件夹、进行磁盘碎片整理、清理注册表、关闭文件和打印机共享、去除不需要的自启动项目等等，网络上有非常多的介绍，在此就不赘述了。现在快来为你的系统“策马扬鞭”吧！

@ ECHO.
@ ECHO.
@ ECHO.                               说   明
@ ECHO --------------------------------------------------------------------------
@ ECHO  IDE通道在这里看：设备管理器---IDE ATA/ATAPI控制器。一般可看到两个或多个。
@ ECHO  其属性内的“设备类型”，系统默认是“自动检测”，把它设为“无”可以提高
@ ECHO  开机速度。但如果以后要接硬盘或光驱，请记得把相应的通道改为“自动检测”，
@ ECHO  否则进系统后看不到它们。
@ ECHO --------------------------------------------------------------------------
@ ECHO.
@ pause
@shift
:: 修改IDE通道检测设备模式，不接设备的设置为无，提高XP启动速度
:: 建议在系统第二次重新启动检测到所有已经安装的IDE设备后运行
:: Author: Climbing(xclimbing@)
:: Date: 2006.10.28
:: 修正:顽固不化(http://zzz.)  
:: Date:2008.04.02
@set _debug=
@echo %_debug% off & setlocal ENABLEDELAYEDEXPANSION
set hkey1=HKLM\SYSTEM\CurrentControlSet\Enum\PCIIDE\IDEChannel
set hkey2=HKLM\SYSTEM\CurrentControlSet\Control\Class
echo 检测开始.........
for /f "usebackq tokens=*" %%I in (`reg query %hkey1% ^| find /i "IDEChannel\"`) do call :_check "%%I"
@ ECHO.
@ ECHO.
@ ECHO.
echo IED通道检测设备模式设置完成。
@ ECHO.
pause  
goto :eof
 
:_check
::echo %1
set subkey=
for /f "usebackq tokens=3*" %%J in (`reg query %1 ^| find /i "driver"`) do set subkey=%%J
set DriverDesc=
for /f "usebackq tokens=3,4*" %%K in (`reg query "%hkey2%\%subkey%" /v DriverDesc ^| find /i "driverdesc"`) do set DriverDesc=%%K %%L 通道
reg query "%hkey2%\%subkey%" /v MasterDeviceType | find /i "0x0" > nul
if not %errorlevel%==1 goto _ChgMaster
echo “%DriverDesc%”的设备0上有设备存在。
goto _CheckSlave
 
:_ChgMaster
reg add "%hkey2%\%subkey%" /v UserMasterDeviceType /t REG_DWORD /d 3 /f >nul
echo “%DriverDesc%”的设备0上无设备，系统“检测方式”设置为无。
 
:_CheckSlave
reg query "%hkey2%\%subkey%" /v SlaveDeviceType | find /i "0x0" > nul
if not %errorlevel%==1 goto _ChgSlave
echo “%DriverDesc%”的设备1上有设备存在。
goto :eof
 
:_ChgSlave
reg add "%hkey2%\%subkey%" /v UserSlaveDeviceType /t REG_DWORD /d 3 /f >nul
echo “%DriverDesc%”的设备1上无设备，系统“检测方式”设置为无。
goto :eof


这是我电脑上的，电脑公司特别版的，不过我现在用的可是浩海技术的XP，我还有特别版的GHO