| 网站首页 | 业界新闻 | 群组 | 交易 | 人才 | 下载频道 | 博客 | 代码贴 | 编程论坛
免费IT实战开发视频教程合集分享千里之行 始于足下
共有 883 人关注过本帖
标题:VFP 如何查找并删除指定网站的COOKIE?
只看楼主 加入收藏
sxwjl
Rank: 1
等 级:新手上路
帖 子:21
专家分:0
注 册:2009-3-29
结帖率:75%
  已结贴   问题点数:20  回复次数:8   
VFP 如何查找并删除指定网站的COOKIE?
VFP 如何查找并删除指定网站的COOKIE?
如查找并删除本网站: Cookie:administrator@bbs.bccn.net/  
搜索更多相关主题的帖子: Cookie  如何  网站  
2017-06-05 19:48
红星二锅头
Rank: 7Rank: 7Rank: 7
等 级:贵宾
威 望:38
帖 子:447
专家分:690
注 册:2016-8-25
  得分:0 
如果是 IE 浏览器的,用下面的 API 清理
DECLARE INTEGER InternetGetCookie IN wininet;
    STRING    lpszUrlName,;
    STRING    lpszCookieName,;
    STRING  @ lpszCookieData,;
    INTEGER @ lpdwSize

其他浏览器的,恐怕只能删除 Cooker 文件夹

团队红星二锅头,队长王猛,领队李冲,顾问杨伟,副队张挺,外联马彪,内勤韩秀,人事顾闯,财务赵魁,后勤周强
2017-06-06 12:28
sxwjl
Rank: 1
等 级:新手上路
帖 子:21
专家分:0
注 册:2009-3-29
  得分:0 
以下是引用红星二锅头在2017-6-6 12:28:26的发言:

如果是 IE 浏览器的,用下面的 API 清理
DECLARE INTEGER InternetGetCookie IN wininet;
    STRING    lpszUrlName,;
    STRING    lpszCookieName,;
    STRING  @ lpszCookieData,;
    INTEGER @ lpdwSize
 
其他浏览器的,恐怕只能删除 Cooker 文件夹
InternetGetCookie 的具体参数怎么设置,能给个实例吗?如:删除IE浏览器中的 Cookie:administrator@bccn.net/

[此贴子已经被作者于2017-6-6 15:51编辑过]

2017-06-06 15:48
红星二锅头
Rank: 7Rank: 7Rank: 7
等 级:贵宾
威 望:38
帖 子:447
专家分:690
注 册:2016-8-25
  得分:20 
*!*    Cookies 管理(删除/获取)
*!*    用法:首先打开你的浏览器中,输入:https://bbs.bccn.net/
*!*    如果需要用户名和密码的,请输入:用户名:xxxxxxx 和 密码:yyyyyyy
*!*    等正常后,运行本代码,就可以过得你的 Cookie 的 Cook.txt 文件
*!*    InternetGetCookie() 只读取 Cookie 目录下生成的 Cookie

Clear
Do Declare

Local lcUrl, lcCookieName, lcCookieData, lnLen
lcUrl = "https://bbs.bccn.net/"  && 网址
lcCookieName = "user settings"  && 定义 Cookie 名
lcCookieData = "regular,54,126,-1,0"

*    = AddPersistentCookie(lcUrl, lcCookieName,;
lcCookieData, date()+2)

? "Cookie:", ReadCookie(lcUrl, lcCookieName)  && 读取 Cookie

* = DeleteCookie(lcUrl, lcCookieName)  && 删除 Cookie
* =Strtofile(ReadCookie(lcUrl, lcCookieName), "Cook.txt")  && 保存 Cookie 文件


Function ReadCookie(lcUrl, lcCookieName)
    Local lcCookieData, lnLen, lcResult
    lnLen = 4096  && 预设接收结果的缓冲区的大小为:4KB
    lcCookieData = Space(lnLen)
    lcResult = ""  && 预设接收的结果

    If InternetGetCookie(lcUrl, lcCookieName, @lcCookieData, @lnLen) <> 0
        lcResult = Left(lcCookieData, lnLen-1)
    Else
        * 259 = 没有可用的数据了。
    Endif
    Return lcResult
Endfunc


Procedure AddSessionCookie(lcUrl, lcCookieName, lcCookieData)
    * 会话的 Cookie 被存储在内存中,可以通过创建它们的进程访问。
    = InternetSetCookie(lcUrl, lcCookieName, lcCookieData)
Endproc


Procedure AddPersistentCookie(lcUrl, lcCookieName, lcCookieData, lvExpires)
    * Persistent cookies are cookies that have an expiration date.
    * These cookies are stored in the Windows\System directory.

    = InternetSetCookie(lcUrl, lcCookieName,;
        lcCookieData + ";expires=" + toGMTString(lvExpires))
Endproc


Procedure DeleteCookie(lcUrl, lcCookieName)
    * To delete a persistent cookie you must set its expiry date
    * to a time that has already expired.
    * Usually it keeps staying as a session cookie after being deleted

    = AddPersistentCookie(lcUrl, lcCookieName, "", Date()-1)
Endproc


Function toGMTString(ltDate)
    * 返回 datetime 格式为 DAY, DD-MMM-YYYY HH:MM:SS GMT

    Return Substr("SunMonTueWedThuFriSat",;
        (Dow(ltDate,1)-1)*3+1, 3) + ", " +;
        STRTR(Str(Day(ltDate), 2), " ","0") + "-" +;
        SUBSTR("JanFebMarAprMayJunJulAugSepOctNovDec",;
        (Month(ltDate)-1)*3+1, 3) + "-" +;
        STR(Year(ltDate),4) + " " +;
        STRTR(Str(Hour(ltDate), 2), " ","0") + ":" +;
        STRTR(Str(Minute(ltDate), 2), " ","0") + ":" +;
        STRTR(Str(Sec(ltDate), 2), " ","0") + " GMT"
Endfunc


Procedure Declare
    Declare Integer InternetGetCookie In wininet;
        STRING lpszUrlName, String lpszCookieName,;
        STRING @lpszCookieData, Integer @lpdwSize

    Declare Integer InternetSetCookie In wininet;
        STRING lpszUrl, String lpszCookieName,;
        STRING lpszCookieData
Endproc


[此贴子已经被作者于2017-6-6 16:27编辑过]


团队红星二锅头,队长王猛,领队李冲,顾问杨伟,副队张挺,外联马彪,内勤韩秀,人事顾闯,财务赵魁,后勤周强
2017-06-06 16:24
wangzhiyi
Rank: 7Rank: 7Rank: 7
等 级:贵宾
威 望:25
帖 子:311
专家分:577
注 册:2014-4-9
  得分:0 
回复保存学习。
2017-06-07 01:06
sxwjl
Rank: 1
等 级:新手上路
帖 子:21
专家分:0
注 册:2009-3-29
  得分:0 
谢谢,保存学习!
2017-06-07 15:06
厨师王德榜
Rank: 20Rank: 20Rank: 20Rank: 20Rank: 20
等 级:版主
威 望:72
帖 子:455
专家分:1642
注 册:2013-2-16
  得分:0 
学习学习。红星二锅头是个热心人。
2017-06-08 16:54
风度123123
Rank: 1
等 级:新手上路
帖 子:2
专家分:4
注 册:2017-6-18
  得分:0 
学习了,谢谢
2017-06-18 08:38
eepcvfp
Rank: 2
等 级:论坛游民
帖 子:162
专家分:15
注 册:2013-8-12
  得分:0 
真是高手!
2017-06-18 23:26







关于我们 | 广告合作 | 编程中国 | 清除Cookies | TOP | 手机版

编程中国 版权所有,并保留所有权利。
Powered by Discuz, Processed in 0.028764 second(s), 9 queries.
Copyright©2004-2018, BCCN.NET, All Rights Reserved