怎么写代码呢？
我写了可是输入{^1986-11-14}时,最后的结果是一九八六年月日

有点问题，不知道哪里错了，哦，帮我看一下，谢了！

set talk off
clear
input "pls input a date :" to x
c1="一二三四五六七八九十"
q=space(0)
b1=year(x)
q1=space(0)
do while b1>0
h1=b1%10
p1=subs(c1,2*h1-1,2)
q1=p1+q1
b1=int(b1/10)
enddo
b2=month(x)
q2=space(0)8k
do while len(b2)=2
h2=b2%10
p2=subs(c1,2*h2-1,2)
q2=p2+q2
b2=int(b2/10)
else len(b2)=1
p2=subs(c1,2*b2-1,2)
q2=p2+q2
enddo
b3=day(x)
q3=space(0)
do while len(b3)=2
h3=b3%10
p3=subs(c1,2*h3-1,2)
q3=p3+q3
b3=int(b3/10)
else len(b3)=1
p3=subs(c1,2*b3-1,2)
q3=p3+q3
enddo
q=q1+"年"+q2+"月"+q3+"日"
?Q
set talk on

谢谢！

do while len(b2)=2
Else
Enddo
do while len(b3)=2
Else
Enddo
这两个循环结构应该是有问题的。

年份您已经正确转换了，对月份，我是这么转换的(只用三行命令）：
lcYF=MONTH(X)
lcMonth='一 二 三 四 五 六 七 八 九 十 十一十二'
lcChmonth=AllTrim(lcMonth,((lcYF-1)*4+1),4)+'月'

日子嘛，您自己再搞一搞。
另外，你还必须考虑一下“〇”这个字符吧，比如2007年

[此贴子已经被作者于2007-6-12 19:42:42编辑过]

啸凡解释得挺好!

对，要考虑0的问题，可是我不大会啊，

能给我完整的代码吗？

谢谢了！

本人有收获，替啸凡总结一下：


set talk off
clear
x=date()
input "pls input a date :" to x
n_year=year(x)
n_month=month(x)
n_day=day(x)

&&计算年
cy_string='零一二三四五六七八九 '
c_year=""
for i=1 to 4
c_temp=substr(str(n_year,4),i,1)
n_temp=val(c_temp)+1
c_year=c_year+alltrim(substr(cy_string,((n_temp-1)*2+1),2))
endfor

&&计算月
lcYF=n_month
lcMonth='一 二 三 四 五 六 七 八 九 十 十一十二'
lcChmonth=alltrim(substr(lcMonth,((lcYF-1)*4+1),4))+'月'


&&计算日
cd_string='一 二 三 四 五 六 七 八 九 十 '
cd_string=cd_string+'十一 十二 十三 十四 十五 十六 十七 十八 十九 二十 '
cd_string=cd_string+'二十一二十二二十三二十四二十五二十六二十七二十八二十九三十 三十一'
c_day=alltrim(substr(cd_string,((n_day-1)*6+1),6))+'日'

c_date=c_year+"年"+lcChmonth+c_day
set date to ymd
set century on

? x," ",c_date

[此贴子已经被作者于2007-6-14 0:00:43编辑过]

呵呵，条条大路通罗马，楼上的算法也不错

CLEAR
dDate=DATE()
* 年
?CHRTRANC(TRANSFORM(YEAR(dDATE)),[0123456789],[〇一二三四五六七八九])+[年]
* 月
?GETWORDNUM([一,二,三,四,五,六,七,八,九,十,十一,十二],MONTH(DDATE),[,])+[月]
* 日
lcDay=[一,二,三,四,五,六,七,八,九,十,十一,十二,十三,十四,十五,十六,十七,十八,十九,二十,二十一,二十二,二十三,二十四,二十五,二十六,二十七,二十八,二十九,三十,三十一]
?GETWORDNUM(lcDay,Day(DDATE),[,])+[日]

这个命令用的够绝。。。
GETWORDNUM([一,二,三,四,五,六,七,八,九,十,十一,十二],MONTH(DDATE),[,])+[月]