前提是所有字段均是字符型，不是的话加入转换函数。

再想请教各位一个问题，用数据库连接的方式与用程序一行行字段插入的方式来看，即上述用union的方式与用其他非数据库连接的方式的出来的结果中，在数据量逐渐增大的情况下，哪种方式运行的速度比较快？

吹版的效率高

当只有 1W 条记录时，差别不大，差别约 2 秒。
当有 10W 条记录时，差别开始明显，一个耗时约 29秒，另一个约 5秒。

Clear
Close Databases
*!*    测试一：29s
Create Cursor Test1 (Id Int Autoinc, Name C(10), XingBie C(2), PhoneNum C(5))
For I = 1 To 100000
    Insert Into Test1 (Name, XingBie, PhoneNum) Values(Sys(2015), Iif(Int(I/2) = I/2, '男', '女'), Sys(3))
Endfor

t1 = Seconds( )
Select Id, Field(1) + ':' As 字段A, (Select Padl(Id, 10, " ")       As 字段B From Test1 Where Id = A.Id) From Test1 As A ;
    Union ;
Select Id, Field(2) + ':' As 字段A, (Select Name                    As 字段B From Test1 Where Id = A.Id) From Test1 As A ;
    Union ;
Select Id, Field(3) + ':' As 字段A, (Select XingBie                 As 字段B From Test1 Where Id = A.Id) From Test1 As A ;
    Union ;
Select Id, Field(4) + ':' As 字段A, (Select Padl(PhoneNum, 10, " ") As 字段B From Test1 Where Id = A.Id) From Test1 As A ;
    Into Cursor Query

Select 字段A, 字段B From Query Into Cursor Query
Browse Last Nowait
? Transform(Seconds( ) - T1) + '秒'
Messagebox(Transform(Seconds( ) - T1) + '秒')

*!*    Return


*!*    测试二：5s
Create Cursor Test1 (Id Int Autoinc, Name C(10), XingBie C(2), PhoneNum C(5))
For I = 1 To 100000
    Insert Into Test1 (Name, XingBie, PhoneNum) Values(Sys(2015), Iif(Int(I/2) = I/2, '男', '女'), Sys(3))
EndFor

t1 = Seconds( )
Create Cursor tt (S1 C(10), S2 C(10))
Select Test1
Scan
    For i = 1 To Fcount()
        ss1 = Field(i)
        ss2 = Transform(Evaluate(ss1))
        Insert Into tt Values (ss1, ss2)
    Endfor
Endscan
Select tt
Go Top
Browse Last Nowait
? Transform(Seconds( ) - T1) + '秒'
Messagebox(Transform(Seconds( ) - T1) + '秒')

[此贴子已经被作者于2016-3-15 11:01编辑过]

表操作的效率主要看遍历表次数。
一个 Select ... From 至少有一个“表”，而且每个 Select 至少要遍历“表”一次，多个 Select “嵌套”就可想而知。

其实楼主的问题不是很难，这里至少 90(+)% 的人会做，有人跟帖说用 SQL 语句做难度大，所以引出了多重连接的 SQL 算法。
这里的 SQL 语句复杂，效率低，不通用，纯粹是玩弄技巧，或者是一题多解，作为 SQL 语法的练手。