如上图，在文本框text4输入编号后表中可以搜索定位到相应条件记录号，
但是在list1框中显示的值没有进行相应改变。请教大神们如何在文本框text4中输入值时list1框中显示也进行即时改变

用SET FILTER TO 条件

想过这个方法，但是每次选完后都要重新set filt to太麻烦，如果数据库大一点这个过程也是比较折磨人的

list1的RowSourceType=3、RowSource="SELECT...FROM...WHERE bh==thisform.text4.value INTO CURSOR tmp_list1"。
需要刷新list1时执行thisform.list1.Requery。

谢谢老大指点，马上实践

研究了一会，没怎么弄 明白sql语句在属性里面的使用方法，再研究一下

老大，请都一下是这个意思吗？

你先增加1个按钮如 command1,其中
** command1.click
thisform.list1.RowSourceType=3
thisform.list1.RowSource="SELECT...FROM...WHERE bh==thisform.text4.value INTO CURSOR tmp_list1"
thisform.list1.Requery
** 看看，是不是你要的，如果是，你再想方法，怎么把 这个功能放到 text4.keykress 去

简单写个示例，是否这意思：
** test.prg
CREATE CURSOR tt (bh C(10), xm C(20))
INSERT INTO tt VALUES ("101", "项目101")
INSERT INTO tt VALUES ("201", "项目201")
INSERT INTO tt VALUES ("301", "项目301")
INSERT INTO tt VALUES ("102", "项目102")
INSERT INTO tt VALUES ("202", "项目202")
INSERT INTO tt VALUES ("302", "项目302")

of = CREATEOBJECT("myform")
of.show(1)

DEFINE CLASS myform as Form
    ADD OBJECT text4 as textbox WITH top=10,left=10,width=100
    ADD OBJECT list1 as listbox WITH top=40,left=10,width=200,;
        ColumnCount = 2,;
        RowSourceType = 3
    PROCEDURE Init
        this._ListRequery()
    ENDPROC
   
    PROCEDURE _ListRequery()
        IF !EMPTY(this.text4.value)
            this.list1.RowSource = "SELECT bh,xm FROM tt WHERE ALLTRIM(thisform.text4.value)$bh INTO CURSOR tmp_list1"
            **this.list1.RowSource = "SELECT bh,xm FROM tt WHERE bh=ALLTRIM(thisform.text4.value) INTO CURSOR tmp_list1"
        ELSE
            this.list1.RowSource = "SELECT bh,xm FROM tt INTO CURSOR tmp_list1"
        ENDIF
        *this.list1.Requery
    ENDFUNC
   
    PROCEDURE text4.InteractiveChange
        thisform._ListRequery()      
    ENDPROC
ENDDEFINE

谢谢，应该不是这个意思。
我的目的是在文本框text4中每键入一个字符list1框中就会将相应符合条件的记录显示出来
例如图中输入0415的时候字段编号中包含有0415的第一个记录就会相应的显示在框中第一行