帮忙看下这里的语句要怎么改，谢谢 - VFP论坛

问题点数：0 回复次数：5

帮忙看下这里的语句要怎么改，谢谢

use 用户表
  do case
  case thisform.Optiongroup1.option1.value=1
GO TOP
    flag=0
    do while not eof()
        IF Alltrim(用户名)==Alltrim(Thisform.Text1.Value)
           IF Alltrim(用户密码)==Alltrim(Thisform.Text2.Value)
            if Alltrim(用户类型)=="系统管理员"
             do form  主控制平台
                ELSE
              WAIT "不能访问" WINDOW TIMEOUT 1
             endif
            flag=1
            EXIT
        ENDIF
    endif
     skip
       enddo
    IF flag=0
        WAIT "用户名错误" WINDOW TIMEOUT 2
    ENDIF
case thisform.Optiongroup1.option2.value=2
  GO TOP
    flag=0
    do while not eof()
        IF Alltrim(用户名)==Alltrim(Thisform.Text1.Value)
           IF Alltrim(用户密码)==Alltrim(Thisform.Text2.Value)
            if Alltrim(用户类型)=="一般用户"
             do form  主控制平台1
                ELSE
              WAIT "不能访问" WINDOW TIMEOUT 1
             endif
            flag=1
            EXIT
        ENDIF
    endif
     skip
       enddo
    IF flag=0
        WAIT "用户名错误" WINDOW TIMEOUT 2
    ENDIF
endcase

我运行的时候，只能运行前面部分，而且前面部分如果密码错误的话也不显示“不能访问”

搜索更多相关主题的帖子: 系统管理员　用户名　密码　

第 2 楼

得分:0

locate for (Alltrim(用户名)==Alltrim(Thisform.Text1.Value)) and (Alltrim(用户密码)==Alltrim(Thisform.Text2.Value))
if found()
    do case
       case Alltrim(用户类型)=="一般用户"
           do form  主控制平台1

       case Alltrim(用户类型)=="系统管理员"
           do form  主控制平台
       other
              WAIT "不能访问" WINDOW TIMEOUT 1
    endcase
else
   WAIT "用户名或密码不正确！" WINDOW TIMEOUT 1
endif

第 3 楼

得分:0

回复 2 楼 zjj1974

谢谢你！！！！

第 4 楼

得分:0

不用客气

第 5 楼

得分:0

如果要区分是用户名错误还是用户密码错误，可修改为：

程序代码：

locate for Alltrim(用户名)==Alltrim(Thisform.Text1.Value)
do case
case !found()
    WAIT "用户名不正确！" WINDOW TIMEOUT 1
case !Alltrim(用户密码)==Alltrim(Thisform.Text2.Value)
    WAIT "密码不正确！" WINDOW TIMEOUT 1
case Alltrim(用户类型)=="一般用户"
    do form  主控制平台1
case Alltrim(用户类型)=="系统管理员"
    do form  主控制平台
other
    WAIT "不能访问" WINDOW TIMEOUT 1 
endcase

泉城飞狐

第 6 楼

得分:0

看来关键在思路。