请教一下在combo控件中引用了数据表的一列记录做为控件的选项,当选择了某一项后,怎样才能做到对该表的后在记录的查询?我用了以下代码:
Private Sub Form_Load()
Dim jl As Integer
Adodc2.ConnectionString = Provider = "Microsoft.Jet.OLEDB.4.0;Data Source=F:\指标.mdb;Persist Security Info=False"
Adodc2.RecordSource = "系数"
jl = Adodc2.Recordset.RecordCount '计算表中的记录数
For i = 0 To jl - 1
Combo1.AddItem Adodc2.Recordset.Fields("城市")
Adodc2.Recordset.MoveNext '下一条记录
Next
Adodc2.Recordset.MoveFirst
end sub
引用成功,但下步的对表查询不知在哪个过程中写怎样的代码?谢谢
我用代码
Adodc2.RecordSource = "select * from 系数 where 城市 LIKE '%" & Combo1.Text & "%'"
Adodc2.Refresh
提示找不到数据源

Option Explicit

Private Conn As ADODB.Connection
Dim Rst As ADODB.Recordset

Private Sub cboStuName_Click()
On Error GoTo errhandle
Dim sql As String
sql = "SELECT 学号,姓名,语文,英文,数学 FROM score WHERE 姓名 ='" & cboStuName.Text & "'"
If Rst.State = adStateOpen Then Rst.Close

Rst.Open sql, Conn, adOpenKeyset, adLockPessimistic, adCmdText

Set dgrid.DataSource = Rst
Exit Sub
errhandle:
MsgBox Err.Description
Exit Sub
End Sub

Private Sub Form_Load()
On Err GoTo errhandle
Set Conn = CreateObject("ADODB.Connection")
Dim constring As String
constring = "Provider=Microsoft.Jet.OleDb.4.0;Data Source=" & App.Path & "\Orders.mdb"
Conn.ConnectionString = constring
Conn.Open

Set Rst = CreateObject("ADODB.Recordset")
Rst.CursorLocation = adUseClient

Dim sql As String
sql = "SELECT 学号, 姓名,语文,英文,数学 FROM score"
Rst.Open sql, Conn, adOpenKeyset, adLockPessimistic, adCmdText

Dim i As Long
Dim lngRecordCount As Long
Rst.MoveLast
lngRecordCount = Rst.RecordCount
Rst.MoveFirst

For i = 0 To lngRecordCount - 1
cboStuName.AddItem Rst.Fields("姓名").Value
Rst.MoveNext
Next

Set dgrid.DataSource = Rst
Exit Sub
errhandle:
MsgBox Err.Description
Exit Sub
End Sub

Private Sub Form_Unload(Cancel As Integer)
Set Rst = Nothing
Set Conn = Nothing
End Sub

谢谢