在文本框的Valid中：

IF not(thisform.text_khd.Value>0 and thisform.text_khd.Value<=5)
        messagebox("请重新输入","系统提示")
        thisform.text_khd.Value=0
        Return .f.
ENDIF
用代码控制文本框输入内。
不输入内容，直接按退出命令按钮，也提示要求重新输入。
怎样才能跳过文本框输入控制代码，按退出命令按钮退出表单？

试试改在 LostFocus 事件：
IF !BETWEEN(this.value, 1, 5)
    NODEFAULT
    this.value = 0
ENDIF

数据检查不要主動激活，变为被动的，检查代码无需写在valid事件中，写在一个自定义的方法中，在适当时候由别的代码去调用它，这样才可以控制什么时候检查、什么时候不检查。

[ 本帖最后由 TonyDeng 于 2015-4-3 01:34 编辑 ]

进退有余

奇怪的思路

CLEAR ALL
CLEAR
oForm = CREATEOBJECT("C_Form")
WITH oForm
    .Caption = "Test"
    .AutoCenter = .T.
    .Show
ENDWITH
READ EVENTS
CLEAR ALL
RETURN

DEFINE CLASS C_Form AS Form

    ADD OBJECT Label1  AS Label         WITH Caption = "数值1", Top = 5, Left = 5, Height = 25, Width = 60
    ADD OBJECT Text1   AS TextBox       WITH Value = 1, Height = 25, Width = 100
    ADD OBJECT Label2  AS Label         WITH Caption = "数值2", Value = 0, Top = 35, Left = 5, Height = 25, Width = 60
    ADD OBJECT Text2   AS TextBox       WITH Value = 0, Height = 25, Width = 100
    ADD OBJECT cmdExit AS CommandButton WITH Caption = "退出[\<E]", Height = 25, Width = 60
   
    PROCEDURE Text1.CheckValue()
        WITH This
            IF (.Value < 1) .OR. (.Value > 99)
                WAIT ThisForm.Label1.Caption + "输入错误！" WINDOW NOWAIT TIMEOUT 2
                .SetFocus
            ENDIF
        ENDWITH
    ENDPROC
   
    PROCEDURE Text2.GotFocus
        ThisForm.Text1.CheckValue
    ENDPROC
   
    PROCEDURE cmdExit.Click
        ThisForm.Release
    ENDPROC
   
    PROCEDURE Arrange
        WITH ThisForm.Text1
            .Top = ThisForm.Label1.Top
            .Left = ThisForm.Label1.Left + ThisForm.Label1.Width + 5
        ENDWITH
        WITH ThisForm.Text2
            .Top = ThisForm.Label2.Top
            .Left = ThisForm.Label2.Left + ThisForm.Label2.Width + 5
        ENDWITH
        WITH ThisForm.cmdExit
            .Top = ThisForm.Height - .Height - 5
            .Left = 5
        ENDWITH
    ENDPROC
   
    PROCEDURE Init
        WITH ThisForm
            .SetAll("FontBold", .T., "Label")
            .SetAll("Alignment", 1, "Label")
            .SetAll("SelectOnEntry", .T., "TextBox")
        ENDWITH
    ENDPROC
   
    PROCEDURE Activate
        ThisForm.Arrange
    ENDPROC
   
    PROCEDURE Resize
        ThisForm.Arrange
    ENDPROC
   
    PROCEDURE Click
        ThisForm.Text1.CheckValue
    ENDPROC
   
    PROCEDURE Destroy
        CLEAR EVENTS
    ENDPROC
   
ENDDEFINE

代码很简单，不注释，自己仔细看看吧。

顺便提一下：关闭窗体，除了按表单上的【退出】按钮，还可以按右上角的叉叉，你无法知道用戶按哪个结束的窗体。


[ 本帖最后由 TonyDeng 于 2015-4-3 18:53 编辑 ]

你这个问题的困难之处，是焦点离开那个文本框之后，哪个控件接收焦点，是无法预知的，而後續的控件，有些需要检测数据，有些不需要，所以，把方案专注于文本框本身，是没有用的，必须从後續的控件入手。这就是逻辑推理和证明。

授人以渔，不授人以鱼。