我做了一个.只运行一次程序带托盘的.但当收缩到托盘时.再运行程序不能激活窗体
请大家帮忙
单元代码如下
unit wdRunOnce;

{*******************************************
 * brief: 让程序只运行一次
 * autor: linzhenqun
 * date: 2005-12-28
 * email: linzhengqun@
 * blog: http://blog.
********************************************}

interface

(* 程序是否已经运行，如果运行则激活它 *)
function AppHasRun(AppHandle: THandle): Boolean;


implementation
uses
  Windows, Messages;

const
  MapFileName = '{CAF49BBB-AF40-4FDE-8757-51D5AEB5BBBF}';

type
  //共享内存
  PShareMem = ^TShareMem;
  TShareMem = record
    AppHandle: THandle;  //保存程序的句柄
  end;

var
  hMapFile: THandle;
  PSMem: PShareMem;

procedure CreateMapFile;
begin
  hMapFile := OpenFileMapping(FILE_MAP_ALL_ACCESS, False, PChar(MapFileName));
  if hMapFile = 0 then
  begin
    hMapFile := CreateFileMapping($FFFFFFFF, nil, PAGE_READWRITE, 0,
      SizeOf(TShareMem), MapFileName);
    PSMem := MapViewOfFile(hMapFile, FILE_MAP_WRITE or FILE_MAP_READ, 0, 0, 0);
    if PSMem = nil then
    begin
      CloseHandle(hMapFile);
      Exit;
    end;
    PSMem^.AppHandle := 0;
  end
  else begin
    PSMem := MapViewOfFile(hMapFile, FILE_MAP_WRITE or FILE_MAP_READ, 0, 0, 0);
    if PSMem = nil then
    begin
      CloseHandle(hMapFile);
    end
  end;
end;

procedure FreeMapFile;
begin
  UnMapViewOfFile(PSMem);
  CloseHandle(hMapFile);
end;

function AppHasRun(AppHandle: THandle): Boolean;
var
  TopWindow: HWnd;
begin
  Result := False;
  if PSMem <> nil then
  begin
    if PSMem^.AppHandle <> 0 then
    begin
      SendMessage(PSMem^.AppHandle, WM_SYSCOMMAND, SC_RESTORE, 0);
      TopWindow := GetLastActivePopup(PSMem^.AppHandle);
      if (TopWindow <> 0) and (TopWindow <> PSMem^.AppHandle) and
        IsWindowVisible(TopWindow) and IsWindowEnabled(TopWindow) then
        SetForegroundWindow(TopWindow);
      Result := True;
    end
    else
      PSMem^.AppHandle := AppHandle;
  end;
end;

initialization
  CreateMapFile;

finalization
  FreeMapFile;

end.

用第三方控件多好

用共享映射文件来做这个直接就是杀鸡用大关刀了，好简单的方法
先给主窗口一个自定义的类名字，在给个函数用 FindWindow 看看找不找到这个窗口，若找不到，则允许自己启动，若找到，给这个窗口发个消息让它活动
unit ...
interface
type
  TMainForm = class(TForm)
  ...
  protected
    procedure CreateParams(var Params: TCreateParams); override;
  end;
...
function AppCanStart: Boolean;

implementation
const
  MyWindowClassName = 'MyWindowsClassName2020-1';

procedure TMainForm.CreateParams(var Params: TCreateParams);
begin
  inherited;
  Params.WinClassName:= MyWindowClassName;
end;
function AppCanStart: Boolean;
var
  FWnd: HWND;
begin
  FWnd:= FindWindow(MyWindowClassName, nil);  
  if IsWindow(FWnd) then begin
    SetForeGroundWindow(FWnd);
    Result:= False;
  end else begin
    Result:= True;
  end;
end;

DPR 中：
begin
  if AppCanStart then begin
  Application.Initialize;
  Application.CreateForm(TMainForm, MainForm);
  Application.Run;
  end;
end.