[求助]大家好！急切求助 - ASP技术论坛

yakey

等　级：新手上路
帖　子：6
专家分：0
注　册：2007-9-27

楼主

问题点数：0 回复次数：7

[求助]大家好！急切求助

大家好呀，小女子初来乍到，有礼了。我是带着问题来的，请侠侠们帮帮我！
下面是做了一个直接提交到邮箱的表单的sent.asp。可是怎么也调试不出；帮忙诊断下吧，谢谢
<%
Dim idearmail, contentId
iname=Request("iname")
why=Request("why")
tel=Request("itel")
email=Request("iemail")
idear=Request("idear")
mailbody=""诉求类型："&why&vbcrlf&"发件人："&iname&vbcrlf&"我的邮箱："&email&vbcrlf&"我的电话："&tel&vbcrlf&"我的"&why&":"&idear"
Set idearmail = Server.CreateObject("JMail.Message")
idearmail.Charset = "gb2312"
idearmail.From =email
idearmail.FromName = iname
idearmail.Subject = "意见"
//idearmail.Subject = iname&"对***"why
idearmail.body=mailbody
idearmail.MailServerUserName = "asia"
idearmail.MailServerPassword = "7311"
idearmail.Priority = 3
idearmail.AddHeader "Originating-IP", Request.ServerVariables("REMOTE_ADDR")
idearmail.AddRecipient("***@hotmail.com")
isgo=idearmail.Send("用户名:密码@邮件服务器")
if isgo then
msg="提交成功！"
else
msg="发送失败！"
end if

idearmail.Close()
Set idearmail = Nothing

%>

搜索更多相关主题的帖子: Request　why　

2007-09-27 11:06

yakey

等　级：新手上路
帖　子：6
专家分：0
注　册：2007-9-27

第 3 楼

得分:0

已经研究过了，可还是不行。服务器上已经装了jmail了。我的这些语句好像有错误，可是自己找不到

2007-09-27 13:33

yms123

等　级：版主
威　望：209
帖　子：12488
专家分：19042
注　册：2004-7-17

第 5 楼

得分:0

JMail发送邮件需要邮件发送服务器(Smtp)的地址
[CODE]<%@ Language=VBScript %>
<%

'+++++++++++++++++++++++++++++
' 参数设置
'+++++++++++++++++++++++++++++
'邮件底部的广告
mailfoot= "xxxxxxx"
'用来发送邮件的SMTP服务器
mailserver= "smtp.xxxxx.com"
'如果服务器需要SMTP身份验证则：
'登录用户名
mailserverloginname= "xxxxxx"
'登录密码
mailserverloginpass= "xxxxxx"
'域名（如果你用“name@domain.com”这样的用户名登录时，请指明domain.com
mailuserdomain= "xxxx@xxxxx.com"
'+++++++++++++++++++++++++++++
%>
<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=gb2312">
<title>FormMail - Ajiang.net</title>
<style type="text/css">

</style>
</head>
<body>
<table width="498" border="0" align="center" cellpadding="0" cellspacing="0">
<tr>
<td><img src="formmail_r1_c1.gif" width="500" height="75"></td>
</tr>
<tr>
<td height="300" background="formmail_r2_c1.gif">
<table width="390" border="0" align="center" cellpadding="0" cellspacing="0">
<%
'获取表单数据
fromname= Request.Form("fromname")
frommail= Request.Form("frommail")
toname= Request.Form("toname")
tomail= Request.Form("tomail")
mailtitle= Request.Form("mailtitle")
mailbody= Request.Form("mailbody")
'检查是否填写了表单
if tomail="" then
%>
<form action="<%=Request.ServerVariables("SCRIPT_NAME")%>" method=post>
<tr>
<td><p>发信人姓名:
<input type="text" name="fromname">
<br>
发信人信箱:
<input type="text" name="frommail">
<br>
收信人姓名:
<input type="text" name="toname">
<br>
收信人信箱:
<input type="text" name="tomail">
<br>信件主题:　
<input name="mailtitle" type="text" size="51">
<br>
信件内容:<br>
　　　　　　<textarea name="mailbody" cols="49" rows="9"></textarea>
<br>
<input name="Submit" type="submit" class="backc" value="提交">
</p>
</td>
</tr>
</form>
<%
else
if frommail="" then
msg="您必须填写您的邮件地址，才可以发信给别人。"
else

'=============== 发信 ================
dim JMail
set JMail=server.CreateObject("Jmail.message")
JMail.Silent=true
JMail.Charset = "gb2312"
JMail.FromName = fromname
JMail.from = frommail
JMail.AddRecipient tomail,toname
JMail.Subject = mailtitle
jmail.Body=mailbody & vbcrlf & vbcrlf & mailfoot
JMail.MailServerUserName = mailserverloginname
JMail.MailServerPassWord = mailserverloginpass
JMail.MailDomain = mailuserdomain
sendok=JMail.send(mailserver)
if sendok then
msg="已经成功发送了邮件！"
else
msg="发送邮件失败，可能是您填写了错误的邮件地址。<br>" & _
"如果您确信没有写错邮件地址，则可能是发信程序出了<br>" & _
"故障，请与管理员联系"
end if
end if
%>
<tr>
<td valign=middle>
<table width=80% align=center>
<tr><td><p><%=msg%><br><br><a href='javascript:history.back()'>[返回]</a></p></td></tr>
</table>
</td>
</tr>
<%
end if
%>
</table>
</td>
</tr>
<tr>
<td><img src="formmail_r3_c1.gif" width="500" height="36"></td>
</tr>
</table>
</body>
</html>[/CODE]
楼主可以参考一下。

2007-09-27 14:38

piaoxue

来　自：地球
等　级：论坛游侠
威　望：3
帖　子：606
专家分：113
注　册：2005-9-19

第 7 楼

得分:0

我有一个比较简单的邮件发送的代码你研究一下吧
<%
dim strsubject,strquery
strsubject=trim("来自"+request.Form("1")+"的MAIL信息")
strquery=trim("字段1："+Request.Form("1")&" ； "&"字段2："+Request.Form("2")&" ； "&"字段3："+request.Form("3")&" ； "&"字段4："+request.Form("4")&" ； "&"字段5"+request.Form("5")）
Const cdoSendUsingMethod="http://schemas.microsoft.com/cdo/configuration/sendusing"
Const cdoSendUsingPort=2
Const cdoSMTPServer="http://schemas.microsoft.com/cdo/configuration/smtpserver"
Const cdoSMTPServerPort="http://schemas.microsoft.com/cdo/configuration/smtpserverport"
Const cdoSMTPConnectionTimeout="http://schemas.microsoft.com/cdo/configuration/smtpconnectiontimeout"
Const cdoSMTPAuthenticate="http://schemas.microsoft.com/cdo/configuration/smtpauthenticate"
Const cdoBasic=1
Const cdoSendUserName="http://schemas.microsoft.com/cdo/configuration/sendusername"
Const cdoSendPassword="http://schemas.microsoft.com/cdo/configuration/sendpassword"
Dim objConfig
Dim objMessage
Dim Fields
Set objConfig = Server.CreateObject("CDO.Configuration")
Set Fields = objConfig.Fields
With Fields
.Item(cdoSendUsingMethod) = cdoSendUsingPort
.Item(cdoSMTPServer) = "smtp.163.com"
.Item(cdoSMTPServerPort) = 25
.Item(cdoSMTPConnectionTimeout) = 10
.Item(cdoSMTPAuthenticate) = cdoBasic
.Item(cdoSendUserName) = "123@163.com" '这里是你的邮箱用户名
.Item(cdoSendPassword) = "123456" '这里是密码
.Update
End With
Set objMessage = Server.CreateObject("CDO.Message")
Set objMessage.Configuration = objConfig
With objMessage
.To = "456@126.com"
.From = request.Form("1")+"<123@163.com>"
.Subject = strsubject
.TextBody = strquery
.Send
End With
Set Fields = Nothing
Set objMessage = Nothing
Set objConfig = Nothing
response.write "<div align=center>信息发送成功！<br><br><a href=javascript:window.close()>关闭</a></div>"
%>

我是做平面设计、网站制作、网站推广、主机域名等业务的站长。有需要的给我站内信吧。

2007-09-27 16:37