如何读取word 表格并导入到vfp的dbf中

之前几个贴都与word表格有关，还没搞清楚吗?

本人对vfp一知半解，只是爱好而已，但有时却能解决工作中的具体问题。希望得到各位高手的指点，不胜感谢！

CREATE CURSOR tt (考生号 C(16), 姓名 C(10), 总分 I, 语文 I, 数学 I, 外语 I, 综合 I)
word = CREATEOBJECT("Word.Application")
doc = word.Documents.Open("C:\TEMP\文档\文档.docx")
tab = doc.tables[1]
FOR row=2 TO tab.rows.count
    INSERT INTO tt VALUES (;
       RTRIM(tab.Cell(row,1).Range.Text, 0h0D,0h07,0h20),;
       RTRIM(tab.Cell(row,2).Range.Text, 0h0D,0h07,0h20),;
       VAL(tab.Cell(row,3).Range.Text),;
       VAL(tab.Cell(row,4).Range.Text),;
       VAL(tab.Cell(row,5).Range.Text),;
       VAL(tab.Cell(row,6).Range.Text),;
       VAL(tab.Cell(row,7).Range.Text))
ENDFOR
doc.Close
word.Quit
SELECT * FROM tt

@吹水佬 非常感谢！！！

RTRIM(tab.Cell(row,1).Range.Text, 0h0D,0h07,0h20),; RTRIM(tab.Cell(row,2).Range.Text, 0h0D,0h07,0h20),;
这两行代码后面 0h0D,0h07,0h20这串字符不明白是什么意思，望指点！
      

从word表取出来的字符串尾部有些杂乱的字符

****  要再能自动造表，不如吹版的简单（仅参考）
 close all
  cwj=ADDBS(SYS(5)+SYS(2003))+"文档.docx"
  ow=CREATEOBJECT("word.application")
  ot=ow.Application.Documents.Open(cwj)   
  nrow=ot.tables(1).rows.count
  ncol=ot.Tables(1).Columns.Count
  create cursor b1 (zd1 c(20),zd2 n(10))
  
  csq="select " && 先造一个表
  for nn=1 to ncol
      zd=ot.Tables.item(1).cell(1,nn).range.text
      do case
         case nn<3
              csq=csq+"zd1 as "+zd+","
         case nn>2 and nn<7
              csq=csq+"zd2 as "+zd+","
         case nn=7
              csq=csq+"zd2 as "+zd+" from b1 into cursor b2 readwrite"
       endcase      
   endfor                    
    csq=CHRTRAN(csq,CHR(7)+CHR(13),'')
    ExecScript(csq)
  ********** 造表完毕

  select b2 &&给表填数据
  for i=2 to nrow
      append blank
      for j=1 to ncol
          zd=ot.Tables.item(1).cell(i,j).range.text
          zd=CHRTRAN(zd,CHR(7)+CHR(13),'')
          czd=FIELD(j)
          if j>2
             zd=VAL(zd)
          endif   
          replace &czd with zd
      endfor
  endfor
     
   ow.ActiveDocument.Close
   ow.Quit
   browse
  close all