请问 怎样用vb画图 我是用mscomm控件从串口读出一个数据，每隔一秒取一次值。以时间为横轴，数值为纵轴，画一条实时曲线，用vb 怎样实现。请各位高手帮忙！！

先把数据拿来看看

线由点组成,画点函数pset(x,y),vbcolorname
如以下假代码
x=time++
y=data++
PSet (x, y), vbColorName

'下面的是clsCurve类模块
  '===========================================================
  Option Explicit
   
  Private m_hMemDC     As Long
  Private m_hBakDC     As Long
  Private m_hOutDC     As Long
  Private m_hOldMemBmp     As Long
  Private m_hOldBakBmp     As Long
  Private m_hOldMemPen     As Long
  Private m_hBrush     As Long
   
  Private m_nXUnitLen     As Long
  Private m_nYUnitLen     As Long
  Private m_nPrevY     As Long
  Private R     As RECT
      
  Public Sub SetView(ByVal hOutDC As Long, _
                                                  ByVal nWidth As Long, _
                                                  ByVal nHeight As Long, _
                                                  ByVal nXUnits As Long, _
                                                  ByVal nYUnits As Long)
            
          Dim hObject     As Long
          m_hOutDC = hOutDC
          R.Left = 0:       R.Top = 0
          R.Bottom = nHeight
          R.Right = nWidth
          m_nXUnitLen = nWidth \ nXUnits
          m_nYUnitLen = nHeight \ nYUnits
            
          m_hMemDC = CreateCompatibleDC(hOutDC)
          m_hBakDC = CreateCompatibleDC(hOutDC)
            
            
          hObject = CreateCompatibleBitmap(hOutDC, nWidth, nHeight)
          m_hOldMemBmp = SelectObject(m_hMemDC, hObject)
            
          hObject = CreateCompatibleBitmap(hOutDC, nWidth, nHeight)
          m_hOldBakBmp = SelectObject(m_hBakDC, hObject)
            
          hObject = CreatePen(0, 1, vbBlack)
          m_hOldMemPen = SelectObject(m_hMemDC, hObject)
            
          m_hBrush = CreateSolidBrush(vbWhite)
          FillRect m_hMemDC, R, m_hBrush
          BitBlt m_hOutDC, 0, 0, nWidth, nHeight, m_hMemDC, 0, 0, vbSrcCopy
            
  End Sub
   
   
  Public Sub DrawCurve(ByVal nY As Long)
            
          '保留原来的曲线
          Dim nWidth     As Long, nHeight       As Long
          nWidth = R.Right
          nHeight = R.Bottom
            
          BitBlt m_hBakDC, 0, 0, nWidth, nHeight, m_hMemDC, 0, 0, vbSrcCopy
          FillRect m_hMemDC, R, m_hBrush
          '向左退移1个单位
          BitBlt m_hMemDC, 0, 0, nWidth, nHeight, m_hBakDC, m_nXUnitLen, 0, vbSrcCopy
            
          '画新的曲线
          Dim PrevPoint     As POINTAPI
          nY = nHeight - CLng(nY * m_nYUnitLen)
          MoveToEx m_hMemDC, nWidth - m_nXUnitLen, m_nPrevY, PrevPoint
            
          LineTo m_hMemDC, nWidth - 1, nY
   
          m_nPrevY = nY
            
          '输出结果
   
          BitBlt m_hOutDC, 0, 0, nWidth, nHeight, m_hMemDC, 0, 0, vbSrcCopy
            
  End Sub
   
   
   
   
  Public Sub RedrawCurve()
          If m_hMemDC = 0 Then Exit Sub
          BitBlt m_hOutDC, 0, 0, R.Right, R.Bottom, m_hMemDC, 0, 0, vbSrcCopy
  End Sub
   
  Public Property Get hdc() As Long
          hdc = m_hMemDC
  End Property
   
   
  Private Sub Class_Terminate()
          Dim hMemUsedBmp     As Long, hBakUsedBmp       As Long
          Dim hMemUsedPen     As Long
            
          hMemUsedBmp = SelectObject(m_hMemDC, m_hOldMemBmp)
          hBakUsedBmp = SelectObject(m_hBakDC, m_hOldBakBmp)
          hMemUsedPen = SelectObject(m_hMemDC, m_hOldMemPen)
         
          DeleteDC m_hMemDC
          DeleteDC m_hBakDC
            
          DeleteObject hMemUsedBmp
          DeleteObject hBakUsedBmp
          DeleteObject hMemUsedPen
          DeleteObject m_hBrush
  End Sub

  '下面的是modGDI模块
  '===========================================================
  Option Explicit
  Public Type POINTAPI
                  x   As Long
                  y   As Long
  End Type
   
  Public Type RECT
                  Left   As Long
                  Top   As Long
                  Right   As Long
                  Bottom   As Long
  End Type
   
  Public Declare Function LineTo Lib "gdi32" (ByVal hdc As Long, ByVal x As Long, ByVal y As Long) As Long
  Public Declare Function MoveToEx Lib "gdi32" (ByVal hdc As Long, ByVal x As Long, ByVal y As Long, lpPoint As POINTAPI) As Long
  Public Declare Function CreateCompatibleDC Lib "gdi32" (ByVal hdc As Long) As Long
  Public Declare Function DeleteDC Lib "gdi32" (ByVal hdc As Long) As Long
  Public Declare Function SelectObject Lib "gdi32" (ByVal hdc As Long, ByVal hObject As Long) As Long
  Public Declare Function DeleteObject Lib "gdi32" (ByVal hObject As Long) As Long
  Public Declare Function CreateCompatibleBitmap Lib "gdi32" (ByVal hdc As Long, ByVal nWidth As Long, ByVal nHeight As Long) As Long
  Public Declare Function CreateSolidBrush Lib "gdi32" (ByVal crColor As Long) As Long
  Public Declare Function CreatePen Lib "gdi32" (ByVal nPenStyle As Long, ByVal nWidth As Long, ByVal crColor As Long) As Long
  Public Declare Function BitBlt Lib "gdi32" (ByVal hDestDC As Long, ByVal x As Long, ByVal y As Long, ByVal nWidth As Long, ByVal nHeight As Long, ByVal hSrcDC As Long, ByVal xSrc As Long, ByVal ySrc As Long, ByVal dwRop As Long) As Long
  Public Declare Function FillRect Lib "user32" (ByVal hdc As Long, lpRect As RECT, ByVal hBrush As Long) As Long
   
  '下面的是frmMain窗体，注意自己创建控件
  '===========================================================
  Option Explicit
  Dim CurveDrawer     As clsCurve
   
  Private Sub cmdDemo_Click()
          Dim nY     As Long
          CurveDrawer.SetView picOut.hdc, picOut.Width - 10, picOut.Height - 10, 50, 50
          Timer.Enabled = True
  End Sub
   
  Private Sub Form_Load()
          ScaleMode = 3
          Timer.Interval = 500
          Timer.Enabled = False
          Set CurveDrawer = New clsCurve
  End Sub
   
  Private Sub picOut_Paint()
          CurveDrawer.RedrawCurve
  End Sub
   
  Private Sub Timer_Timer()
          CurveDrawer.DrawCurve CLng(Rnd * 51)
  End Sub

高手，看的不是太懂

研究一下这个BitBlt 就能处理这个问题了。

研究[bc05]

其中，voltage的值保持7600左右，如果没有变化的话，画出的就什么都没有.
为什么呢？

Option Explicit

Dim OutBuf(0 To 0) As Byte
Dim InBuf() As Byte
Dim CheckSum As String
Dim Voltage, Current As Integer

Dim CurveDrawer     As clsCurve

Private Sub Command1_Click()
    Dim nY     As Long
    CurveDrawer.SetView picOut.hdc, picOut.Width - 10, picOut.Height - 10, 790, 590
    Timer1.Enabled = True
End Sub
Private Sub picOut_Paint()
         CurveDrawer.RedrawCurve
End Sub

Private Sub Exit_Click()
    If MSComm1.PortOpen = True Then
        MSComm1.PortOpen = False
    End If

    Unload Form1
End
End Sub

Private Sub Form_Load()
'''''''''''''''''''''''''''''''''''''''''''''''
'
'''''''''''''''''''''''''''''''''''''''''''''''
picOut.Width = 12000
picOut.Height = 9000
ScaleMode = 3
Timer1.Interval = 100
Timer1.Enabled = False
Set CurveDrawer = New clsCurve


'''''''''''''''''''''''''''''''''''''''''''''''
'
'''''''''''''''''''''''''''''''''''''''''''''''
= 1                     '?è?¨Com1
MSComm1.Settings = "9600,n,8,1"         '9600?¨???????????é??8??????????1????????
MSComm1.InBufferSize = 40
MSComm1.OutBufferSize = 40
MSComm1.InputMode = 1
MSComm1.InputLen = 0
MSComm1.SThreshold = 0
MSComm1.InBufferCount = 0               '??????????????
MSComm1.OutBufferCount = 0              '????·?????????
'MSComm1.RThreshold = 1
     
On Error Resume Next
Err.Clear
If MSComm1.PortOpen = False Then
    MSComm1.PortOpen = True
   
    If Err Then
    MsgBox "?????¨?????§"
    Exit Sub
    End If

End If
End Sub

Sub TimeDelay(DT As Long)
Dim tt As Long

tt = GetTickCount()
Do
DoEvents
Loop Until GetTickCount - tt >= DT
End Sub

Private Sub Stop_Click()
CommandFlag = True
SendCommand = "STOP"
End Sub
Public Sub SEND_REC(BT As Byte, CNT As Integer)
        OutBuf(0) = CByte(BT)
        MSComm1.InBufferCount = 0
        MSComm1.Output = OutBuf
        TimeDelay (100)
        Do
        DoEvents
        Loop Until MSComm1.InBufferCount = CNT
        
        ReDim InBuf(CNT)
        InBuf = MSComm1.Input
        MSComm1.InBufferCount = 0
        
        If InBuf(0) <> OutBuf(0) Then
            MsgBox "ERROR COMMUNICATION"
        End If
End Sub

Private Sub Timer1_Timer()

Dim i As Integer
...
CurveDrawer.DrawCurve CLng(Voltage / 20)
picOut.Refresh

End Sub

attach the picture

啊，我也想问这个问题呢。。