我使用vsflexgrid控件，想实现 MSFlexGrid 控件单数行背景为白色，双数的行背景为黄色，
代码如下：
With VSFlexGrid1
   
   
    For i = 0 To .Rows - 1

        If i Mod 2 = 0 Then
        .CellBackColor = &HC0E0FF    ' 浅黄
        Else
        .CellBackColor = vbWhite ' 白色
        End If
    Next i
End With
可是不灵。请高手指教。
第二个问题，如何隐藏那个水平滚动条？
第三个问题，如何实现选中一个单元格使其背景色为蓝色。谢谢！

[此贴子已经被作者于2019-6-2 12:21编辑过]

顶起来。现在第一个问题搞好了，找到了一个函数。
Public Sub SetRowColor(ByRef MSHFlexGrid As Object)
    Dim J, i, objName
    objName = TypeName(MSHFlexGrid)

    If StrConv(Trim(objName), vbUpperCase) <> "VSFLEXGRID" Then
        Exit Sub
    End If

    MSHFlexGrid.FillStyle = 1

    For i = 1 To MSHFlexGrid.Rows - 1
        MSHFlexGrid.Row = i

        If i Mod 2 = 0 Then
            MSHFlexGrid.Col = 0
            MSHFlexGrid.ColSel = MSHFlexGrid.Cols - 1
            MSHFlexGrid.CellBackColor = &H80000018
        End If

    Next i
   
    For i = 1 To MSHFlexGrid.Rows - 1
        MSHFlexGrid.Row = i
        MSHFlexGrid.Col = 0
        MSHFlexGrid.CellBackColor = &H8000000F

    Next i

    MSHFlexGrid.FillStyle = 0
    MSHFlexGrid.Row = 0
    MSHFlexGrid.Col = 0
End Sub
其他两个问题还没解决。

Option Explicit

Dim OldVSFRow As Integer
Dim OldVSFCol As Integer

Private Sub Form_Load()
  With VSFlexGrid1
       .Cols = 20
       .Rows = 20
       .ScrollBars = flexScrollBarVertical
       .BackColorAlternate = &HC0E0FF
       .AllowBigSelection = False
       .AllowSelection = False
  End With
  
  OldVSFRow = 1
  OldVSFCol = 1
End Sub

Private Sub VSFlexGrid1_Click()
  If OldVSFRow Mod 2 = 1 Then
     VSFlexGrid1.Cell(flexcpBackColor, OldVSFRow, OldVSFCol) = vbWhite
  Else
     VSFlexGrid1.Cell(flexcpBackColor, OldVSFRow, OldVSFCol) = &HC0E0FF
  End If
  VSFlexGrid1.CellBackColor = vbBlue
  OldVSFRow = VSFlexGrid1.RowSel
  OldVSFCol = VSFlexGrid1.ColSel
End Sub

谢谢分享

[此贴子已经被作者于2019-6-8 00:02编辑过]

谢谢分享！