求助：有A表格式想变B表格式。
谢谢

CREATE CURSOR B表 (xh C(4),xm C(10),;
    生产情况 C(20),;
    数量 N(10,2))
CREATE CURSOR A表 (xh C(4),xm C(10),;
    综合小时产出  N(10,2),;
    达标小时产量  N(10,2),;
    实际标准数量  N(10,2),;
    工艺加工  N(10,2),;
    纯手动加工  N(10,2))
INSERT INTO A表 VALUES("1001","张一",100,600,100,100,100)
INSERT INTO A表 VALUES("1002","李军",400,500,400,400,400)
SCAN
    FOR i=3 TO FCOUNT("A表")
        INSERT INTO B表 VALUES (;
            EVALUATE("A表."+FIELD(1,"A表")),;
            EVALUATE("A表."+FIELD(2,"A表")),;
            FIELD(i,"A表"),;
            EVALUATE("A表."+FIELD(i,"A表")))
    ENDFOR
ENDSCAN
SELECT * FROM B表 ORDER BY 生产情况

CREATE CURSOR B表 (xh C(4),xm C(10),;
    生产情况 C(20),;
    数量 N(10,2))
CREATE CURSOR A表 (xh C(4),xm C(10),;
    综合小时产出  N(10,2),;
    达标小时产量  N(10,2),;
    实际标准数量  N(10,2),;
    工艺加工  N(10,2),;
    纯手动加工  N(10,2))
INSERT INTO A表 VALUES("1001","张一",100,200,300,400,500)
INSERT INTO A表 VALUES("1002","李军",400,500,600,700,800)
nzds=2 
scan
    scatter to azd
    for lnI=1 to fcount("A表")-nzds
        insert into B表 values (A表.XH,A表.XM,field(lnI+nzds,"A表"),azd[lnI+nzds])
    endfor
endscan
select * FROM B表 ORDER BY 3 DESC

与吹版的代码差不多

楼主的这种数据类型转换，就是大家常说的列记录转换为行记录。

谢谢二位版主，给予热心解答。
 有个疑惑 在这个程序代码运行后A表中字段名超过5个汉字，没有问题。而我在2003版EXCEL 转为DBF(6.0)时A表长字段名被截呢？

[此贴子已经被作者于2017-10-15 15:41编辑过]

字段名10个字节长

数据库表、临时表字段名可以超过10个字节

涨知识了，谢谢sdta,谢谢吹水佬，下次有不懂的再来请教你们。