《求助》VFP程序中直接访问FTP服务器
我想在程序中直接访问FTP服务器!不要登录界面就执行FTP.TXT文件中的操作我还想在程序中设定一个时间定时系统
请高手可以指导一下吗？
ftp.txt清单
open 192.168.0.1 21
test
test
bin
prompt
get 测试.txt
bye
[此贴子已经被作者于2005-11-25 23:00:01编辑过]
|
传送命令到 ftp 上执行 |
|
-=-=-=-=-=-=-=-=-=-=-=-=-=- |
* Using FtpCommand
* 传送命令到 FTP 上执行
*-----------------------
Clea
#Define INTERNET_INVALID_PORT_NUMBER 0
#Define INTERNET_OPEN_TYPE_DIRECT 1
#Define INTERNET_SERVICE_FTP 1
#Define FTP_TRANSFER_TYPE_ASCII 1
#Define FTP_TRANSFER_TYPE_BINARY 2
Public hOpen, hFtpSession
Do decl && declare external functions
If connect2ftp ("202.105.49.131", "down", "down")
*DO test1
*DO test2
Do test3
= InternetCloseHandle (hFtpSession)
= InternetCloseHandle (hOpen)
Endif
Return && main
Procedure test1
* 根目录清单
= execCmd (hFtpSession, "LIST", 1)
Return
Endproc
Procedure test2
* 改变工作目录并显示
* 事实上，以下两个命令可以合并为: "LIST dmfiles"
= execCmd (hFtpSession, "CWD dmfiles", 0) && 0 is important
= execCmd (hFtpSession, "LIST", 1)
Return
Endproc
Procedure test3
* 取回(下载)文件
* 保证该文件存在你的 FTP 上
= execCmd (hFtpSession, "CWD 红雨", 0)
= execCmd (hFtpSession, "LIST", 1)
= execCmd (hFtpSession, "MKD temptest", 0)
= execCmd (hFtpSession, "RETR 日历控件.zip", 1)
Return
Endproc
Function connect2ftp (strHost, strUser, strPwd)
* open access to Inet functions
hOpen = InternetOpen ("vfp", INTERNET_OPEN_TYPE_DIRECT, 0, 0, 0)
If hOpen = 0
? "找不到库 WinInet.Dll 的入口"
Return .F.
Endif
* connect to FTP
hFtpSession = InternetConnect (hOpen, strHost, INTERNET_INVALID_PORT_NUMBER,;
strUser, strPwd, INTERNET_SERVICE_FTP, 0, 0)
If hFtpSession = 0
* close access to Inet functions and exit
= InternetCloseHandle (hOpen)
? "连接 FTP." + strHost + " 失败"
Return .F.
Else
? "连接到 " + strHost + " 用户: [" + strUser + "]密码:[" + strPwd + "]"
Endif
Return .T.
Endfunc
Function execCmd (hSession, lcCommand, fExpectResponse)
* note that ASCII type is hard-coded
hFile = 0
lnResult = FtpCommand (hFtpSession, fExpectResponse,;
FTP_TRANSFER_TYPE_ASCII, lcCommand, 0, @hFile)
If lnResult = 0
? "命令执行错误: " + LTRIM(STR(GetLastError()))
Return
Endif
If hFile <> 0
* if there is a return - display it on the screen
Set MEMOWIDTH TO 100
lnBufsize = 128 && reading buffer size
?
publ fileinfo
fileinfo = chr(13)+chr(10)
Do WHILE .T.
lcBuffer = REPLI (Chr(0), lnBufsize)
lnBytesRead = 0
If InternetReadFile (hFile, @lcBuffer, lnBufsize, @lnBytesRead) = 1
lcBuffer = LEFT(lcBuffer, lnBytesRead)
?? lcBuffer
fileinfo = fileinfo + lcBuffer
If lnBytesRead < lnBufsize
Exit
Endif
Else
Exit
Endif
Enddo
= InternetCloseHandle (hFile)
Endif
Return
Endfunc
Procedure decl
Declare INTEGER GetLastError IN kernel32
Declare INTEGER InternetOpen IN wininet;
STRING sAgent,;
INTEGER lAccessType,;
STRING sProxyName,;
STRING sProxyBypass,;
STRING lFlags
Declare INTEGER InternetCloseHandle IN wininet INTEGER hInet
Declare INTEGER InternetConnect IN wininet;
INTEGER hInternetSession,;
STRING sServerName,;
INTEGER nServerPort,;
STRING sUsername,;
STRING sPassword,;
INTEGER lService,;
INTEGER lFlags,;
INTEGER lContext
Declare INTEGER FtpCommand IN wininet;
INTEGER hConnect,;
INTEGER fExpectResponse,;
INTEGER dwFlags,;
STRING lpszCommand,;
STRING @ dwContext,;
INTEGER @ phFtpCommand
Declare INTEGER InternetReadFile IN wininet;
INTEGER hFile,;
STRING @ sBuffer,;
INTEGER lNumBytesToRead,;
INTEGER @ dwNumberOfBytesRead
Return
Endproc
|
|
在指定 ftp 上创建目录 |
|
-=-=-=-=-=-=-=-=-=-=-=-=-=- |
* Creating a directory on the FTP
* 在指定 FTP 上创建目录
*---------------------------------
Clea
#Define INTERNET_INVALID_PORT_NUMBER 0
#Define INTERNET_OPEN_TYPE_DIRECT 1
#Define INTERNET_SERVICE_FTP 1
#Define INTERNET_SERVICE_GOPHER 2
#Define INTERNET_SERVICE_HTTP 3
Do doDeclare
* initialize access to Inet functions
hOpen = InternetOpen ("vfp", INTERNET_OPEN_TYPE_DIRECT, 0, 0, 0)
If hOpen = 0
? "找不到库 WinInet.Dll 的入口"
Return
Endif
* put FTP connection settings here
strHost = "202.105.49.131"
strUser = "down"
strPwd = "down"
* connect to the FTP
hFtpSession = InternetConnect (hOpen, strHost, INTERNET_INVALID_PORT_NUMBER,;
strUser, strPwd, INTERNET_SERVICE_FTP, 0, 0)
If hFtpSession <> 0
mydir = "红雨" + SUBSTR(SYS(3),5)
If FtpCreateDirectory (hFtpSession, mydir) = 1
? "新的目录 " + mydir + " 创建成功"
Else
? "不能创建新目录：" + mydir
Endif
Else
? "指定的 FTP 连接失败！！！"
Endif
* close FTP connection
= InternetCloseHandle (hFtpSession)
= InternetCloseHandle (hOpen)
Procedure doDeclare
Declare INTEGER InternetOpen IN "wininet.dll" ;
STRING sAgent,;
INTEGER lAccessType,;
STRING sProxyName,;
STRING sProxyBypass,;
STRING lFlags
Declare INTEGER InternetCloseHandle IN "wininet.dll" INTEGER hInet
Declare INTEGER InternetConnect IN "wininet.dll" ;
INTEGER hInternetSession,;
STRING sServerName,;
INTEGER nServerPort,;
STRING sUsername,;
STRING sPassword,;
INTEGER lService,;
INTEGER lFlags,;
INTEGER lContext
Declare INTEGER FtpCreateDirectory IN "wininet.dll" ;
INTEGER hFtpSession,;
STRING lpszDirectory
Endproc
|
|
从 ftp 上删除指定文件 |
|
-=-=-=-=-=-=-=-=-=-=-=-=-=- |
* Deleting a file stored on the FTP server
* 从 ftp 上删除指定文件
*-------------------------------------------------
clea
#Define INTERNET_INVALID_PORT_NUMBER 0
#Define INTERNET_OPEN_TYPE_DIRECT 1
#Define INTERNET_SERVICE_FTP 1
#Define FTP_TRANSFER_TYPE_ASCII 1
#Define FTP_TRANSFER_TYPE_BINARY 2
Public hOpen, hFtpSession
Do decl
If connect2ftp ("202.105.49.131", "down", "down")
* no wildcards accepted; valid file name only
? FtpDeleteFile (hFtpSession, "红雨/temptest.zip" )
= InternetCloseHandle (hFtpSession)
= InternetCloseHandle (hOpen)
Endif
Procedure decl
Declare INTEGER InternetOpen IN wininet.dll;
STRING sAgent,;
INTEGER lAccessType,;
STRING sProxyName,;
STRING sProxyBypass,;
STRING lFlags
Declare INTEGER InternetCloseHandle IN wininet.dll INTEGER hInet
Declare INTEGER InternetConnect IN wininet.dll;
INTEGER hInternetSession,;
STRING sServerName,;
INTEGER nServerPort,;
STRING sUsername,;
STRING sPassword,;
INTEGER lService,;
INTEGER lFlags,;
INTEGER lContext
Declare INTEGER FtpDeleteFile IN wininet.dll;
INTEGER hConnect,;
STRING lpszFileName
Return
Endproc
Function connect2ftp (strHost, strUser, strPwd)
* open access to Inet functions
hOpen = InternetOpen ("vfp", INTERNET_OPEN_TYPE_DIRECT, 0, 0, 0)
If hOpen = 0
? "找不到库 WinInet.Dll 的入口"
Return .F.
Endif
* connect to FTP
hFtpSession = InternetConnect (hOpen, strHost, INTERNET_INVALID_PORT_NUMBER,;
strUser, strPwd, INTERNET_SERVICE_FTP, 0, 0)
If hFtpSession = 0
* close access to Inet functions and exit
= InternetCloseHandle (hOpen)
? "连接 FTP " + strHost + " 无效！！！"
Return .F.
Else
? "连接到 " + strHost + " as: [" + strUser + ", *****]"
Endif
Return .T.
Endfunc
|
