菜单内容较少，不想让其独占一行。想让菜单放在表单左上角，在表单中，但不要独占一行。如何能做到？

[此贴子已经被作者于2019-8-12 10:24编辑过]

应该可以加入到表单标题的菜单里

通过快捷菜单的方法达到楼主的需求，通俗的说用右键的方法解决这个问题

能具体点吗？

朋友你可能是在顶层表单里加入的菜单吧？
如果菜单的内容太少了，那你可以改成工具栏
在项层表单里加入自定义工具栏，就能实现你的诉求。

参考示例：


* 窗口标题系统菜单添加菜单项
* 点击窗口标题菜单或<Shift+右键>任务栏图标
*** test.prg ***
_screen.Visible = .F.
DECLARE LONG GetSystemMenu IN User32 LONG, LONG
DECLARE LONG AppendMenu IN User32 LONG, LONG, LONG, STRING@
DECLARE LONG SendMessage IN User32 LONG, LONG, LONG, LONG
of = CREATEOBJECT("form1")
of.show
READ EVENTS
RETURN

DEFINE CLASS form1 AS Form
    ShowWindow = 2
    AutoCenter = .T.
    PROCEDURE Init
        LOCAL hMenu
        hMenu = GetSystemMenu(this.hWnd, 0)
        AppendMenu(hMenu, 0, 0x1001, "菜单项1")
        AppendMenu(hMenu, 0, 0x1002, "菜单项2")
        AppendMenu(hMenu, 0, 0x1003, "菜单项3")
        BINDEVENT(this.hWnd, 0x0112, this, "myMenuCmd") && WM_SYSCOMMAND 0x0112
    ENDPROC
    PROCEDURE UnLoad
        CLEAR EVENTS
    ENDPROC
    PROCEDURE myMenuCmd(hWnd, Msg, wParam, lParam)
        DO CASE
        CASE wParam == 0x1001
            MESSAGEBOX("菜单项1")
        CASE wParam == 0x1002
            MESSAGEBOX("菜单项2")
        CASE wParam == 0x1003
            MESSAGEBOX("菜单项3")
        ENDCASE
        SendMessage(hWnd, Msg, wParam, lParam)
    ENDPROC
ENDDEFINE

也可以通过系统定义快捷菜单，也很方便，可在表彰上使用也可在桌面使用。

6楼吹版主的方式，适用面广，稳定性可靠性强。

使用快捷菜单的确可以实现，也能满足我的需求；
另外，吹版的我测试，显示如下：

学习，谢谢！