品种     机号
A         5
B         4
A         1
A         3
A         2
B         6
B         7
我想把表做成：
品种
A        5  1  3  2  
B        4  6  7

请问用VFP怎么实现？高，谢谢！

CREATE CURSOR test (品种 c(1), 机号 n(1))
INSERT INTO test VALUES ("A", 5)
INSERT INTO test VALUES ("B", 4)
INSERT INTO test VALUES ("A", 1)
INSERT INTO test VALUES ("A", 3)
INSERT INTO test VALUES ("A", 2)
INSERT INTO test VALUES ("B", 6)
INSERT INTO test VALUES ("B", 7)
SELECT 品种, COUNT(*) lnCnt FROM test GROUP BY 1 ORDER BY 2 DESC INTO ARRAY aa
lcStr = "品种 c(1)"
FOR ln = 1 TO aa[1,2]
    lcStr = lcStr + ", S" + TRANSFORM(ln) + " n(1)"
ENDFOR
CREATE CURSOR t1 (&lcStr) && 保存最后结果
INSERT INTO t1 (品种) SELECT DISTINCT 品种 FROM test 
INDEX ON 品种 TAG t1
CREATE CURSOR t2 (品种 c(1), js N(4)) && 记录字段列序号
INSERT INTO t2 (品种) SELECT DISTINCT 品种 FROM test 
INDEX ON 品种 TAG t2
SELECT test
SCAN 
    IF SEEK(test.品种, "t2", "t2") = .T.
        REPLACE js WITH js + 1 IN t2
        ln = t2.js
        IF SEEK(test.品种, "t1", "t1") = .T.
            REPLACE ("S" + TRANSFORM(ln)) WITH test.机号 IN t1
        ENDIF 
    ENDIF
ENDSCAN
SELECT t1
BROWSE 

还可以通过数组的方法解决问题

一种简单的归类，安品种划分记录条就好。

未看明这样转换想表达什么，有什么意义？

这样的转置，你还是跑到EXCEL中做，很方便的。

*多一种方法理解一下
SELECT 0
CREATE CURSOR 表1(品种 c(5),机号 c(5))
INSERT INTO 表1 VALUES ("A", '5')
INSERT INTO 表1 VALUES ("B", '4')
INSERT INTO 表1 VALUES ("A", '1')
INSERT INTO 表1 VALUES ("A", '3')
INSERT INTO 表1 VALUES ("A", '2')
INSERT INTO 表1 VALUES ("B", '6')
INSERT INTO 表1 VALUES ("B", '7')

SELECT 0
CREATE CURSOR 表2(A c(5),B c(5))

SELECT 表1
GO top
DO WHILE .NOT.EOF()
pz=UPPER(ALLTRIM(品种))
jh=ALLTRIM(机号)
SELECT 表2
LOCATE FOR empty(&pz)
IF .not.FOUND()
APPEND BLANK
ENDIF
REPLACE &pz WITH JH
SELECT 表1
SKIP
ENDDO
SELECT 表2
BROWSE

谢谢二楼，正是我想要的结果。
七楼的结果行列颠倒了，如果能倒过来就对了。
其实我想要的是机号连成一行文本，写在一个字段里。我就可以转成word文件去打印了。
这样的表现实很有意义的，一个品种有哪机台机在做。

品种     机号
A         5
B         4
A         1
A         3
A         2
B         6
B         7
我想把表做成：
品种   机        号
A        5  1  3  2  （机号是一个字符型字段）
B        4  6  7
然后我可以做成报表或导出到excel或者word打印。

2楼的代码变一下就可以，更简单些了。