This.LineStyle= 1  && tvwRootLines
This.Style= 7  && tvwTreelinesPlusMinusPictureText
This.ImageList=Thisform.Imagelist1   &&与Imagelist控件建立关联
*This.SingleSel=.t.
SELECT bm
SET DELETED ON
GO TOP
DO WHILE !EOF()
   &&添加部门节点，以唯一的部门编号字段作为控件的Key
   This.Nodes.Add(,,ALLTRIM(bm.bmdm),ALLTRIM(bm.bm),1,3)
               
  *（ 属于，子节点，名称，标题）节点的名称就用编号，子节点的属于就用节点的名称，就是bmdm。

   SELECT wjmjs
   SET DELETED ON
   SET FILTER TO ALLTRIM(wjmjs.bmdm)=ALLTRIM(bm.bmdm)
   GO TOP

   &&添加部门中人员节点，以唯一的Key字段值作为控件的Key
   DO WHILE !EOF()
     This.Nodes.Add(ALLTRIM(bm.bmdm),4,ALLTRIM(wjmjs.Key),ALLTRIM(wjmjs.lxr),3,3) **********提示错误ole IDispatch 异常代码 0 出自Nodes: Key is not unique in collection
      SKIP
   ENDDO

   SELECT bm
   SKIP
ENDDO
SELECT wjmjs
SET FILTER TO
GO TOP
SELECT bm
GO TOP


数据库文件

没看出来是问问题的   还是分享的

This.Nodes.Add(ALLTRIM(bm.bmdm),4,ALLTRIM(wjmjs.Key),ALLTRIM(wjmjs.lxr),3,3) **********提示错误ole IDispatch 异常代码 0 出自Nodes: Key is not unique in collection

.  .

[ 本帖最后由 qingfameng 于 2014-5-10 07:22 编辑 ]

我仔细测试了楼主的代码，发现错误出在 SET FILTER TO ALLTRIM(wjmjs.bmdm)=ALLTRIM(bm.bmdm) 这一条语句上。
当 bm.bmdm = 'B1'时，wjmjs.dbf 将显示 wjmjs.bmdm 等于 B1 或 B11 的记录，这就造成 B11 的记录重复显示了，在第二次重复添加节点时，因节点 Key 不唯一而报错。
将代码改为 SET FILTER TO ALLTRIM(wjmjs.bmdm)==ALLTRIM(bm.bmdm) 就 OK 了。

认真负责！

认真负责！