asp生成html网页的原理。
看了许多网上的教程，都是只举例子，不讲原理。有哪位可以比较详细的讲一下原理，不必举例子的。或者有没有好的教材，给个链接地址，谢谢啦。

在线等ing

html文件用记事本打开,里面也就是很多的html标签和内容什么的组成的

而asp用fso可以新建一个文件,然后向文件中写入这些标签和内容,最后把文件保存为扩展名为html的格式,这样一个html文件就生成了.

就像你新建一个txt文件,然后手工输入代码,然后保存,最后在把txt换成html,效果是一样的.只不过一个是利用fso,一个是你手工操作

<%
createmodefile "tt","txtfile","a.asp" '这是调用函数

function createmodefile(filename,txtfilename,htmfile)
set filefso =Server.CreateObject("Scripting.FileSystemObject")
if not filefso.FolderExists(server.MapPath(filename)) then
set filefsofile=filefso.CreateFolder(server.MapPath (filename))'创建文件夹
end if
createfile filename,txtfilename,htmfile
response.Write("全部创建成功")
end function

function createfile(filename,txtfilename,htmfile)'创建htm文件函数
url="http://"&Request.ServerVariables("SERVER_NAME")& left(Request.ServerVariables("URL"),InstrRev(Request.ServerVariables("URL"),"/"))&htmfile
set fso =Server.CreateObject("Scripting.FileSystemObject")
set fout =fso.CreateTextFile(server.mappath(filename&"/"&txtfilename&".htm"),true)
pencat=GetResult(url)
fout.writeline pencat
fout.close
end function

Function GetResult(URL)
strReturn = ""
Set oSend = CreateObject("MSXML2.XMLHTTP")
oSend.Open "GET",URL,false
oSend.Send()
Result = oSend.ResponseBody
Set oSend = Nothing
If Err.Number <> 0 Then
Exit Function
End If
For ii = 1 To LenB(Result)
ThisCharCode = AscB(MidB(Result,ii,1))
If ThisCharCode < &H80 Then
strReturn = strReturn & Chr(ThisCharCode)
Else
NextCharCode = AscB(MidB(Result,ii+1,1))
strReturn = strReturn & Chr (CLng(ThisCharCode) * &H100 + CInt(NextCharCode))
ii = ii + 1
End If
Next
GetResult = strReturn
End Function
%>

1、ASP两种简单的生成静态首页的方法


为什么要生成静态首页？
1、如果你首页读取的数据库次数比较多，速度很慢，而且占用很多服务器资源。使用静态页面访问速度当然快多了
2、搜索引擎容易搜索到
3、如果程序出问题，也能保证首页能访问。
4、其他的太多，自己想：）
应用方式：
如果你的首页是index.asp,你可以生成index.htm （默认访问顺序必须是index.htm,index.asp）。这样访问者第一次访问到你的网站的时候打开的是index.htm 。你可以把网站首页的链接做成index.asp，这样从网站任何一个页面点击首页的链接出现的就是index.asp,这样保证的信息更新的及时性（毕竟index.htm需要每次手动更新）。
方法一：
直接将首页文件包含在表单文本框中，将首页代码最为数据提交，然后生成静态页面。
代码如下：
<%
'------------------------------------------------------------
'使用表单提交生成静态首页的代码
'确保你的空间支持FSO，且首页代码内容较少
'------------------------------------------------------------
dim content
content=Trim(Request.Form("content"))
if content<>"" then
call makeindex()
end if
sub makeindex()
  Set Fso = Server.CreateObject("Scripting.FileSystemObject")
  Filen=Server.MapPath("index.htm")
  Set Site_Config=FSO.CreateTextFile(Filen,true, False)
  Site_Config.Write content
  Site_Config.Close
  Set Fso = Nothing
  Response.Write("<script>alert('已经成功生成首页！')</script>")
end sub
%>
<form name="form1" method="post" action="">
 <textarea name="content">
<!-- ＃i nclude file="index.asp" -->
</textarea>
 <br>
 <input type="submit" name="Submit" value="提交">
</form>
缺点：
1、如果首页中包括<@ ..>标记，会提示出错。
2、如果首页代码较长，用表单无法提交过去（表单数据长度有一定的限制）。
解决方案：
1、去掉index.asp中的<@ >标记
2、使用eWebEditor，提交支持大数据（能自动分割）
优点：
可以在生成时对内容实时修改。
方法二：
直接使用XMLHTTP获取index.asp的代码

<%
'----------------------------------------------------------
'使用XMLHTTP生成静态首页的代码
'Curl 为你的首页地址，确保你的空间支持FSO
'-----------------------------------------------------------
dim read,Curl,content
Curl="http://www.
read=getHTTPPage(Curl)
if read<>"" then
  content=read
  call makeindex()
end if
sub makeindex()
  Set Fso = Server.CreateObject("Scripting.FileSystemObject")
  Filen=Server.MapPath("index.htm")
  Set Site_Config=FSO.CreateTextFile(Filen,true, False)
  Site_Config.Write content
  Site_Config.Close
  Set Fso = Nothing
  Response.Write("<script>alert('已经成功生成首页！')</script>")
end sub
Function getHTTPPage(url)
  dim http
  set http=Server.createobject("Microsoft.XMLHTTP")
  Http.open "GET",url,false
  Http.send()
  if Http.readystate<>4 then
    exit function
  end if
  getHTTPPage=bytesToBSTR(Http.responseBody,"GB2312")
  set http=nothing
  if err.number<>0 then err.Clear
End function
Function BytesToBstr(body,Cset)
  dim objstream
  set objstream = Server.CreateObject("adodb.stream")
  objstream.Type = 1
  objstream.Mode =3
  objstream.Open
  objstream.Write body
  objstream.Position = 0
  objstream.Type = 2
  objstream.Charset = Cset
  BytesToBstr = objstream.ReadText
  objstream.Close
  set objstream = nothing
End Function
%>


2、模板分离批量生成


模板文件中要替换的内容均以{...}括起来

为力求简洁，去掉了错误处理代码（replace中要来替换的字符串参数不能为null值，当然fso也应该做错误检查）。
<%
' ---------------------------------------------------------------------------------------------------------------------
' 出自: kevin fung [url]http://www.[/url]
' 作者: kevin fung 落伍者ID:kevin2008,转载时请保持原样
' 时间: 2006/07/05落伍者论坛首发
' ----------------------------------------------------------------------------------------------------------------------
Dim start '该变量为指针将要指向的记录集位置，通过参数动态获得
Dim Template '模板文件将以字符串读入该变量
Dim content '替换后的字符串变量
Dim objConn '连接对象
Dim ConnStr '连接字符串
Dim sql '查询语句
Dim cnt:cnt = 1 '本轮循环计数器初始化

start = request("start") '获取本轮指针的开始位置
If IsNumeric(start) Then start = CLng(start) Else start=1
If start=0 Then start = 1 '如果start

ConnStr = "Provider = Microsoft.Jet.OLEDB.4.0;Data Source = " & Server.MapPath("DataBase.mdb")
sql = "select * from table_name"

Set objConn = Server.CreateObject("ADODB.Connection")
objConn.Open ConnStr

set rs = Server.CreateObject("ADODB.Recordset")
rs.open sql,objConn,1,1 '打开数据集
rs.AbsolutePosition = start '最关键的一步,将指针指向start，start通过参数动态获得

Template = getTemplate(Server.MapPath("template.html"))' template.html为模板文件，通过函数getTemplate读入到字符串,模板文件中要替换的内容均以{...}括起来

While Not rs.eof And cnt<= 500 '500是设定一次请求生成页面的循环次数，根据实际情况修改，如果太高了，记录集很多的时候会出现超时错误
content = Replace(Template,"{filed_name_1}",rs("filed_name_1")) '用字段值替换模板内容
content = Replace(content,"{filed_name_2}",rs("filed_name_2"))
......
content = Replace(content,"{filed_name_n}",rs("filed_name_n"))

genHtml content,Server.MapPath("htmfiles/"&rs("id")&".html") '将替换之后的Template字符串生成HTML文档，htmfiles为存储静态文件的目录,请手动建立

cnt = cnt + 1 '计数器加1
start = start + 1 '指针变量递增
rs.movenext
wend

If Not rs.eof Then '通过刷新的方式进行下一轮请求,并将指针变量start传递到下一轮
response.write "<meta http-equiv='refresh' content='0;URL=?start="&start&"'>"
Else
response.write "生成HTML文件完毕！"
End if

rs.Close()
Set rs = Nothing
objConn.Close()
Set objConn = Nothing

Function getTemplate(template)'读取模板的函数，返回字符串,template为文件名
Dim fso,f
set fso=CreateObject("Scripting.FileSystemObject")
set f = fso.OpenTextFile(template)
getTemplate=f.ReadAll
f.close
set f=nothing
set fso=Nothing
End Function

Sub genHtml(content,filename)'将替换后的内容写入HTML文档,content为替换后的字符串,filename为生成的文件名
Dim fso,f
Set fso = Server.CreateObject("Scripting.FileSystemObject")
Set f = fso.CreateTextFile(filename,true)'如果文件名重复将覆盖旧文件
f.Write content
f.Close
Set f = Nothing
set fso=Nothing
End Sub
%>

[url]http://www.[/url]

原理很简单的就是用FSO生成静态的页面，其实网络上有很多种方法的，我用了一种。

方法1、将你自己要生成静态的模版做好，就是那个HTML的文件，然后用关键字替换的方法去生成静态的页面。

方法2、也是要先做一个模版出来，但是你可以将你的框架搭建起来，然后在后台用一个隐藏域将某些部门抓入近来了，比如导航栏或者是TOP.ASP什么的。还有底部的东西。然后在生成一个静态文件。

注意：如果想批量生成的话注意文件名就行了，我通常是把ID也写在文件名的最后就行了。

其实楼主可以把html文件当作文本文件来操作的，因为html本身就可以用文本方式打开。