以下是引用sdta在2014-7-5 14:10:36的发言：

Clear
kc_name = ""
accept "请输入待查询的课程名：" to kc_name
Select * From 课程表kc Where alltrim(课程名)=alltrim(kc_name) Into Cursor Temp
If Reccount("Temp")=0
    Return messagebox("课程名<"+kc_name+">不存在")
Endif
If Not Empty(kc_name)
    select a.课程名, b.学号,c.姓名,b.成绩 from 课程表kc a Inner join 选课表xk b on a.课程号=b.课程号 ;
     Inner join 学生表stu c on b.学号=c.学号 where alltrim(a.课程名)=alltrim(kc_name) into cursor 结果表jg
    if reccount("结果表jg")=0
        messagebox("没有人选择该课程<"+kc_name+">")
    else
        browse
    Endif
Else
    messagebox("kc_name 不能为空")
Endif

以下是引用吹水佬在2014-7-5 10:26:55的发言：

** 用数据关联举个例子
CREATE CURSOR stu (学号 C(5), 姓名 C(10))
INSERT INTO stu VALUES ("93061", "王燕")
INSERT INTO stu VALUES ("93062", "李丽")
INSERT INTO stu VALUES ("93063", "詹贵")
INSERT INTO stu VALUES ("93064", "潘泰")
INSERT INTO stu VALUES ("93065", "戚莎")
INSERT INTO stu VALUES ("92061", "张平")
INSERT INTO stu VALUES ("92062", "赵东")

CREATE CURSOR kc (课程号 C(4), 课程名 C(10))
INSERT INTO kc VALUES ("C801", "数据结构")
INSERT INTO kc VALUES ("C802", "多媒体")
INSERT INTO kc VALUES ("C803", "数据库")
INSERT INTO kc VALUES ("C804", "C++语言")
INSERT INTO kc VALUES ("C805", "WEB设计")
INSERT INTO kc VALUES ("C806", "操作系统")
INSERT INTO kc VALUES ("C807", "接口技术")
INSERT INTO kc VALUES ("C808", "程序设计")

CREATE CURSOR xk (学号 C(5), 课程号 C(4), 成绩 I)
INSERT INTO xk VALUES ("93061", "C808", 61)
INSERT INTO xk VALUES ("93061", "C803", 78)
INSERT INTO xk VALUES ("93062", "C803", 90)
INSERT INTO xk VALUES ("93062", "C804", 48)
INSERT INTO xk VALUES ("93063", "C804", 89)
INSERT INTO xk VALUES ("93063", "C803", 65)
INSERT INTO xk VALUES ("93064", "C806", 82)
INSERT INTO xk VALUES ("92061", "C804", 91)
INSERT INTO xk VALUES ("93065", "C802", 70)
INSERT INTO xk VALUES ("92062", "C805", 76)

SELECT stu
INDEX on 学号 TAG 学号

SELECT kc
INDEX on 课程号 TAG 课程号

SELECT xk
SET RELATION TO 学号 INTO "stu", 课程号 INTO "kc"

**m课程名 = INPUTBOX("输入查询课程名") && VFP6.0这行代码不能执行

**可改为下面两行代码
m课程名=""
accept "请输入待查询的课程名：" to m课程名

IF !EMPTY(m课程名)
    **BROWSE FIELDS xk.学号, stu.姓名, xk.成绩 FOR RTRIM(kc.课程名) == "数据库"
    SET FILTER TO RTRIM(kc.课程名) == ALLTRIM(m课程名)
    GO TOP
    BROWSE FIELDS xk.学号, stu.姓名, xk.成绩
    SET FILTER TO
    GO TOP
ENDIF

SET RELATION TO