我就要Optiongroup1的效果，用他把其它的command,chenck等等框起来。。
用shape是可以，但移动shape，框起来的东西不会一起移动，还有就是，我第1个问题，以前不知道，现在知道了，可以前置/后置，要是用T版的方法，用prg生成的话，就不知道怎么在shape上放这些，才不会给挡住

CLEAR ALL 
Main()
CLEAR ALL 
RETURN 

PROCEDURE Main()
    LOCAL loForm
    loForm = CREATEOBJECT("C_Form")
    WITH loForm
        .Caption = "Test Container"
        .Show
    ENDWITH 
    READ EVENTS
ENDPROC 

DEFINE CLASS C_Form AS Form
    Width = 600
    Height = 400
    Picture = "20151111_112634_660.JPG"
    MinButton = .F.
    MaxButton = .F.
    BorderStyle = 1
    
    ADD OBJECT CheckGroup1 AS CheckGroup WITH Top = 5, Left = 5

    PROCEDURE Destroy
        CLEAR EVENTS 
    ENDPROC 
    
ENDDEFINE 

DEFINE CLASS CheckGroup AS Container
    BackStyle = 0

    ADD OBJECT Check1 AS CheckBox WITH Caption = "Check 1"
    ADD OBJECT Check2 AS CheckBox WITH Caption = "Check 2"
    ADD OBJECT Check3 AS CheckBox WITH Caption = "Check 3"
    ADD OBJECT Check4 AS CheckBox WITH Caption = "Check 4"
    
    PROCEDURE Init
        WITH This
            .SetAll("BackStyle", 0)
            .Arrange
        ENDWITH 
    ENDPROC 
    
    PROCEDURE Arrange
        LOCAL loControl, lnCount
        lnCount = 0
        FOR EACH loControl AS CheckBox IN This.Controls FOXOBJECT 
            lnCount = lnCount + 1
            WITH loControl
                .Height = 20
                .Width = 200
                .Top = 5 + (lnCount - 1) * (.Height + 5)
                .Left = 5
                .Parent.Height = .Top + .Height + 5
                .Parent.Width = .Left + .Width + 5
            ENDWITH 
        ENDFOR 
    ENDPROC 
    
ENDDEFINE 

谢谢。T版，
Container的边框，能设置成为12楼那样，3D的感觉出来不？

你那个在运行时也不是3D的呀。在设计界面上看是那样而已，在运行时也一样是平的。

[此贴子已经被作者于2015-12-11 17:40编辑过]

11楼的容器凸起不好看吗？

自绘好了，shape + Container，设置一下边线色和透明。