vfp9.0 form中没有用数据环境，数据环境总是出一些莫名其妙的问题。Grid绑定了一个表，在form的init事件里又定义了grid的数据源，是同一个表。
sele 1
use data\ztml exclusive
INDEX on id1 TO idx1
go top
if eof()
  
*   
  
  
endif


thisform.grid1.recordsource='ztml'
thisform.grid1.recordsourcetype=1
thisform.grid1.column3.text1.AutoComplete= 1
thisform.grid1.column3.text1.AutoCompTable= 'data\hhcomp'
thisform.grid1.column4.text1.AutoComplete= 1
thisform.grid1.column4.text1.AutoCompTable= 'data\ggcomp'
thisform.refresh
thisform.grid1.setfocus
现在需要在column2.text1 的keypress事件里添加功能，但是无响应，keypress里测试最简单的 wait wind this.value，无任何反应。
不过如果不在form init事件里重定义grid的数据源，则keypress里的代码可以响应。
请问怎么能够在重定义grid数据源后，text的keypress也可以响应？谢谢

用 MESSAGEBOX(this.value)

谢谢版主。现在问题的关键是keypress事件不响应，就是说不执行这个事件里的代码。

将 MESSAGEBOX(this.value) 放在keypress事件里试，我测试有响应的哦。

在form的activate事件里重定义grid数据源就不行了
thisform.grid1.recordsource='ztml'
 thisform.grid1.recordsourcetype=1

把这个
sele 1
 use data\ztml exclusive

改成
sele ztml
就可以响应了。
真是奇怪。
还是谢谢版主！

use data\ztml exclusive 就是关闭当前表再打开表，之前的数据源关闭了，GRID重新初始化了，当然原来的事件过程代码也没了。
确有需要这种情况，只有动态创建GRID，重新定义GRID相关属性和事件代码。也可以封装一个GRID类，动态创建引用。

动态创建grid后，事件代码怎么加进去？有相关资料吗？

写个简单示例：

** Test.prg
of = CREATEOBJECT("Form1")
of.show(1)
RETURN


DEFINE CLASS Form1 As Form
    ADD OBJECT Command1 AS CommandButton WITH top=10,left=10,height=25,caption="切换表"
    
    PROCEDURE Init
         ENDPROC
    
    PROCEDURE Command1.Click
        USE 
        IF VARTYPE(thisform.Grid1) == "O"
            thisform.RemoveObject("Grid1")
        ENDIF
        thisform.AddObject("Grid1", "_Grid")
        thisform.Grid1.Top = 40
        thisform.Grid1.Left = 10
        IF EMPTY(this.Tag)
            this.Tag = "1"
                * 相当于 use 表1
            CREATE CURSOR 表1 (f1 I, f2 I, f3 I)
            INSERT INTO 表1 VALUES (1, 2, 3)
            INSERT INTO 表1 VALUES (4, 5, 6)
            GO TOP 
            thisform.Grid1.RecordSource = "表1"
        ELSE
            this.Tag = ""
                * 相当于 use 表2
            CREATE CURSOR 表2 (f1 I, f2 I, f3 I)
            INSERT INTO 表2 VALUES (4, 5, 6)
            INSERT INTO 表2 VALUES (7, 8, 9)
            GO TOP 
            thisform.Grid1.RecordSource = "表2"
        ENDIF
    ENDPROC
ENDDEFINE


DEFINE CLASS _Grid AS Grid
    Visible = .T.
    ColumnCount = 3
    RecordSourceType=1

    PROCEDURE Init
        this.Column1.RemoveObject("Text1")
        this.Column1.AddObject("Text1", "_TextBox")
    ENDPROC
ENDDEFINE


DEFINE CLASS _TextBox AS TextBox
    Visible = .T.

    PROCEDURE KeyPress(nKeyCode, nShiftAltCtrl)
        MESSAGEBOX(this.value)
    ENDPROC

    PROCEDURE Click
        MESSAGEBOX(this.value)
    ENDPROC
ENDDEFINE

如果不想封装GRID类，也可以自定义方法用BINDEVENT()绑定，详细参考VFP帮助。