方法一：用OLE打开Excel填数，VBA代码。
方法二：将二维数组写成文本文件，从Excel导入。

恩，...

你原先想的应该是第一种方法，但对单元格的引用格式不了解。其实用Cells(nRow,nCol).Value = Expression就可以了。

以下是我曾给出的将数据库数据写到Excel中的程序，原理是一样的。看看怎么引用单元格的就知道了。

USE new IN 0
dbf2sheet("new", ADDBS(JUSTPATH(FULLPATH("new.dbf"))) + "Export.xlsx", "導出數據5")
RETURN 

*------------------------------------
* 將數據表導出到Excel表格
* 參數：tcAlias -- 數據表工作區別名
*       tcBook  -- Excel 工作簿文件名（帶全路徑、擴展名）
*       tcSheet -- 工作表名稱（自動新增，不可與工作簿中已有Sheet重名）
*------------------------------------
PROCEDURE dbf2sheet(tcAlias AS Character, tcBook AS Character, tcSheet AS Character)
    LOCAL loExcel AS Object
    LOCAL lnIndex AS Integer, lnRow AS Integer, lnCol AS Integer, leValue
    
    WAIT "正在導出數據，請稍候……" WINDOW NOWAIT 
    loExcel = CREATEOBJECT("Excel.Application")
    WITH loExcel
        IF !FILE(tcBook)
            .WorkBooks.Add
        ELSE 
            .WorkBooks.Open(tcBook)
            .Sheets.Add
        ENDIF 
        .Sheets(1).Name = tcSheet
        .WorkSheets(tcSheet).Activate
        SELECT (tcAlias)
        FOR lnIndex = 1 TO FCOUNT(tcAlias)
            .Cells(1,lnIndex).Value = FIELD(lnIndex)
        NEXT 
        .Rows(1).Font.Bold = .T.
        .Rows(1).HorizontalAlignment = 3
        lnRow = 2
        SCAN ALL 
            FOR lnCol = 1 TO FCOUNT(tcAlias)
                leValue = EVALUATE(FIELD(lnCol))
                DO CASE
                    CASE VARTYPE(leValue) == "D"
                        leValue = DTOC(leValue)
                    CASE VARTYPE(leValue) == "L"
                        leValue = IIF(leValue, '1', '0')
                ENDCASE 
                .Cells(lnRow, lnCol).Value = leValue
            NEXT 
            lnRow = lnRow + 1
        ENDSCAN 
        FOR lnIndex = 1 TO FCOUNT(tcAlias)
            .Columns(lnIndex).EntireColumn.AutoFit
        NEXT 
        IF !FILE(tcBook)
            .ActiveWorkBook.SaveAs(tcBook)
        ELSE 
            .ActiveWorkBook.Save
        ENDIF 
        .Quit
    ENDWITH 
    RELEASE loExcel
    WAIT CLEAR 
    
ENDPROC 

感谢老杨和楼主对兄弟代码的认可，来论坛的目的本就是相互交流学习，尺有所短，寸有所长。

对hahayezhe的质疑简单说两句。之所以说它不是26进制，其根本原因在于它不支持0值。0在任何进制计数法中的一个重要作用就是占位，从而便于运算。而它只适合计数，根本和进制没有关系，这一点和罗马数字很类似。所以，我的代码中对数字求了26的模并不一定就是在用26进制，请注意表达式前面那两个连在一起的负号的用意。有兴趣的朋友也可以试试实现一下10进制数和罗马数字间的转换，这个很有意思的。

关于二维数组导入excel，其实只要保存成一定格式的文本文件excel就可以自动导入。一种是以制表符分隔列元素，换行符分隔行元素的txt文件，另一种是以逗号分隔列元素，换行符分隔行元素的.csv文件（其本身还是本文文件，只是换了个后缀）。

对了，将数据保存为xml格式也可以导入excel，与数据库交换也很方便。关于xml应该是楼主的强项吧。

。。。你把int换成其他整型不就行了。。。

......看不懂啊`