试了一下，WIN10的windows文件夹拒绝访问（GetLastError()返回5）
可能是有权限的。

如果只是查找指定文件用不着这么麻烦

改了一下，处理异常情况。
DECLARE LONG FindFirstFile IN Kernel32 STRING@, STRING@
DECLARE LONG FindNextFile IN Kernel32 LONG, STRING@
DECLARE LONG FindClose IN Kernel32 LONG
DECLARE LONG GetLastError IN Kernel32
cPath = "D:\" &&GETDIR()
IF EMPTY(cPath)
    RETURN
ENDIF
DIMENSION arrDIR[1], arrFile[1], arrError[1]
arrDIR[1] = cPath
stFD = SPACE(320)
nCountD = 1
nCountF = 0
nCountE = 0
FOR EACH cPath IN arrDIR
    hf = FindFirstFile(cPath+"*.*", @stFD)
    IF hf == -1
        nCountE = nCountE + 1
        DIMENSION arrError[nCountE]
        arrError[nCountE] = "Error:"+TRANSFORM(GetLastError())+ "  "+cPath
        LOOP
    ENDIF
    DO WHILE .T.
        nFileAttr = CTOBIN(SUBSTR(stFD,1,4),"4RS")
        cFileName = SUBSTR(stFD,45,260)
        cFileName = LEFT(cFileName, AT(0h00,cFileName)-1)
        IF BITAND(nFileAttr,0x10) != 0    &&目录
            IF !(cFileName==".") AND !(cFileName=="..")
                nCountD = nCountD + 1
                DIMENSION arrDIR[nCountD]
                arrDIR[nCountD] = cPath + cFileName + "\"
            ENDIF
        ELSE    &&文件
            nCountF = nCountF + 1
            DIMENSION arrFile[nCountF]
            arrFile[nCountF] = cPath + cFileName
        ENDIF
        IF FindNextFile(hf, @stFD) == 0
            EXIT
        ENDIF
    ENDDO
    FindClose(hf)
ENDFOR
? nCountF,"个文件", nCountD,"个文件夹", nCountE,"个文件夹搜索出现异常"
CREATE CURSOR tt (fn C(240))
DIMENSION arrFile[nCountF,1]
APPEND FROM ARRAY arrFile  
GO TOP
BROWSE
ZAP
DIMENSION arrError[nCountE,1]
APPEND FROM ARRAY arrError
GO TOP
BROWSE

如果没指定路径或没设定搜索路径，也要先枚举路径，还有不同文件夹存在同一文件名。
资源管理器的文件搜索功能，如果关闭索引速度也不快。

我的VF是8.0的，出现无效的下标　提示

6也会提示，只有在9下可以。

吹版的试了下，速度是提高了，但D盘文件少了很多，C盘的数据和昨天测试的差不多，不知什么原因。

在windows中试了下文件统计（D盘，数据差别较大）

对比测试了一下，用VFP的ADIR()搜索，结果与13楼用API的一样。
代码：
cPath = "D:\" &&GETDIR()
IF EMPTY(cPath)
    RETURN
ENDIF
DIMENSION arrDIR[1], arrFile[1], arrError[1]
arrDIR[1] = cPath
nCountD = 1
nCountF = 0
nCountE = 0
FOR EACH cPath IN arrDIR
    nCount = ADIR(arr_tmp, cPath+"*.*","RASHD")
    IF nCount < 1
        nCountE = nCountE + 1
        DIMENSION arrError[nCountE]
        arrError[nCountE] = "失败：" + cPath
        LOOP
    ENDIF
    FOR i=1 TO nCount
        IF "D"$arr_tmp[i,5]
            IF !(arr_tmp[i,1]==".") AND !(arr_tmp[i,1]=="..")
                nCountD = nCountD + 1
                DIMENSION arrDIR[nCountD]
                arrDIR[nCountD] = cPath + arr_tmp[i,1] + "\"
            ENDIF
        ELSE
            nCountF = nCountF + 1
            DIMENSION arrFile[nCountF]
            arrFile[nCountF] = cPath + arr_tmp[i,1]
        ENDIF
    ENDFOR
ENDFOR
? nCountF,"个文件", nCountD,"个文件夹", nCountE,"个文件夹搜索出现异常"
CREATE CURSOR tt (fn C(240))
DIMENSION arrFile[nCountF,1]
APPEND FROM ARRAY arrFile  
GO TOP
BROWSE
ZAP
DIMENSION arrError[nCountE,1]
APPEND FROM ARRAY arrError
GO TOP
BROWSE

吹版，请修改程序，可以获取文件或目录的名称、大小、日期、时间和属性，以及文件的详细版本信息。

AGETFILEVERSION()函数可以获取文件版本信息。