VFP用向导做的表单按钮中的，增加，修改，删除，保存，等等按钮，做好后进去，怎么看不到具体的操作语句的？
他是怎么实现相应的操作的？今天看到VFP的数据缓存技术？难道是用TableUpdate()来处理的？
以前一直都是直接修改表，没用过TableUpdate来更新表。

应该是封装成类的，在代码编辑窗口可以点击“查看父代码”

查到了，是用CURSORGETPROP，来更新数据的。。

是不是，具体说来看

*这个是cmdEdit的
#DEFINE C_NOUPDATE_LOC    "由于选定的视图不发送更新因此你不能编辑它。"

LOCAL lNoSendParentUpdates,lNoSendChildUpdates
LOCAL aTablesUsed,nTablesUsed,i

IF EMPTY(ALIAS())
    RETURN
ENDIF

** Reverting record
IF THIS.Parent.EditMode
   
    IF THIS.Parent.UseDataEnv
        SELECT (THIS.Parent.OldAlias)
        IF CURSORGETPROP("Buffering")>1
            =TableRevert(.T.)
        ENDIF
        IF !EMPTY(THIS.Parent.GridAlias)
            SELECT (THIS.Parent.GridAlias)
            IF CURSORGETPROP("Buffering")>1
                =TableRevert(.T.)
            ENDIF
        ENDIF            
    ELSE
        DIMENSION aTablesUsed[1]
        m.nTablesUsed = AUSED(aTablesUsed)
        FOR i = 1 TO m.nTablesUsed
            IF CURSORGETPROP("Buffering",aTablesUsed[m.i,1])>1
                =TableRevert(.T.,aTablesUsed[m.i,1])
            ENDIF
        ENDFOR
    ENDIF
   
    * Go back to original place
    SELECT (THIS.Parent.OldAlias)
    IF RECCOUNT() < THIS.Parent.OldRec    &&added record at EOF()
        GO TOP
    ELSE
        GO THIS.Parent.OldRec
    ENDIF
ELSE
    * Check to see if view allows updates
    IF CURSORGETPROP("SourceType")#3 AND !CURSORGETPROP("offline") AND;
        !CURSORGETPROP("SendUpdates") AND CURSORGETPROP("SourceType")<100
        lNoSendParentUpdates = .T.
    ENDIF
   
    IF !EMPTY(THIS.Parent.GridAlias) AND ;
      CURSORGETPROP("SourceType",THIS.Parent.GridAlias)#3 AND ;
      !CURSORGETPROP("offline",THIS.Parent.GridAlias) AND ;
      !CURSORGETPROP("SendUpdates",THIS.Parent.GridAlias)
        lNoSendChildUpdates= .T.
    ENDIF
   
    IF (m.lNoSendChildUpdates AND m.lNoSendParentUpdates) OR;
        (EMPTY(THIS.Parent.GridAlias) AND m.lNoSendParentUpdates)
        MESSAGEBOX(C_NOUPDATE_LOC)
        RETURN
    ENDIF
   
    THIS.Parent.OldAlias = ALIAS()    &&save alias in case reverting
    THIS.Parent.OldRec = RECNO()    &&save record in case reverting
ENDIF

** Editing record
THIS.Parent.EditMode = !THIS.Parent.EditMode
THIS.Parent.AddMode = .F.
THIS.Parent.ButtonRefresh()
THIS.Parent.NavRefresh()

那是一个类......就像现在用上了表单..不像以前的版本建个窗口都要用什么  MD WOINDOW.现在有表单了直接点就是了