在winxp+VFP9环境下开发了一套系统
其中一个表单的init事件中写入：
set help on
set help to myhelp.chm
表单上放置了一个按钮cmd_help，在cmd_help.click中写入：
help

连编成exe文件后，安装在winxp的机器中，点击cmd_help或按F1键，能调出帮助窗口，运行正常。安装在win7的机器中，点击cmd_help或按F1键均无反应，也不产生错误信息。如何解决？

不清楚的说

直接通过API打开帮助文件。

能否详细点？请教了

按楼上的思路，做好了。谢谢！
myhelp = 'shkhelp.chm'
DECLARE INTEGER ShellExecute IN "Shell32.dll" INTEGER hwnd,STRING lpVerb,STRING lpFile,STRING lpParameters,STRING lpDirectory,LONG nShowCmd
=Shellexecute(1,"Open", ,myhelp,"",1)

ON KEY LABEL F1 MyHelp()

** Command1.Click
MyHelp()

FUNCTION MyHelp()
    oApp = CREATEOBJECT("Shell.Application")
    oApp.ShellExecute("MyHelp.chm", "", "", "", 1)
ENDFUNC

本人不太懂API函数，继续请教。

用上面的方法解决了打开帮助文件的问题，如何做到不重复打开帮助文件呢？
即：
if 帮助文件没有打开
    打开帮助文件
else
    使帮助文件窗口成为活动窗口
endif

（在VFP中，我通过测试oApp的属性无法判断打开的窗口是否关闭）

oApp与打开的帮助文件进程无关。

打开的是外部进程，要直接知道外部进程的运行情况（进程间的通信）有点麻烦。
如果只想知道有窗口的应用是否在运行，可以按窗口类名或窗口标题搜索窗口。

也可用 ShellExecuteEx() API 打开外部进程，这个API函数的参数是一个数据结构，其中含有进程句柄（hProcess），有了进程句柄对进程的了解就方便多了。VFP调用ShellExecuteEx()涉及到内存分配/释放、内存读/写，内容不少，有兴趣可以参考与进程有关的API说明。

个人意见：就象我们用资源管理器一样，用户喜欢就由她开多几个帮助，不用前后翻页，也许对她真的有帮助。

用 ShellExecuteEx() API 打开/关闭外部进程示例

CLEAR
DECLARE LONG GetProcessHeap   IN Kernel32
DECLARE LONG HeapAlloc        IN Kernel32 LONG, LONG, LONG
DECLARE LONG HeapFree         IN Kernel32 LONG, LONG, LONG
DECLARE LONG TerminateProcess IN Kernel32 LONG, LONG
DECLARE LONG ShellExecuteEx   IN Shell32 STRING@

szFile = "c:\program files (x86)\microsoft visual foxpro 9\dv_foxhelp.chm"
dhFile = HeapAlloc(GetProcessHeap(), 8, LEN(szFile))
SYS(2600, dhFile, LEN(szFile), szFile)

stSEI = BINTOC(60,     "4RS");
      + BINTOC(0x40,   "4RS") + REPLICATE(0h00,  8);
      + BINTOC(dhFile, "4RS") + REPLICATE(0h00,  8);
      + BINTOC(1,      "4RS") + REPLICATE(0h00, 28)

ShellExecuteEx(@stSEI)
HeapFree(GetProcessHeap(), 8, dhFile)
dhProcess = CTOBIN(RIGHT(stSEI, 4), "4RS")
** 3秒后关闭
INKEY(3)
TerminateProcess(dhProcess, 0)
CLEAR DLLS
RETURN

打开外部进程并检测是否已经关闭

CLEAR
#DEFINE STILL_ACTIVE    259
DECLARE LONG GetProcessHeap     IN Kernel32
DECLARE LONG HeapAlloc          IN Kernel32 LONG, LONG, LONG
DECLARE LONG HeapFree           IN Kernel32 LONG, LONG, LONG
DECLARE LONG GetExitCodeProcess IN Kernel32 LONG, LONG@
DECLARE LONG ShellExecuteEx     IN Shell32 STRING@

szFile = "c:\program files (x86)\microsoft visual foxpro 9\dv_foxhelp.chm"
dhFile = HeapAlloc(GetProcessHeap(), 8, LEN(szFile))
SYS(2600, dhFile, LEN(szFile), szFile)

stSEI = BINTOC(60,     "4RS");
      + BINTOC(0x40,   "4RS") + REPLICATE(0h00,  8);
      + BINTOC(dhFile, "4RS") + REPLICATE(0h00,  8);
      + BINTOC(1,      "4RS") + REPLICATE(0h00, 28)

ShellExecuteEx(@stSEI)
HeapFree(GetProcessHeap(), 8, dhFile)
dhProcess = CTOBIN(RIGHT(stSEI, 4), "4RS")
** 5秒后检测是否已经关闭
INKEY(5)
ddExitCode = 0
GetExitCodeProcess(dhProcess, @ddExitCode)
? IIF(ddExitCode == STILL_ACTIVE, "已打开", "已关闭")
CLEAR DLLS
RETURN

[ 本帖最后由 吹水佬 于 2015-6-21 20:46 编辑 ]