文件夹DATA下 cp.dbf
th       sl
A        1
A        3
A        8
B        2
B        9
C        22
D        29
文件夹linshi下 temp.dbf
th
A
B
E
将TH.dbf中th与temp.dbf中th相同的删除
use linshi\temp.dbf
delete  from data\cp where temp.th==cp.th
为什么只删除cp.dbf表中a的行？
应该怎么才能实现都删除？

VFP什么版本

VFP6 代码

create cursor cp (th c(1),sl n(4))
insert into cp values ("A",1)
insert into cp values ("A",3)
insert into cp values ("A",8)
insert into cp values ("B",2)
insert into cp values ("B",9)
insert into cp values ("C",22)
insert into cp values ("D",29)
create cursor temp (th c(1))
insert into temp values ("A")
insert into temp values ("B")
insert into temp values ("E")
select temp
scan
    delete from cp where cp.th==temp.th
endscan
select cp
browse

收到的鲜花

• shankeda 于 2017-07-24 13:18 送鲜花  3朵   附言：我很赞同

VFP9 代码

create cursor cp (th c(1),sl n(4))
insert into cp values ("A",1)
insert into cp values ("A",3)
insert into cp values ("A",8)
insert into cp values ("B",2)
insert into cp values ("B",9)
insert into cp values ("C",22)
insert into cp values ("D",29)
create cursor temp (th c(1))
insert into temp values ("A")
insert into temp values ("B")
insert into temp values ("E")
delete cp from temp where cp.th==temp.th
select cp
browse

delete 好像不能同时删除多个表的，你可以用2条语句

* 先把删除条件数据放到临时表 d_tmp
use linshi\temp.dbf in 0
use data\cp.dbf in 0
select cp.th from temp,cp where temp.th==cp.th into cursor d_tmp

delete  cp from cp,d_tmp where d_tmp.th==cp.th
delete  temp from temp,d_tmp where d_tmp.th==temp.th

VFP6不行，但VFP9行

VF6.0的

可能是我没说明白，只是删除cp表里的数据，temp表也是从别处筛选处来的表，对temp表不做操作。

谢谢大神  解决了

delete from cp where th in(select th from temp.dbf)  ** 在cp表中作了删除标记