有一个表（见附件）只有一列，其中每行对应一个名字，现在希望按以下要求将其分行，存放到另一个新表中：

①提示输入数字“10",创建一个有10列的新表，表的字段名为 name1直到name10，，（新表的字段数要根据输入的数字自动创建，比如输入10就创建10列，输入11就创建11列……）

②从头开始连续取原始数据表中的前10人到新表的第一行，11-20则到第二行……，以此类推。如果输入的数字是11，则从头开始连续取11人到第一行，12-22到第二行，，，

总之就是希望能根据输入的数字自动建相应列数的表，并将原始表中所有人按每行有相应个数的姓名来存放。

希望大师们能不吝赐教，非常感谢！！

怎么论坛上老是有这种问题？是老师布置的作业吧？

话说不是老师布置的作业，而是，我只是一名业余弄弄vfp的其他科目老师。

CLOSE TABLES ALL
c = INPUTBOX('请输入目标表的列数：')
nCols = INT(VAL(c))
IF nCols < 1
    MESSAGEBOX('列数无效！')
    RETURN
ENDIF
CREATE CURSOR t1 (name1 c(10))
FOR i = 2 TO nCols
    ALTER table t1 ADD ('name'+TRAN(i)) c(10)
NEXT
SELECT 0
USE xsxx
DO WHILE NOT EOF()
    APPEND BLANK IN t1
    i = 1
    DO WHILE NOT EOF() AND i <= nCols
        REPLACE ('name'+TRAN(i)) WITH xsxx.name IN t1
        i = i + 1
        SKIP
    ENDDO
ENDDO
SELECT t1
GO TOP
BROWSE

谢谢，以上代码相当完美。

再问，怎样将姓名为两个字的变更为在姓和名之间加上空格（如“张三”变更为“张  三”），然后再填入对应的单元格中？

学习了.

CLOSE TABLES ALL
c = INPUTBOX('请输入目标表的列数：')
nCols = INT(VAL(c))
IF nCols < 1
    MESSAGEBOX('列数无效！')
    RETURN
ENDIF
CREATE CURSOR t1 (name1 c(10))
FOR i = 2 TO nCols
    ALTER table t1 ADD ('name'+TRAN(i)) c(10)
NEXT
SELECT 0
USE xsxx
DO WHILE NOT EOF()
    APPEND BLANK IN t1
    i = 1
    DO WHILE NOT EOF() AND i <= nCols
        cName = IIF(LEN(TRIM(name))=4,STUFF(name,3,0,SPACE(2)),name)
        REPLACE ('name'+TRAN(i)) WITH cName IN t1
        i = i + 1
        SKIP
    ENDDO
ENDDO
SELECT t1
GO TOP
BROWSE

CLOSE DATABASES
USE XSXX IN 0 ALIAS XSXX
DO WHILE .T.
    INPUT "请输入列数：" TO NCOL
    IF NCOL<=1
        MESSAGEBOX("输入列数无效！")
        LOOP
    ELSE
        EXIT
    ENDIF
ENDDO
CSTRU=""
FOR I=1 TO NCOL
     CSTRU=CSTRU+"NAME"+TRANSFORM(I)+" C(6),"
ENDFOR
CSTRU=LEFT(CSTRU,LEN(CSTRU)-1)
*MESSAGEBOX(CSTRU)
CREATE CURSOR TT (&CSTRU)
SELECT XSXX
LOCAL XS[1,NCOL]
XS=""
N=0
SCAN
   XM=IIF(LEN(ALLTRIM(NAME))=4,LEFT(NAME,2)+"  "+SUBSTR(NAME,3,2),NAME)
   N=N+1
   XS[1,N]=XM
   IF N=NCOL OR RECNO()=RECCOUNT()
       INSERT INTO TT FROM ARRAY XS
       N=0
       XS=""
   ENDIF
ENDSCAN
SELECT TT
BROWSE
USE IN XSXX

很好，大体上看懂了，用二维数组取值。

条条大路通罗马。现在分析一下我的代码与sdta版主的代码的异同：
1. 在让用户指定列数时，我使用了inputbox()函数，该函数的返回值是字符型，因此对返回结果进行了类型转换：nCols = int(val(c))。并且当用户输入无效列数时，直接退出。
  sdta版主使用了input命令，该命令可直接输入一个数值，无需转换，并且当用户输入无效值时，系统会提示继续输入，直到输入一个有效值为止。
  优缺点：inputbox()函数打开的是一个标准的widnows对话框，界面美观，但返回值需要转换。input命令是VFP兼容以前DOS版本的老命令，界面不美观，但是其返回值本身就是数值型的，无需转换。
2. 我们的代码都是根据列数建立一个游标。
   我的代码是先建立一个仅包含一个字段的游标，然后再使用“alter table add”逐个添加其他字段。
   sdta版主的代码是生成一个建立游标的字符串，然后再用宏替换执行该语句，从而一次性创建该游标。
3. 在将原表数据转换到目标表时，我使用了嵌套的两个循环，第一个循环用于添加空记录，第二个循环用于更新字段内容。
   sdta使用了一个循环，在循环体内将字段内容先暂存到数组，待到达一定记录数时再将数组内容添加到新表。
   个人意见：两层循环比较好理解，不易出错；单个循环更简练，但需要对计数变量做精准控制，对编程水平有更高的要求。
4. 再对两个汉字姓名的处理上，我使用了stuff()函数，在第一个汉字后面直接插入2个空格。sdta使用了“取前2个字符+2个空格+后2个字符”的方式。