Option Explicit
'Line3 表示时针
'Line1(1) 表示分针（长度960）
'Line2 表示秒针（长度1200）
'Timer 定时器周期1s
'Label2 标签显示当前系统时间
Dim xx1 As Integer '表盘圆心坐标
Dim yy1 As Integer
Dim MyTime, MyHour, MyMinute, MySecond As Integer '定义当前时间，时，分，秒
Dim S_ang, M_ang, H_ang As Single '定义角度变量
Dim S_rad, M_rad, H_rad As Single '定义弧度变量
Dim S_Length, M_Length, H_Length As Integer '定义表针长度变量
Private Sub Form_Load()
xx1 = 2280  '由属性确定圆心坐标
yy1 = 1920
Line3.X1 = xx1  '校准表盘坐标原点
Line3.Y1 = yy1
Line1(1).X1 = xx1
Line1(1).Y1 = yy1
Line2.X1 = xx1
Line2.Y1 = yy1
MyTime = Now  '暂存当前时间值
MySecond = Second(MyTime)  '读取秒
MyMinute = Minute(MyTime)  '读取分
MyHour = Hour(MyTime)      '读取时
M_ang = MyMinute * 6       '任意一点分针角度
M_rad = (3.14 / 180) * M_ang
H_ang = MyHour * 30         '任意一点时针角度
H_rad = (3.14 / 180) * H_ang
Line1(1).X2 = Line1(1).X1 + (960 * Sin(M_rad))     '计算X2，Y2转动坐标 （以单位圆Y轴为0度）
Line1(1).Y2 = Line1(1).Y1 - (960 * Cos(M_rad))
Line3.X2 = Line3.X1 + (720 * Sin(H_rad))     '计算X2，Y2转动坐标 （以单位圆Y轴为0度）
Line3.Y2 = Line3.Y1 - (720 * Cos(H_rad))
End Sub
Private Sub Timer1_Timer()
Label2.Caption = Now
MyTime = Now  '暂存当前时间值
MySecond = Second(MyTime)  '读取秒
Label15.Caption = MySecond
MyMinute = Minute(MyTime)  '读取分
Label18.Caption = MyMinute
MyHour = Hour(MyTime)      '读取时
Label20.Caption = MyHour
S_ang = MySecond * 6       '任意一点秒针角度
M_ang = MyMinute * 6       '任意一点分针角度
M_rad = (3.14 / 180) * M_ang
H_ang = MyHour * 30         '任意一点时针角度
H_rad = (3.14 / 180) * H_ang
S_rad = (3.14 / 180) * S_ang
Line2.X2 = Line2.X1 + (1200 * Sin(S_rad)) '计算X2，Y2转动坐标 （以单位圆Y轴为0度）
Line2.Y2 = Line2.Y1 - (1200 * Cos(S_rad))
If MySecond = 59 Then
Line1(1).X2 = Line1(1).X1 + (960 * Sin(M_rad))     '计算X2，Y2转动坐标 （以单位圆Y轴为0度）
Line1(1).Y2 = Line1(1).Y1 - (960 * Cos(M_rad))
ElseIf MyMinute = 59 Then
Line3.X2 = Line3.X1 + (720 * Sin(H_rad))     '计算X2，Y2转动坐标 （以单位圆Y轴为0度）
Line3.Y2 = Line3.Y1 - (720 * Cos(H_rad))
End If
End Sub
请看到的朋友们，挑毛病找缺陷。

结帖率：0

网速有问题，刷新后重复发内容了。

[ 本帖最后由 lowxiong 于 2014-2-10 23:07 编辑 ]

怎么的也应该画个表盘吧，把有类似运算的用函数调用完成，可减少很多代码，你的时针和分针应计算到小数部分，否则时针会一下跳30度，没有中间值（比如10：30，你的时针仍然指在10点，而不是在10至11点之间，分针亦如此），看我的代码，直接用画线命令写的，应该比你的精细些（新建一工程，添加一个timer控件，拷贝下列代码即可）。


Dim iOx As Integer, iOy As Integer    '原点坐标
Dim iOr As Single                     '秒钟长

Private Sub DrawLine(iRadiu As Single, iDeg As Single, iLen As Single, iThin As Integer, iColor As Long)
  '围绕原点画指定长度、粗细、颜色的线
  Dim j As Single, x1 As Single, y1 As Single, x2 As Single, y2 As Single
  j = 3.1415926 * iDeg / 180 '转化为弧度
  x1 = iOx + iRadiu * Sin(j): y1 = iOy - iRadiu * Cos(j)
  If iLen > 0 Then
    x2 = iOx + (iRadiu - iLen) * Sin(j): y2 = iOy - (iRadiu - iLen) * Cos(j)
  Else
    x2 = iOx + iLen * Sin(j): y2 = iOy - iLen * Cos(j)
  End If
  Me.DrawWidth = iThin
  Me.Line (x1, y1)-(x2, y2), iColor
End Sub

Private Sub Form_Load()
  Me.AutoRedraw = True
  Timer1.Interval = 1000
  iOx = Me.ScaleWidth * 0.5
  iOy = Me.ScaleHeight * 0.5
  iOr = iOy * 0.7                '根据窗口大小自动计算原点坐标和时钟半径
End Sub

Private Sub Timer1_Timer()
  Dim d As Date, s As Single, m As Single, h As Single, i As Single
  d = Time
  s = Second(d)
  m = Minute(d) + s / 60
  h = Hour(d) + m / 60
  If h > 12 Then h = h - 12
  Me.Cls
  For i = 0 To 359 Step 6
    '画表盘
    DrawLine iOr, i, 60, 2, vbBlack
    If i Mod 5 = 0 Then DrawLine iOr, i, 90, 4, vbBlue
  Next
  DrawLine iOr * 0.65, h * 30, iOr * 0.65, 6, vbRed
  DrawLine iOr * 0.85, m * 6, iOr * 0.85, 4, vbGreen
  DrawLine iOr, s * 6, -300, 2, vbBlue
  Me.Circle (iOx, iOy), 60
End Sub

这个东懂关键是指针角度的计算问题。

恩，对的。就是三角函数。

不错，做的的确很精细。向您学习了。
确实我没做您说的小数问题
以后有问题可以常常交流。

追加说明：
这个表实际上是有表盘的，只不过我用的是Line控件和shape控件，手工画的。确实不够好看。