我把图片上传到文件夹，把路径存如数据库，但显示图的时候能不能把过大的图缩小显示呢，
直接显示的话太不清楚了

可以啊.<img src="<%=trim(rs("C_SitePicB"))%>" alt="<%=trim(rs("C_SiteName"))%>" width=75 height="75" border=1 align="absmiddle" style="border-color:#cccccc">这是我的.

按楼上的把显示的图片处理下就可以了吧

就是这样显示很不清楚啊
实验：
把原大小400*400的图用图片编辑器缩小成100*100
用<img src="***a" width=100 height=100></br>
<img src="***b" width=100 height=100>
自己去试试就知道了哪个清楚了

[QUOTE]<%
''获取图片宽度和高度的类，支持JPG，GIF，PNG，BMP
Class ImgWHInfo
Dim ASO
Private Sub Class_Initialize
Set ASO=Server.CreateObject("ADODB.Stream")
ASO.Mode=3
ASO.Type=1
ASO.Open
End Sub
Private Sub Class_Terminate
Err.Clear
Set ASO=Nothing
End Sub

Private Function Bin2Str(Bin)
Dim I, Str
For I=1 To LenB(Bin)
clow=MidB(Bin,I,1)
If ASCB(clow)<128 Then
Str = Str & Chr(ASCB(clow))
Else
I=I+1
If I <= LenB(Bin) Then Str = Str & Chr(ASCW(MidB(Bin,I,1)&clow))
End If
Next
Bin2Str = Str
End Function

Private Function Num2Str(Num,Base,Lens)
Dim Ret
Ret = ""
While(Num>=Base)
Ret = (Num Mod Base) & Ret
Num = (Num - Num Mod Base)/Base
Wend
Num2Str = Right(String(Lens,"0") & Num & Ret,Lens)
End Function

Private Function Str2Num(Str,Base)
Dim Ret,I
Ret = 0
For I=1 To Len(Str)
Ret = Ret *base + Cint(Mid(Str,I,1))
Next
Str2Num=Ret
End Function

Private Function BinVal(Bin)
Dim Ret,I
Ret = 0
For I = LenB(Bin) To 1 Step -1
Ret = Ret *256 + AscB(MidB(Bin,I,1))
Next
BinVal=Ret
End Function

Private Function BinVal2(Bin)
Dim Ret,I
Ret = 0
For I = 1 To LenB(Bin)
Ret = Ret *256 + AscB(MidB(Bin,I,1))
Next
BinVal2=Ret
End Function

Private Function GetImageSize(filespec)
Dim bFlag
Dim Ret(3)
ASO.LoadFromFile(filespec)
bFlag=ASO.Read(3)
Select Case Hex(binVal(bFlag))
Case "4E5089":
ASO.Read(15)
ret(0)="PNG"
ret(1)=BinVal2(ASO.Read(2))
ASO.Read(2)
ret(2)=BinVal2(ASO.Read(2))
Case "464947":
ASO.read(3)
ret(0)="gif"
ret(1)=BinVal(ASO.Read(2))
ret(2)=BinVal(ASO.Read(2))
Case "535746":
ASO.read(5)
binData=ASO.Read(1)
sConv=Num2Str(ascb(binData),2 ,8)
nBits=Str2Num(left(sConv,5),2)
sConv=mid(sConv,6)
While(len(sConv)<nBits*4)
binData=ASO.Read(1)
sConv=sConv&Num2Str(AscB(binData),2 ,8)
Wend
ret(0)="SWF"
ret(1)=Int(Abs(Str2Num(Mid(sConv,1*nBits+1,nBits),2)-Str2Num(Mid(sConv,0*nBits+1,nBits),2))/20)
ret(2)=Int(Abs(Str2Num(Mid(sConv,3*nBits+1,nBits),2)-Str2Num(Mid(sConv,2*nBits+1,nBits),2))/20)
Case "FFD8FF":
Do
Do: p1=binVal(ASO.Read(1)): Loop While p1=255 And Not ASO.EOS
If p1>191 And p1<196 Then Exit Do Else ASO.read(binval2(ASO.Read(2))-2)
Do:p1=binVal(ASO.Read(1)):Loop While p1<255 And Not ASO.EOS
Loop While True
ASO.Read(3)
ret(0)="JPG"
ret(2)=binval2(ASO.Read(2))
ret(1)=binval2(ASO.Read(2))
Case Else:
If left(Bin2Str(bFlag),2)="BM" Then
ASO.Read(15)
ret(0)="BMP"
ret(1)=binval(ASO.Read(4))
ret(2)=binval(ASO.Read(4))
Else
ret(0)=""
End If
End Select
ret(3)="width=""" & ret(1) &""" height=""" & ret(2) &""""
getimagesize=ret
End Function

Public Function imgW(IMGPath)
Dim FSO,IMGFile,FileExt,Arr
Set FSO = Server.CreateObject("Scripting.FileSystemObject")
If (FSO.FileExists(IMGPath)) Then
Set IMGFile = FSO.GetFile(IMGPath)
FileExt=FSO.GetExtensionName(IMGPath)
Select Case LCase(FileExt)
Case "gif","bmp","jpg","png":
Arr=GetImageSize(IMGFile.Path)
imgW = Arr(1)
End Select
Set IMGFile=Nothing
Else
imgW = 0
End If
Set FSO=Nothing
End Function

Public Function imgH(IMGPath)
Dim FSO,IMGFile,FileExt,Arr
Set FSO = server.CreateObject("Scripting.FileSystemObject")
If (FSO.FileExists(IMGPath)) Then
Set IMGFile = FSO.GetFile(IMGPath)
FileExt=FSO.GetExtensionName(IMGPath)
Select Case LCase(FileExt)
Case "gif","bmp","jpg","png":
Arr=getImageSize(IMGFile.Path)
imgH = Arr(2)
End Select
Set IMGFile=Nothing
Else
imgH = 0
End If
Set FSO=Nothing
End Function
End Class

'使用方法 按比例缩小图片
Dim OldImagePath,ImagesUrl,MaxW,MaxH
'===================================
'OldImagePath 图片文件的物理地址
'ImagesUrl 图片文件的URL地址
'MaxW 显示区域的最大宽度
'MaxH 显示区域的最大高度
'===================================
OldImagePath ="d:\webroot\UpFile\001.jpg"
ImagesUrl ="/UpFile/001.jpg"
MaxW = "300"
MaxH = "300"

ReducePercent = 1
ReducePercentW = 1
ReducePercentH = 1
''创建 ImgWHInfo 类对象
Set ImgWHObj = New ImgWHInfo
Old_W = ImgWHObj.imgW(OldImagePath)
Old_H = ImgWHObj.imgH(OldImagePath)
If Old_W > MaxW Then
ReducePercentW = MaxW/Old_W
End If
If Old_H > MaxH Then
ReducePercentH = MaxH/Old_H
End If
If ReducePercentW < ReducePercentH Then
ReducePercent = ReducePercentW
Else
ReducePercent = ReducePercentH
End If
NewW = Cint(Old_W * ReducePercent)
NewH = Cint(Old_H * ReducePercent)
If NewW = 0 Then NewW = MaxW
If NewH = 0 Then NewH = MaxH
ReturnSmallImage = "<Img src="""& ImagesUrl &""" width="""& NewW &""" height="""& NewH &""" border=""0"">"
Response.Write(ReturnSmallImage)
%>[/QUOTE]

[此贴子已经被作者于2007-3-11 10:13:03编辑过]

看来只有在上传的时候对文件进行限制了
5楼的方法跟2楼的原理一样，只是更智能一些
而且5楼的方法我有几个地方想问下：
ReducePercentW = MaxW/Old_W
这样可能更好一些
ReducePercentW = cInt(MaxW)/cInt(Old_W)

If NewW = 0 Then NewW = MaxW - 5
这个 -5 是什么意思啊


还有就是 当判断到高度或宽度只有一个超了，那他只会缩小一个，那结果就有可能使图变得不美观了
应该要缩小就一起缩小