代码都是网上抄来的，不知道有坑没有，请大家指教，同事也请大家分享一下自己掌握的简单易用的方法获取内外网IP的代码
IPSocket=CreateObject("MSWinsock.Winsock")
?"内网IP",IPSocket.LocalIP

test=CREATEOBJECT("WinHttp.WinHttpRequest.5.1")
test.OPEN("get","http://www.,.F.)
test.SEND
?"外网IP",test.responsetext

谢谢，不过我这用 www. 返回的是 ipv6 地址

若本机有多个 IP，推荐采用下述方法：

LOCAL ;
    oWMI AS OBJECT,;
    oLocal AS OBJECT,;
    oHARDWARE AS OBJECT,;
    object1 AS OBJECT,;
    cIP,;
    cMAC
oWMI = CREATEOBJECT("WbemScripting.SWbemLocator")
oLocal = oWMI.ConnectServer(".", "root\cimv2")
oHARDWARE = oLocal.ExecQuery("SELECT * FROM Win32_NetworkAdapterConfiguration Where IPEnabled=1")
FOR EACH object1 IN oHARDWARE
    cIP = object1.Properties_('IPAddress').VALUE
    cMAC = object1.Properties_('MACAddress').VALUE
    EXIT
ENDFOR
? 'IP地址：',cIP
? 'MAC地址：',cMAC

一个程序对外通信，对应的IP是唯一的

通过路由器界面查询的也是IPV6?
这倒是个新情况

公网IP查询可以用这个地址：http://

LOCAL zdrole1
zdrole1 = createObject('Microsoft.XMLHTTP')
zdrole1.open('GET' , 'http://' , .f.)
zdrole1.send()
resu_zjb_url =STREXTRACT(zdrole1.responseText,'<h2>','</h2>')
?resu_zjb_url

获取程序使用的内网IP地址
PROCEDURE getip
LOCAL dwSize, stTable, nTableCount,    dwLocalAddr, dwOwningPid,szLocalAddr,CurrentProcessId,ii
store "0.0.0.0" TO dwLocalAddr
Declare Integer GetCurrentProcessId In kernel32.Dll
DECLARE LONG GetExtendedTcpTable IN "Iphlpapi.dll" STRING@, LONG@, LONG, LONG, LONG, LONG
DECLARE LONG inet_ntoa IN "Ws2_32" LONG
DECLARE LONG ntohs IN "Ws2_32" LONG
DECLARE INTEGER CloseHandle IN kernel32 INTEGER hObject
DECLARE Long GetModuleFileNameEx IN PsApi  Long hProcess, Long hModule, String @ lpExename, Long dwSize
DECLARE Long OpenProcess IN WIN32API Long dwDesiredAccess, Long bInheritHandle, Long dwProcessId
CurrentProcessId=GetCurrentProcessId()
dwSize=0
GetExtendedTcpTable(NULL, @dwSize, 1, 2, 5, 0) && TCP_TABLE_OWNER_PID_ALL
IF m.dwSize > 0
    stTable = REPLICATE(0h0, m.dwSize) && 分配数据空间
    GetExtendedTcpTable(@stTable, @dwSize, 1, 2, 5, 0)
    nTableCount = CTOBIN(SUBSTR(m.stTable, 1, 4), "4Rs")
    IF m.nTableCount > 0
        stTable = STUFF(m.stTable, 1, 4, "")
        FOR ii = 1 TO m.nTableCount
            szLocalAddr = CTOBIN(SUBSTR(m.stTable, 5, 4), "4R")+2^31 && 本地 IP地址
            szLocalAddr = SYS(2600, inet_ntoa(m.szLocalAddr), 16)
            szLocalAddr = LEFT(szLocalAddr, AT(0h00, m.szLocalAddr)-1)
            dwOwningPid = CTOBIN(SUBSTR(m.stTable, 21, 4), "4R")+2^31 && 关联的进程ID
            IF m.CurrentProcessId=m.dwOwningPid
                dwLocalAddr=m.szLocalAddr
                exit
            endif
            stTable = STUFF(m.stTable, 1, 24, "")
        NEXT
    ENDIF
ENDIF
retu m.dwLocalAddr

公网获取ip地址返回ipv6的原因是因为我们的电脑同时支持ipv6,和ipv4，而且优先ipv6。

这里有简单获得本地IP地址，和外网ip地址的两个程序。
使用ipconfig命令获得本地ip地址，运行时会有个黑屏一闪而过，这个好像不能解决

CLEAR
lcTempFile = "D:\TEMP\temp.txt"
IF FILE(lcTempFile)
    ERASE (lcTempFile)
ENDIF

lcCommand = 'CMD /C "ipconfig > ' + lcTempFile + '"'
RUN &lcCommand

cstr=FILETOSTR(lcTempFile)
n=ALINES(atemp,cstr,CHR(13)+CHR(10))

FOR i=1 TO n
    IF "ipv4" $ LOWER(atemp[i])
        ?ALLTRIM(STREXTRACT(atemp[i],":",""))
        EXIT 
    ELSE 
        LOOP 
    ENDIF
ENDFOR

获得公网ip地址的程序如下：

CLEAR 
LOCAL lcURL, lcResult, lcIP

* 定义一个获取外网IP的URL
lcURL = "https:///ip" 
* 备用网址 https:[color=#808080]//api./jsonip[/color]
* 备用网址 https:[color=#808080]//www./ip &&需要关闭ipv6，否则显示ipv6格式的ip地址[/color]

* 使用WinHTTP对象发送HTTP GET请求
lcResult = GetHTTP(lcURL)

* 解析返回的JSON数据
IF !EMPTY(lcResult)
    *lcIP = STREXTRACT(lcResult, '"origin":"', '"')
    lcIP = STREXTRACT(lcResult, ["],["],3)
    ? "外网IP地址: " + lcIP
ELSE
    ? "无法获取外网IP地址"
ENDIF

FUNCTION GetHTTP(lcURL)
    LOCAL loHTTP, lcResponse
    loHTTP = CREATEOBJECT("WinHttp.WinHttpRequest.5.1")
    loHTTP.Open("GET", lcURL, .F.)
    loHTTP.Send()
    WAIT "正在查询ip地址。。。" WINDOW AT 35,130 TIMEOUT 3
    lcResponse = loHTTP.ResponseText
    RETURN lcResponse
ENDFUNC

*!*  参考一片空白，吹水佬
DECLARE long CreateProcess       IN kernel32 as apiCreateProcess       string@,string@,string@,string@,long,long,string@,string@,string@,string@
DECLARE long CloseHandle         IN kernel32 as apiCloseHandle         long
DECLARE long WaitForSingleObject IN kernel32 as apiWaitForSingleObject long,long
DECLARE long CreateFileW         IN kernel32 as apiCreateFileW         string,long,long,string@,long,long,long
DECLARE long GetFileSize         IN kernel32 as apiGetFileSize         long,long@
DECLARE long CloseHandle         IN kernel32 as apiCloseHandle         long
DECLARE long ReadFile            IN kernel32 as apiReadFile            long,string@,long,long@,string@
DECLARE long WriteFile           IN kernel32 as apiWriteFile           long,string@,long,long@,string@
Declare long CreatePipe          IN kernel32 as apiCreatePipe           Long@,Long@,string@,Long
#define CREATE_NO_WINDOW        0x08000000
#define GENERIC_READ            0x80000000
#define GENERIC_WRITE           0x40000000
#define FILE_SHARE_READ         1
#define FILE_SHARE_WRITE        2
#define FILE_ATTRIBUTE_NORMAL   0x80
#define CREATE_ALWAYS           2
#define OPEN_EXISTING           3
#define INVALID_HANDLE_VALUE    -1

Execmd="ipconfig"
cstr=Docmd(Execmd)
n=ALINES(atemp,cstr,CHR(13)+CHR(10))
FOR i=1 TO n
    IF "ipv4" $ LOWER(atemp[i])
        ?ALLTRIM(STREXTRACT(atemp[i],":",""))
        EXIT
    ELSE
        LOOP
    ENDIF
ENDFOR
RETURN

FUNCTION DoCmd(cmd)
    LOCAL si, pi,sa,h_read ,h_write,cBuffers,cBuffer,bytes_read
    STORE 0 TO m.h_read,m.h_write,m.bytes_read
    sa=BINTOC(12,"4rs")+BINTOC(0,"4rs")+BINTOC(1,"4rs")
    IF 0==apiCreatePipe(@m.h_read ,@m.h_write ,@sa ,0)
      RETURN ""
    ENDIF
    si = BINTOC(68, "4RS") + REPLICATE(0h00,40)+BINTOC(257,"4RS")+REPLICATE(0h00,12)+BINTOC(m.h_write,"4rs")+REPLICATE(0h00,4)
    pi = REPLICATE(0h00, 16)                        
    IF apiCreateProcess(null,cmd,NULL,NULL,1,CREATE_NO_WINDOW,NULL,null,@si,@pi) == 0
        apiCloseHandle(m.h_write)
        apiCloseHandle(m.h_read)
        RETURN ""
    ENDIF
   
    LOCAL hProcess, hThread
    hProcess = CTOBIN(SUBSTR(pi, 1, 4), "4rs")
    hThread  = CTOBIN(SUBSTR(pi, 5, 4), "4rs")
    apiCloseHandle(m.h_write)
    apiCloseHandle(hProcess)
    apiCloseHandle(hThread)
    m.cBuffers=""
    DO WHILE .t.
        m.cBuffer=REPLICATE(CHR(0),2048)
        m.bytes_read=0
        IF apiReadFile(m.h_read ,@m.cbuffer,2048 ,@m.bytes_read ,0) = 0
           EXIT
        ELSE
           m.cBuffers=m.cBuffers+LEFT(m.cBuffer,m.bytes_read)
        ENDIF
    ENDDO
    apiCloseHandle(m.h_read)
    RETURN m.cBuffers
ENDFUNC

获取本地IP地址，上面的 代码 都得不到正确的IP

比如：笔记本 WIFI联网的