[此贴子已经被作者于2015-10-23 17:15编辑过]

程序代码：

** 考试座位安排
** 要求：每一位考生的前后（行）是同级生而非同班生（或空）、左右（列）是非同级生（或空）。

n级 = 6    && 生成模拟数据的年级个数
n班 = 10   && 生成模拟数据的每年级班个数 
n行 = 8    && 考场每班座位行数
n列 = 8    && 考场每班座位列数
    * 建模拟数据
CREATE CURSOR 学生表 (级 I, 班 I, 名 C(20))
FOR i = 1 TO n级
    FOR j = 1 TO n班
        FOR k = 1 TO IIF(MOD(i, 2)==0, 60, 50)    && 不同级班人数不同
        *FOR k = 1 TO IIF(MOD(j, 2)==0, 60, 50)    && 不同班人数不同
            INSERT INTO 学生表 VALUES (i, j, PADL(i,2," ")+"年级"+PADL(j,2," ")+"班"+PADL(k,8,"x"))
        ENDFOR
    ENDFOR
ENDFOR
    * 建考场表
cCmd = "CREATE CURSOR 考场表 (考场 I"
FOR i = 1 TO n列
    cCmd = cCmd + ",列"+TRANSFORM(i)+" C(20)"
ENDFOR
cCmd = cCmd + ")"
EXECSCRIPT(cCmd)
    * 生成考场表数据
n场i = 1
n列i = 1
n行i = 0
FOR i = 1 TO n级
    建考场表(i, @n场i, @n列i, @n行i)
        * 同一考场相邻两列不同一个年级
        * 如果上一次处理的年级从第1列开始，则下一个年级从第2列开始，否则从第1列开始。
    n列i = IIF(n列i==1, 2, 1)
ENDFOR
    * 浏览考场表数据
SELECT 考场表
GO TOP 
BROWSE

    * 建考场表(n级i, n场i, n列i, n行i)
    * n级i ... 某年级，值传送
    * n场i ... 当前处理的考场号，地址传送
    * n列i ... 当前处理的考场表列号（字段号），地址传送
    * n行i ... 当前处理的考场表行号（记录号），地址传送
FUNCTION 建考场表(n级i, n场i, n列i, n行i)
    LOCAL i, n列k, n行k
        * 获取某年级数据
    SELECT * FROM 学生表 WHERE 级==n级i INTO CURSOR 级表
        * 按要求：同一考场考生的前后是同年级而不同一个班，在此用随机乱序处理来达到要求。
    SELECT 级表
    INDEX on RAND(班+RECNO()) TAG 班序    && 乱序
    *INDEX on RAND(RECNO()) TAG 班序    && 乱序
    GO TOP IN "级表"
        * 将某年级考生安排考场座位
    n列k = n列i
    n行k = n行i
    
    DO WHILE !EOF("级表")
            * 如果处理完最后一列
        IF n列k > n列
            n行k = n行k + n行                    && 下一个考场行起始
            IF (n行k+1) <= RECCOUNT("考场表")    && 如果还有适用空座位
                n列k = n列i                      && 从原来的起始列重新开始  
            ELSE
                n场i = n场i + 1                  && 没有适用空座位时添加一个新考场
                    * 如果当前的年级是从第2列开始的，则保存的行起始号变为当前处理中的行号
                IF n列i == 2
                    n行i = n行k                  && 保存行起始号  
                ENDIF
                n列i = 1                         && 新考场安排座位从第1列开始，并保存起始列号
                n列k = n列i
            ENDIF
        ENDIF
            * 安排一列座位
        i = 1
        DO WHILE !EOF("级表") AND (i <= n行)
                * 如果有适用的空座号就找号入座，否则新增一行座位。
            IF (n行k+i) <= RECCOUNT("考场表")
                GO (n行k+i) IN "考场表"
            ELSE
                APPEND BLANK IN "考场表"
                REPLACE 考场 WITH n场i IN "考场表"
            ENDIF
                * 对号入座，标记考生数据
            REPLACE ("列"+TRANSFORM(n列k)) WITH 级表.名 IN "考场表"
            i = i + 1
            SKIP IN "级表"
        ENDDO
            * 处理下一列
        n列k = n列k + 2    
    ENDDO
ENDFUNC