msgbox窗口
msgbox窗口弹出后不按确定按钮，程序是否就不继续往下运行。如何才能在不按按钮，的情况下程序继续运行
griefforyou发过一个
'以下放到Moudle中
'**************************************
' Name: Auto close messagebox
' Description:This function replaces VB'
' s msgbox function and closes itself afte
' r the parameter provided number of secon
' ds. The syntax and return values are exa
' ctly the same as msgbox except the first
' parameter is the number of seconds to di
' splay. Just add this code to a module (n
' ot a cls or frm) in your project and cal
' l ACmsgbox. Thanks to Sparq's submission
' here for help in writing this.
'With the added parameter of
' By: Daniel Biener
'
'This code is copyrighted and has' limited warranties.Please see http://w
' ww.Planet-Source-Code.com/vb/scripts/Sho
' wCode.asp?txtCodeId=27940&lngWId=1
'for details.
'**************************************
'**************************************
'Windows API/Global Declarations for :Au
' to close messagebox
'**************************************
Private Declare Function SetTimer Lib "user32" (Byval hWnd As Long, Byval nIDEvent As Long, Byval uElapse As Long, Byval lpTimerFunc As Long) As Long
Private Declare Function KillTimer Lib "user32" (Byval hWnd As Long, Byval nIDEvent As Long) As Long
Private Declare Function FindWindow Lib "user32" Alias "FindWindowA" (Byval lpClassName As String, Byval lpWindowName As String) As Long
Private Declare Function SetForegroundWindow Lib "user32" (Byval hWnd As Long) As Long
Private Const NV_CLOSEMSGBOX As Long = &H5000&
Private sLastTitle As String
Public Function ACmsgbox(AutoCloseSeconds As Long, prompt As String, Optional buttons As Long, _
Optional title As String, Optional helpfile As String, _
Optional context As Long) As Long
sLastTitle = title
SetTimer Screen.ActiveForm.hWnd, NV_CLOSEMSGBOX, AutoCloseSeconds * 1000, AddressOf TimerProc
ACmsgbox = Msgbox(prompt, buttons, title, helpfile, context)
End Function
Private Sub TimerProc(Byval hWnd As Long, Byval uMsg As Long, Byval idEvent As Long, Byval dwTime As Long)
Dim hMessageBox As Long
KillTimer hWnd, idEvent
Select Case idEvent
Case NV_CLOSEMSGBOX
hMessageBox = FindWindow("#32770", sLastTitle)
If hMessageBox Then
Call SetForegroundWindow(hMessageBox)
SendKeys "{enter}"
End If
sLastTitle = vbNullString
End Select
End Sub
'调用代码
Private Sub Command1_Click()
ACmsgbox 3, "test", vbYes, "test"
End Sub
