下了,看不到任何代码,运行后出错误!望指教,谢谢!@

代码在类里，运行表单demo应该可以的。
下面就是相关的代码：
If This.isSort = .F.
   Return
Endif
*!* 用Aevents函数返回呼叫这个事件的对象(同BindEvents绑定使用)，也就是判断哪个Column的Header被点击
*!* 调用grd.GetFieldTag判断该字段是否已索引
Local Array laEvents[1]
Try
   Private lcSourceAlias,lcControlSource,lcField,lcTag,Ftag,lnBuffer,lcSortGrc
   Local lcSourceAlias,lcControlSource,lcField,lcTag,Ftag,lnBuffer,lcSortGrc
   Aevents(laEvents,0)   
   lcSourceAlias = laEvents[1,1].Parent.Parent.RecordSource
   lcControlSource = laEvents[1,1].Parent.ControlSource
   lcSourceAlias = Iif(!Empty(lcSourceAlias),lcSourceAlias,Substr(lcControlSource,1,At(".",lcControlSource)-1))
   lcSourceAlias = Iif(!Empty(lcSourceAlias),lcSourceAlias,Alias())
   lcField = Substr(lcControlSource,At(".",lcControlSource)+1)
   *--
   If Empty(lcSourceAlias)
      Return
   Endif
   If Empty(lcField)
      Return
   Endif

   lcTag = "SortTag"
   Ftag = This.GetFieldTag(lcSourceAlias,lcField)
   Select (lcSourceAlias)
   *--
   lnBuffer = CursorGetProp("Buffering")
   If lnBuffer > 3
      CursorSetProp("Buffering" ,3)
   Endif
   *--
   lcSortGrc = This.SortGrc
   If !Empty(This.SortGrc)
      This.&lcSortGrc..Header1.Picture=""
   Endif
   This.SortGrc= laEvents[1,1].Parent.Name
   
   Select(lcSourceAlias)
   If Empty(Ftag)
      If laEvents[1,1].Tag = "Down"
         Inde On &lcField Tag &lcTag Descending
         laEvents[1,1].Picture = Iif(File("Down.bmp"),"Down.bmp","")
         laEvents[1,1].Tag = "Up"
      Else
         Inde On &lcField Tag &lcTag Ascending
         laEvents[1,1].Picture = Iif(File("Up.bmp"),"Up.bmp","")
         laEvents[1,1].Tag = "Down"
      Endif
   Else
      If laEvents[1,1].Tag = "Down"
         Set Order To (Ftag) Descending
         laEvents[1,1].Picture = Iif(File("Down.bmp"),"Down.bmp","")
         laEvents[1,1].Tag = "Up"
      Else
         Set Order To (Ftag) Ascending
         laEvents[1,1].Picture = Iif(File("Up.bmp"),"Up.bmp","")
         laEvents[1,1].Tag = "Down"
      Endif
   Endif
   If lnBuffer > 3
      CursorSetProp("Buffering" ,lnBuffer)
   Endif
   Go Top
   This.Refresh
Catch
Endtry

楼主说明一下运行环境吧，我这里也是操作类型不匹配，我的是VF6.0

不好意思，我的代码都是基于VFP9.0 SP2编写的，一般来说在VFP8.0上也能正确执行。

我的grid是由数据源定义的，请问老师代码写在什么地方呢？因为只有grid属性。

想问一下楼主
在普通表的浏览窗口内如何实现呢

希望得到指点 先顶一下先

今天为了实现这个点头排序,找到了这一贴,借用了楼主的几个关键字,简洁一下代码如下:
我用的是可读写的临时表,方便快速显示.
更新数据的时候需要再绑定一次,因为列数会有改变.

DEFINE CLASS grid001 as Grid
  RecordsourceType=1
  Recordsource="tmp1"
  Tag01=.T.

  PROCEDURE bindclick()
    LOCAL T1
    For Each T1 In This.Columns
        Bindevent(T1.Controls(1),"Click",This,"grhClick")
    Endfor
  ENDPROC
  PROCEDURE grhClick()
    LOCAL T1(1),T2
    Aevents(T1,0)   
    T2=T1(1,1).parent.columnorder
    this.RecordSource=""
    T2="SELECT * FROM tmp1 ORDER BY "+ALLTRIM(STR(T2))+IIF(this.tag01," ASC "," DESC ")+"INTO CURSOR tmp1 READWRITE"
    EXECSCRIPT(T2)
    this.Tag01=!this.Tag01        
    this.RecordSource="tmp1"
    this.bindclick
  ENDPROC
ENDDEFINE

不错,谢谢

非常有用。。慢慢研究一下。。。。